m4/stdint.m4

   1 # stdint.m4 serial 21
   2 dnl Copyright (C) 2001-2002, 2004-2006 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert and Bruno Haible.
   8 dnl Test whether <stdint.h> is supported or must be substituted.
   9
  10 AC_DEFUN([gl_STDINT_H],
  11 [
  12   AC_PREREQ(2.59)dnl
  13
  14   dnl Check for long long int and unsigned long long int.
  15   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  16   if test $ac_cv_type_long_long_int = yes; then
  17     HAVE_LONG_LONG_INT=1
  18   else
  19     HAVE_LONG_LONG_INT=0
  20   fi
  21   AC_SUBST([HAVE_LONG_LONG_INT])
  22   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  23   if test $ac_cv_type_unsigned_long_long_int = yes; then
  24     HAVE_UNSIGNED_LONG_LONG_INT=1
  25   else
  26     HAVE_UNSIGNED_LONG_LONG_INT=0
  27   fi
  28   AC_SUBST([HAVE_UNSIGNED_LONG_LONG_INT])
  29
  30   dnl Check for <wchar.h>.
  31   AC_CHECK_HEADERS_ONCE([wchar.h])
  32   if test $ac_cv_header_wchar_h = yes; then
  33     HAVE_WCHAR_H=1
  34   else
  35     HAVE_WCHAR_H=0
  36   fi
  37   AC_SUBST([HAVE_WCHAR_H])
  38
  39   dnl Check for <inttypes.h>.
  40   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
  41   if test $ac_cv_header_inttypes_h = yes; then
  42     HAVE_INTTYPES_H=1
  43   else
  44     HAVE_INTTYPES_H=0
  45   fi
  46   AC_SUBST([HAVE_INTTYPES_H])
  47
  48   dnl Check for <sys/types.h>.
  49   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h.
  50   if test $ac_cv_header_sys_types_h = yes; then
  51     HAVE_SYS_TYPES_H=1
  52   else
  53     HAVE_SYS_TYPES_H=0
  54   fi
  55   AC_SUBST([HAVE_SYS_TYPES_H])
  56
  57   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_stdint_h.
  58   if test $ac_cv_header_stdint_h = yes; then
  59     gl_ABSOLUTE_HEADER([stdint.h])
  60     ABSOLUTE_STDINT_H=\"$gl_cv_absolute_stdint_h\"
  61     HAVE_STDINT_H=1
  62   else
  63     ABSOLUTE_STDINT_H=\"no/such/file/stdint.h\"
  64     HAVE_STDINT_H=0
  65   fi
  66   AC_SUBST([ABSOLUTE_STDINT_H])
  67   AC_SUBST([HAVE_STDINT_H])
  68
  69   dnl Now see whether we need a substitute <stdint.h>.  Use
  70   dnl ABSOLUTE_STDINT_H, not <stdint.h>, so that it also works during
  71   dnl a "config.status --recheck" if a stdint.h has been
  72   dnl created in the build directory.
  73   if test $ac_cv_header_stdint_h = yes; then
  74     AC_CACHE_CHECK([whether stdint.h conforms to C99],
  75       [gl_cv_header_working_stdint_h],
  76       [gl_cv_header_working_stdint_h=no
  77        AC_COMPILE_IFELSE([
  78          AC_LANG_PROGRAM([[
  79 #include <stddef.h>
  80 #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
  81 #define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */
  82 #include ABSOLUTE_STDINT_H
  83 #ifdef INT8_MAX
  84 int8_t a1 = INT8_MAX;
  85 int8_t a1min = INT8_MIN;
  86 #endif
  87 #ifdef INT16_MAX
  88 int16_t a2 = INT16_MAX;
  89 int16_t a2min = INT16_MIN;
  90 #endif
  91 #ifdef INT32_MAX
  92 int32_t a3 = INT32_MAX;
  93 int32_t a3min = INT32_MIN;
  94 #endif
  95 #ifdef INT64_MAX
  96 int64_t a4 = INT64_MAX;
  97 int64_t a4min = INT64_MIN;
  98 #endif
  99 #ifdef UINT8_MAX
 100 uint8_t b1 = UINT8_MAX;
 101 #else
 102 typedef int b1[(unsigned char) -1 != 255 ? 1 : -1];
 103 #endif
 104 #ifdef UINT16_MAX
 105 uint16_t b2 = UINT16_MAX;
 106 #endif
 107 #ifdef UINT32_MAX
 108 uint32_t b3 = UINT32_MAX;
 109 #endif
 110 #ifdef UINT64_MAX
 111 uint64_t b4 = UINT64_MAX;
 112 #endif
 113 int_least8_t c1 = INT8_C (0x7f);
 114 int_least8_t c1max = INT_LEAST8_MAX;
 115 int_least8_t c1min = INT_LEAST8_MIN;
 116 int_least16_t c2 = INT16_C (0x7fff);
 117 int_least16_t c2max = INT_LEAST16_MAX;
 118 int_least16_t c2min = INT_LEAST16_MIN;
 119 int_least32_t c3 = INT32_C (0x7fffffff);
 120 int_least32_t c3max = INT_LEAST32_MAX;
 121 int_least32_t c3min = INT_LEAST32_MIN;
 122 int_least64_t c4 = INT64_C (0x7fffffffffffffff);
 123 int_least64_t c4max = INT_LEAST64_MAX;
 124 int_least64_t c4min = INT_LEAST64_MIN;
 125 uint_least8_t d1 = UINT8_C (0xff);
 126 uint_least8_t d1max = UINT_LEAST8_MAX;
 127 uint_least16_t d2 = UINT16_C (0xffff);
 128 uint_least16_t d2max = UINT_LEAST16_MAX;
 129 uint_least32_t d3 = UINT32_C (0xffffffff);
 130 uint_least32_t d3max = UINT_LEAST32_MAX;
 131 uint_least64_t d4 = UINT64_C (0xffffffffffffffff);
 132 uint_least64_t d4max = UINT_LEAST64_MAX;
 133 int_fast8_t e1 = INT_FAST8_MAX;
 134 int_fast8_t e1min = INT_FAST8_MIN;
 135 int_fast16_t e2 = INT_FAST16_MAX;
 136 int_fast16_t e2min = INT_FAST16_MIN;
 137 int_fast32_t e3 = INT_FAST32_MAX;
 138 int_fast32_t e3min = INT_FAST32_MIN;
 139 int_fast64_t e4 = INT_FAST64_MAX;
 140 int_fast64_t e4min = INT_FAST64_MIN;
 141 uint_fast8_t f1 = UINT_FAST8_MAX;
 142 uint_fast16_t f2 = UINT_FAST16_MAX;
 143 uint_fast32_t f3 = UINT_FAST32_MAX;
 144 uint_fast64_t f4 = UINT_FAST64_MAX;
 145 #ifdef INTPTR_MAX
 146 intptr_t g = INTPTR_MAX;
 147 intptr_t gmin = INTPTR_MIN;
 148 #endif
 149 #ifdef UINTPTR_MAX
 150 uintptr_t h = UINTPTR_MAX;
 151 #endif
 152 intmax_t i = INTMAX_MAX;
 153 uintmax_t j = UINTMAX_MAX;
 154 struct s {
 155   int check_PTRDIFF: PTRDIFF_MIN < 0 && 0 < PTRDIFF_MAX ? 1 : -1;
 156   int check_SIG_ATOMIC: SIG_ATOMIC_MIN <= 0 && 0 < SIG_ATOMIC_MAX ? 1 : -1;
 157   int check_SIZE: 0 < SIZE_MAX ? 1 : -1;
 158   int check_WCHAR: WCHAR_MIN <= 0 && 0 < WCHAR_MAX ? 1 : -1;
 159   int check_WINT: WINT_MIN <= 0 && 0 < WINT_MAX ? 1 : -1;
 160
 161   /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others.  */
 162   int check_UINT8_C:
 163         (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1;
 164   int check_UINT16_C:
 165         (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1;
 166
 167   /* Detect bugs in OpenBSD 3.9 stdint.h.  */
 168 #ifdef UINT8_MAX
 169   int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1;
 170 #endif
 171 #ifdef UINT16_MAX
 172   int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1;
 173 #endif
 174 #ifdef UINT32_MAX
 175   int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1;
 176 #endif
 177 #ifdef UINT64_MAX
 178   int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1;
 179 #endif
 180   int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1;
 181   int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1;
 182   int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1;
 183   int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1;
 184   int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1;
 185   int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1;
 186   int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1;
 187   int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1;
 188   int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1;
 189   int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1;
 190   int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1;
 191 };
 192          ]])],
 193          [gl_cv_header_working_stdint_h=yes])])
 194   fi
 195   if test "$gl_cv_header_working_stdint_h" = yes; then
 196     STDINT_H=
 197   else
 198     dnl Check for <sys/inttypes.h>, and for
 199     dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
 200     AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h])
 201     if test $ac_cv_header_sys_inttypes_h = yes; then
 202       HAVE_SYS_INTTYPES_H=1
 203     else
 204       HAVE_SYS_INTTYPES_H=0
 205     fi
 206     AC_SUBST([HAVE_SYS_INTTYPES_H])
 207     if test $ac_cv_header_sys_bitypes_h = yes; then
 208       HAVE_SYS_BITYPES_H=1
 209     else
 210       HAVE_SYS_BITYPES_H=0
 211     fi
 212     AC_SUBST([HAVE_SYS_BITYPES_H])
 213
 214     gl_STDINT_TYPE_PROPERTIES
 215     STDINT_H=stdint.h
 216   fi
 217   AC_SUBST(STDINT_H)
 218 ])
 219
 220 dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES)
 221 dnl Determine the size of each of the given types in bits.
 222 AC_DEFUN([gl_STDINT_BITSIZEOF],
 223 [
 224   dnl Use a shell loop, to avoid bloating configure, and
 225   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 226   dnl   config.h.in,
 227   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 228   AC_FOREACH([gltype], [$1],
 229     [AH_TEMPLATE([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 230        [Define to the number of bits in type ']gltype['.])])
 231   for gltype in $1 ; do
 232     AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}],
 233       [AC_COMPUTE_INT([result], [sizeof ($gltype) * CHAR_BIT],
 234          [$2
 235 #include <limits.h>], [result=unknown])
 236        eval gl_cv_bitsizeof_${gltype}=\$result
 237       ])
 238     eval result=\$gl_cv_bitsizeof_${gltype}
 239     if test $result = unknown; then
 240       dnl Use a nonempty default, because some compilers, such as IRIX 5 cc,
 241       dnl do a syntax check even on unused #if conditions and give an error
 242       dnl on valid C code like this:
 243       dnl   #if 0
 244       dnl   # if  > 32
 245       dnl   # endif
 246       dnl   #endif
 247       result=0
 248     fi
 249     GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 250     AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result])
 251     eval BITSIZEOF_${GLTYPE}=\$result
 252   done
 253   AC_FOREACH([gltype], [$1],
 254     [AC_SUBST([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 255 ])
 256
 257 dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES)
 258 dnl Determine the signedness of each of the given types.
 259 dnl Define HAVE_SIGNED_TYPE if type is signed.
 260 AC_DEFUN([gl_CHECK_TYPES_SIGNED],
 261 [
 262   dnl Use a shell loop, to avoid bloating configure, and
 263   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 264   dnl   config.h.in,
 265   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 266   AC_FOREACH([gltype], [$1],
 267     [AH_TEMPLATE([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 268        [Define to 1 if ']gltype[' is a signed integer type.])])
 269   for gltype in $1 ; do
 270     AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed],
 271       [AC_COMPILE_IFELSE(
 272          [AC_LANG_PROGRAM([$2[
 273             int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])],
 274          result=yes, result=no)
 275        eval gl_cv_type_${gltype}_signed=\$result
 276       ])
 277     eval result=\$gl_cv_type_${gltype}_signed
 278     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 279     if test "$result" = yes; then
 280       AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], 1)
 281       eval HAVE_SIGNED_${GLTYPE}=1
 282     else
 283       eval HAVE_SIGNED_${GLTYPE}=0
 284     fi
 285   done
 286   AC_FOREACH([gltype], [$1],
 287     [AC_SUBST([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 288 ])
 289
 290 dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES)
 291 dnl Determine the suffix to use for integer constants of the given types.
 292 dnl Define t_SUFFIX for each such type.
 293 AC_DEFUN([gl_INTEGER_TYPE_SUFFIX],
 294 [
 295   dnl Use a shell loop, to avoid bloating configure, and
 296   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 297   dnl   config.h.in,
 298   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 299   AC_FOREACH([gltype], [$1],
 300     [AH_TEMPLATE(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX],
 301        [Define to l, ll, u, ul, ull, etc., as suitable for
 302         constants of type ']gltype['.])])
 303   for gltype in $1 ; do
 304     AC_CACHE_CHECK([for $gltype integer literal suffix],
 305       [gl_cv_type_${gltype}_suffix],
 306       [eval gl_cv_type_${gltype}_suffix=no
 307        eval result=\$gl_cv_type_${gltype}_signed
 308        if test "$result" = yes; then
 309          glsufu=
 310        else
 311          glsufu=u
 312        fi
 313        for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do
 314          case $glsuf in
 315            '')  gltype1='int';;
 316            l)   gltype1='long int';;
 317            ll)  gltype1='long long int';;
 318            i64) gltype1='__int64';;
 319            u)   gltype1='unsigned int';;
 320            ul)  gltype1='unsigned long int';;
 321            ull) gltype1='unsigned long long int';;
 322            ui64)gltype1='unsigned __int64';;
 323          esac
 324          AC_COMPILE_IFELSE(
 325            [AC_LANG_PROGRAM([$2
 326               extern $gltype foo;
 327               extern $gltype1 foo;])],
 328            [eval gl_cv_type_${gltype}_suffix=\$glsuf])
 329          eval result=\$gl_cv_type_${gltype}_suffix
 330          test "$result" != no && break
 331        done])
 332     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 333     eval result=\$gl_cv_type_${gltype}_suffix
 334     test "$result" = no && result=
 335     eval ${GLTYPE}_SUFFIX=\$result
 336     AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], $result)
 337   done
 338   AC_FOREACH([gltype], [$1],
 339     [AC_SUBST(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])])
 340 ])
 341
 342 dnl gl_STDINT_INCLUDES
 343 AC_DEFUN([gl_STDINT_INCLUDES],
 344 [[
 345   #include <stddef.h>
 346   #include <signal.h>
 347   #if HAVE_WCHAR_H
 348     /* BSD/OS 4.1 has a bug: <stdio.h> and <time.h> must be included before
 349        <wchar.h>.  */
 350   # include <stdio.h>
 351   # include <time.h>
 352   # include <wchar.h>
 353   #endif
 354 ]])
 355
 356 dnl gl_STDINT_TYPE_PROPERTIES
 357 dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t
 358 dnl of interest to stdint_.h.
 359 AC_DEFUN([gl_STDINT_TYPE_PROPERTIES],
 360 [
 361   gl_STDINT_BITSIZEOF([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
 362     [gl_STDINT_INCLUDES])
 363   gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t],
 364     [gl_STDINT_INCLUDES])
 365   gl_cv_type_ptrdiff_t_signed=yes
 366   gl_cv_type_size_t_signed=no
 367   gl_INTEGER_TYPE_SUFFIX([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
 368     [gl_STDINT_INCLUDES])
 369 ])
 370
 371 dnl Autoconf >= 2.61 has AC_COMPUTE_INT built-in.
 372 dnl Remove this when we can assume autoconf >= 2.61.
 373 m4_ifdef([AC_COMPUTE_INT], [], [
 374   AC_DEFUN([AC_COMPUTE_INT], [_AC_COMPUTE_INT([$2],[$1],[$3],[$4])])
 375 ])