m4/stdint.m4

   1 # stdint.m4 serial 19
   2 dnl Copyright (C) 2001-2002, 2004-2006 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert and Bruno Haible.
   8 dnl Test whether <stdint.h> is supported or must be substituted.
   9
  10 AC_DEFUN([gl_STDINT_H],
  11 [
  12   AC_PREREQ(2.59)dnl
  13
  14   dnl Check for long long int.
  15   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  16   if test $ac_cv_type_long_long_int = yes; then
  17     HAVE_LONG_LONG_INT=1
  18   else
  19     HAVE_LONG_LONG_INT=0
  20   fi
  21   AC_SUBST([HAVE_LONG_LONG_INT])
  22
  23   dnl Check for <wchar.h>.
  24   AC_CHECK_HEADERS_ONCE([wchar.h])
  25   if test $ac_cv_header_wchar_h = yes; then
  26     HAVE_WCHAR_H=1
  27   else
  28     HAVE_WCHAR_H=0
  29   fi
  30   AC_SUBST([HAVE_WCHAR_H])
  31
  32   dnl Check for <inttypes.h>.
  33   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
  34   if test $ac_cv_header_inttypes_h = yes; then
  35     gl_ABSOLUTE_HEADER([inttypes.h])
  36     ABSOLUTE_INTTYPES_H=\"$gl_cv_absolute_inttypes_h\"
  37     HAVE_INTTYPES_H=1
  38   else
  39     ABSOLUTE_INTTYPES_H=\"no/such/file/inttypes.h\"
  40     HAVE_INTTYPES_H=0
  41   fi
  42   AC_SUBST([ABSOLUTE_INTTYPES_H])
  43   AC_SUBST([HAVE_INTTYPES_H])
  44
  45   dnl Check for <sys/types.h>.
  46   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h.
  47   if test $ac_cv_header_sys_types_h = yes; then
  48     HAVE_SYS_TYPES_H=1
  49   else
  50     HAVE_SYS_TYPES_H=0
  51   fi
  52   AC_SUBST([HAVE_SYS_TYPES_H])
  53
  54   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_stdint_h.
  55   if test $ac_cv_header_stdint_h = yes; then
  56     gl_ABSOLUTE_HEADER([stdint.h])
  57     ABSOLUTE_STDINT_H=\"$gl_cv_absolute_stdint_h\"
  58     HAVE_STDINT_H=1
  59   else
  60     ABSOLUTE_STDINT_H=\"no/such/file/stdint.h\"
  61     HAVE_STDINT_H=0
  62   fi
  63   AC_SUBST([ABSOLUTE_STDINT_H])
  64   AC_SUBST([HAVE_STDINT_H])
  65
  66   dnl Now see whether we need a substitute <stdint.h>.  Use
  67   dnl ABSOLUTE_STDINT_H, not <stdint.h>, so that it also works during
  68   dnl a "config.status --recheck" if a stdint.h has been
  69   dnl created in the build directory.
  70   if test $ac_cv_header_stdint_h = yes; then
  71     AC_CACHE_CHECK([whether stdint.h conforms to C99],
  72       [gl_cv_header_working_stdint_h],
  73       [gl_cv_header_working_stdint_h=no
  74        AC_COMPILE_IFELSE([
  75          AC_LANG_PROGRAM([[
  76 #include <stddef.h>
  77 #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
  78 #define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */
  79 #include ABSOLUTE_STDINT_H
  80 #ifdef INT8_MAX
  81 int8_t a1 = INT8_MAX;
  82 int8_t a1min = INT8_MIN;
  83 #endif
  84 #ifdef INT16_MAX
  85 int16_t a2 = INT16_MAX;
  86 int16_t a2min = INT16_MIN;
  87 #endif
  88 #ifdef INT32_MAX
  89 int32_t a3 = INT32_MAX;
  90 int32_t a3min = INT32_MIN;
  91 #endif
  92 #ifdef INT64_MAX
  93 int64_t a4 = INT64_MAX;
  94 int64_t a4min = INT64_MIN;
  95 #endif
  96 #ifdef UINT8_MAX
  97 uint8_t b1 = UINT8_MAX;
  98 #else
  99 typedef int b1[(unsigned char) -1 != 255 ? 1 : -1];
 100 #endif
 101 #ifdef UINT16_MAX
 102 uint16_t b2 = UINT16_MAX;
 103 #endif
 104 #ifdef UINT32_MAX
 105 uint32_t b3 = UINT32_MAX;
 106 #endif
 107 #ifdef UINT64_MAX
 108 uint64_t b4 = UINT64_MAX;
 109 #endif
 110 int_least8_t c1 = INT8_C (0x7f);
 111 int_least8_t c1max = INT_LEAST8_MAX;
 112 int_least8_t c1min = INT_LEAST8_MIN;
 113 int_least16_t c2 = INT16_C (0x7fff);
 114 int_least16_t c2max = INT_LEAST16_MAX;
 115 int_least16_t c2min = INT_LEAST16_MIN;
 116 int_least32_t c3 = INT32_C (0x7fffffff);
 117 int_least32_t c3max = INT_LEAST32_MAX;
 118 int_least32_t c3min = INT_LEAST32_MIN;
 119 int_least64_t c4 = INT64_C (0x7fffffffffffffff);
 120 int_least64_t c4max = INT_LEAST64_MAX;
 121 int_least64_t c4min = INT_LEAST64_MIN;
 122 uint_least8_t d1 = UINT8_C (0xff);
 123 uint_least8_t d1max = UINT_LEAST8_MAX;
 124 uint_least16_t d2 = UINT16_C (0xffff);
 125 uint_least16_t d2max = UINT_LEAST16_MAX;
 126 uint_least32_t d3 = UINT32_C (0xffffffff);
 127 uint_least32_t d3max = UINT_LEAST32_MAX;
 128 uint_least64_t d4 = UINT64_C (0xffffffffffffffff);
 129 uint_least64_t d4max = UINT_LEAST64_MAX;
 130 int_fast8_t e1 = INT_FAST8_MAX;
 131 int_fast8_t e1min = INT_FAST8_MIN;
 132 int_fast16_t e2 = INT_FAST16_MAX;
 133 int_fast16_t e2min = INT_FAST16_MIN;
 134 int_fast32_t e3 = INT_FAST32_MAX;
 135 int_fast32_t e3min = INT_FAST32_MIN;
 136 int_fast64_t e4 = INT_FAST64_MAX;
 137 int_fast64_t e4min = INT_FAST64_MIN;
 138 uint_fast8_t f1 = UINT_FAST8_MAX;
 139 uint_fast16_t f2 = UINT_FAST16_MAX;
 140 uint_fast32_t f3 = UINT_FAST32_MAX;
 141 uint_fast64_t f4 = UINT_FAST64_MAX;
 142 #ifdef INTPTR_MAX
 143 intptr_t g = INTPTR_MAX;
 144 intptr_t gmin = INTPTR_MIN;
 145 #endif
 146 #ifdef UINTPTR_MAX
 147 uintptr_t h = UINTPTR_MAX;
 148 #endif
 149 intmax_t i = INTMAX_MAX;
 150 uintmax_t j = UINTMAX_MAX;
 151 struct s {
 152   int check_PTRDIFF: PTRDIFF_MIN < 0 && 0 < PTRDIFF_MAX ? 1 : -1;
 153   int check_SIG_ATOMIC: SIG_ATOMIC_MIN <= 0 && 0 < SIG_ATOMIC_MAX ? 1 : -1;
 154   int check_SIZE: 0 < SIZE_MAX ? 1 : -1;
 155   int check_WCHAR: WCHAR_MIN <= 0 && 0 < WCHAR_MAX ? 1 : -1;
 156   int check_WINT: WINT_MIN <= 0 && 0 < WINT_MAX ? 1 : -1;
 157
 158   /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others.  */
 159   int check_UINT8_C:
 160         (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1;
 161   int check_UINT16_C:
 162         (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1;
 163
 164   /* Detect bugs in OpenBSD 3.9 stdint.h.  */
 165 #ifdef UINT8_MAX
 166   int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1;
 167 #endif
 168 #ifdef UINT16_MAX
 169   int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1;
 170 #endif
 171 #ifdef UINT32_MAX
 172   int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1;
 173 #endif
 174 #ifdef UINT64_MAX
 175   int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1;
 176 #endif
 177   int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1;
 178   int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1;
 179   int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1;
 180   int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1;
 181   int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1;
 182   int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1;
 183   int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1;
 184   int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1;
 185   int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1;
 186   int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1;
 187   int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1;
 188 };
 189          ]])],
 190          [gl_cv_header_working_stdint_h=yes])])
 191   fi
 192   if test "$gl_cv_header_working_stdint_h" != yes; then
 193
 194     dnl Check for <sys/inttypes.h>, and for
 195     dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
 196     AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h])
 197     if test $ac_cv_header_sys_inttypes_h = yes; then
 198       HAVE_SYS_INTTYPES_H=1
 199     else
 200       HAVE_SYS_INTTYPES_H=0
 201     fi
 202     AC_SUBST([HAVE_SYS_INTTYPES_H])
 203     if test $ac_cv_header_sys_bitypes_h = yes; then
 204       HAVE_SYS_BITYPES_H=1
 205     else
 206       HAVE_SYS_BITYPES_H=0
 207     fi
 208     AC_SUBST([HAVE_SYS_BITYPES_H])
 209
 210     gl_STDINT_TYPE_PROPERTIES
 211     STDINT_H=stdint.h
 212   fi
 213   AC_SUBST(STDINT_H)
 214 ])
 215
 216 dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES)
 217 dnl Determine the size of each of the given types in bits.
 218 AC_DEFUN([gl_STDINT_BITSIZEOF],
 219 [
 220   dnl Use a shell loop, to avoid bloating configure, and
 221   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 222   dnl   config.h.in,
 223   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 224   AC_FOREACH([gltype], [$1],
 225     [AH_TEMPLATE([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 226        [Define to the number of bits in type ']gltype['.])])
 227   for gltype in $1 ; do
 228     AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}],
 229       [_AC_COMPUTE_INT([sizeof ($gltype) * CHAR_BIT], result,
 230          [$2
 231 #include <limits.h>], [result=unknown])
 232        eval gl_cv_bitsizeof_${gltype}=\$result
 233       ])
 234     eval result=\$gl_cv_bitsizeof_${gltype}
 235     if test $result = unknown; then
 236       dnl Use a nonempty default, because some compilers, such as IRIX 5 cc,
 237       dnl do a syntax check even on unused #if conditions and give an error
 238       dnl on valid C code like this:
 239       dnl   #if 0
 240       dnl   # if  > 32
 241       dnl   # endif
 242       dnl   #endif
 243       result=0
 244     fi
 245     GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 246     AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result])
 247     eval BITSIZEOF_${GLTYPE}=\$result
 248   done
 249   AC_FOREACH([gltype], [$1],
 250     [AC_SUBST([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 251 ])
 252
 253 dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES)
 254 dnl Determine the signedness of each of the given types.
 255 dnl Define HAVE_SIGNED_TYPE if type is signed.
 256 AC_DEFUN([gl_CHECK_TYPES_SIGNED],
 257 [
 258   dnl Use a shell loop, to avoid bloating configure, and
 259   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 260   dnl   config.h.in,
 261   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 262   AC_FOREACH([gltype], [$1],
 263     [AH_TEMPLATE([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 264        [Define to 1 if ']gltype[' is a signed integer type.])])
 265   for gltype in $1 ; do
 266     AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed],
 267       [AC_COMPILE_IFELSE(
 268          [AC_LANG_PROGRAM([$2[
 269             int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])],
 270          result=yes, result=no)
 271        eval gl_cv_type_${gltype}_signed=\$result
 272       ])
 273     eval result=\$gl_cv_type_${gltype}_signed
 274     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 275     if test "$result" = yes; then
 276       AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], 1)
 277       eval HAVE_SIGNED_${GLTYPE}=1
 278     else
 279       eval HAVE_SIGNED_${GLTYPE}=0
 280     fi
 281   done
 282   AC_FOREACH([gltype], [$1],
 283     [AC_SUBST([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 284 ])
 285
 286 dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES)
 287 dnl Determine the suffix to use for integer constants of the given types.
 288 dnl Define t_SUFFIX for each such type.
 289 AC_DEFUN([gl_INTEGER_TYPE_SUFFIX],
 290 [
 291   dnl Use a shell loop, to avoid bloating configure, and
 292   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 293   dnl   config.h.in,
 294   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 295   AC_FOREACH([gltype], [$1],
 296     [AH_TEMPLATE(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX],
 297        [Define to l, ll, u, ul, ull, etc., as suitable for
 298         constants of type ']gltype['.])])
 299   for gltype in $1 ; do
 300     AC_CACHE_CHECK([for $gltype integer literal suffix],
 301       [gl_cv_type_${gltype}_suffix],
 302       [eval gl_cv_type_${gltype}_suffix=no
 303        eval result=\$gl_cv_type_${gltype}_signed
 304        if test "$result" = yes; then
 305          glsufu=
 306        else
 307          glsufu=u
 308        fi
 309        for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do
 310          case $glsuf in
 311            '')  gltype1='int';;
 312            l)   gltype1='long int';;
 313            ll)  gltype1='long long int';;
 314            i64) gltype1='__int64';;
 315            u)   gltype1='unsigned int';;
 316            ul)  gltype1='unsigned long int';;
 317            ull) gltype1='unsigned long long int';;
 318            ui64)gltype1='unsigned __int64';;
 319          esac
 320          AC_COMPILE_IFELSE(
 321            [AC_LANG_PROGRAM([$2
 322               extern $gltype foo;
 323               extern $gltype1 foo;])],
 324            [eval gl_cv_type_${gltype}_suffix=\$glsuf])
 325          eval result=\$gl_cv_type_${gltype}_suffix
 326          test "$result" != no && break
 327        done])
 328     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 329     eval result=\$gl_cv_type_${gltype}_suffix
 330     test "$result" = no && result=
 331     eval ${GLTYPE}_SUFFIX=\$result
 332     AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], $result)
 333   done
 334   AC_FOREACH([gltype], [$1],
 335     [AC_SUBST(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])])
 336 ])
 337
 338 dnl gl_STDINT_INCLUDES
 339 AC_DEFUN([gl_STDINT_INCLUDES],
 340 [[
 341   #include <stddef.h>
 342   #include <signal.h>
 343   #if HAVE_WCHAR_H
 344     /* BSD/OS 4.1 has a bug: <stdio.h> and <time.h> must be included before
 345        <wchar.h>.  */
 346   # include <stdio.h>
 347   # include <time.h>
 348   # include <wchar.h>
 349   #endif
 350 ]])
 351
 352 dnl gl_STDINT_TYPE_PROPERTIES
 353 dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t
 354 dnl of interest to stdint_.h.
 355 AC_DEFUN([gl_STDINT_TYPE_PROPERTIES],
 356 [
 357   gl_STDINT_BITSIZEOF([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
 358     [gl_STDINT_INCLUDES])
 359   gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t],
 360     [gl_STDINT_INCLUDES])
 361   gl_cv_type_ptrdiff_t_signed=yes
 362   gl_cv_type_size_t_signed=no
 363   gl_INTEGER_TYPE_SUFFIX([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
 364     [gl_STDINT_INCLUDES])
 365 ])