m4/stdint.m4

   1 # stdint.m4 serial 37
   2 dnl Copyright (C) 2001-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert and Bruno Haible.
   8 dnl Test whether <stdint.h> is supported or must be substituted.
   9
  10 AC_DEFUN([gl_STDINT_H],
  11 [
  12   AC_PREREQ([2.59])dnl
  13
  14   dnl Check for long long int and unsigned long long int.
  15   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  16   if test $ac_cv_type_long_long_int = yes; then
  17     HAVE_LONG_LONG_INT=1
  18   else
  19     HAVE_LONG_LONG_INT=0
  20   fi
  21   AC_SUBST([HAVE_LONG_LONG_INT])
  22   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  23   if test $ac_cv_type_unsigned_long_long_int = yes; then
  24     HAVE_UNSIGNED_LONG_LONG_INT=1
  25   else
  26     HAVE_UNSIGNED_LONG_LONG_INT=0
  27   fi
  28   AC_SUBST([HAVE_UNSIGNED_LONG_LONG_INT])
  29
  30   dnl Check for <inttypes.h>.
  31   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
  32   if test $ac_cv_header_inttypes_h = yes; then
  33     HAVE_INTTYPES_H=1
  34   else
  35     HAVE_INTTYPES_H=0
  36   fi
  37   AC_SUBST([HAVE_INTTYPES_H])
  38
  39   dnl Check for <sys/types.h>.
  40   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h.
  41   if test $ac_cv_header_sys_types_h = yes; then
  42     HAVE_SYS_TYPES_H=1
  43   else
  44     HAVE_SYS_TYPES_H=0
  45   fi
  46   AC_SUBST([HAVE_SYS_TYPES_H])
  47
  48   gl_CHECK_NEXT_HEADERS([stdint.h])
  49   if test $ac_cv_header_stdint_h = yes; then
  50     HAVE_STDINT_H=1
  51   else
  52     HAVE_STDINT_H=0
  53   fi
  54   AC_SUBST([HAVE_STDINT_H])
  55
  56   dnl Now see whether we need a substitute <stdint.h>.
  57   if test $ac_cv_header_stdint_h = yes; then
  58     AC_CACHE_CHECK([whether stdint.h conforms to C99],
  59       [gl_cv_header_working_stdint_h],
  60       [gl_cv_header_working_stdint_h=no
  61        AC_COMPILE_IFELSE([
  62          AC_LANG_PROGRAM([[
  63 #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
  64 #define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */
  65 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
  66 #include <stdint.h>
  67 /* Dragonfly defines WCHAR_MIN, WCHAR_MAX only in <wchar.h>.  */
  68 #if !(defined WCHAR_MIN && defined WCHAR_MAX)
  69 #error "WCHAR_MIN, WCHAR_MAX not defined in <stdint.h>"
  70 #endif
  71 ]
  72 gl_STDINT_INCLUDES
  73 [
  74 #ifdef INT8_MAX
  75 int8_t a1 = INT8_MAX;
  76 int8_t a1min = INT8_MIN;
  77 #endif
  78 #ifdef INT16_MAX
  79 int16_t a2 = INT16_MAX;
  80 int16_t a2min = INT16_MIN;
  81 #endif
  82 #ifdef INT32_MAX
  83 int32_t a3 = INT32_MAX;
  84 int32_t a3min = INT32_MIN;
  85 #endif
  86 #ifdef INT64_MAX
  87 int64_t a4 = INT64_MAX;
  88 int64_t a4min = INT64_MIN;
  89 #endif
  90 #ifdef UINT8_MAX
  91 uint8_t b1 = UINT8_MAX;
  92 #else
  93 typedef int b1[(unsigned char) -1 != 255 ? 1 : -1];
  94 #endif
  95 #ifdef UINT16_MAX
  96 uint16_t b2 = UINT16_MAX;
  97 #endif
  98 #ifdef UINT32_MAX
  99 uint32_t b3 = UINT32_MAX;
 100 #endif
 101 #ifdef UINT64_MAX
 102 uint64_t b4 = UINT64_MAX;
 103 #endif
 104 int_least8_t c1 = INT8_C (0x7f);
 105 int_least8_t c1max = INT_LEAST8_MAX;
 106 int_least8_t c1min = INT_LEAST8_MIN;
 107 int_least16_t c2 = INT16_C (0x7fff);
 108 int_least16_t c2max = INT_LEAST16_MAX;
 109 int_least16_t c2min = INT_LEAST16_MIN;
 110 int_least32_t c3 = INT32_C (0x7fffffff);
 111 int_least32_t c3max = INT_LEAST32_MAX;
 112 int_least32_t c3min = INT_LEAST32_MIN;
 113 int_least64_t c4 = INT64_C (0x7fffffffffffffff);
 114 int_least64_t c4max = INT_LEAST64_MAX;
 115 int_least64_t c4min = INT_LEAST64_MIN;
 116 uint_least8_t d1 = UINT8_C (0xff);
 117 uint_least8_t d1max = UINT_LEAST8_MAX;
 118 uint_least16_t d2 = UINT16_C (0xffff);
 119 uint_least16_t d2max = UINT_LEAST16_MAX;
 120 uint_least32_t d3 = UINT32_C (0xffffffff);
 121 uint_least32_t d3max = UINT_LEAST32_MAX;
 122 uint_least64_t d4 = UINT64_C (0xffffffffffffffff);
 123 uint_least64_t d4max = UINT_LEAST64_MAX;
 124 int_fast8_t e1 = INT_FAST8_MAX;
 125 int_fast8_t e1min = INT_FAST8_MIN;
 126 int_fast16_t e2 = INT_FAST16_MAX;
 127 int_fast16_t e2min = INT_FAST16_MIN;
 128 int_fast32_t e3 = INT_FAST32_MAX;
 129 int_fast32_t e3min = INT_FAST32_MIN;
 130 int_fast64_t e4 = INT_FAST64_MAX;
 131 int_fast64_t e4min = INT_FAST64_MIN;
 132 uint_fast8_t f1 = UINT_FAST8_MAX;
 133 uint_fast16_t f2 = UINT_FAST16_MAX;
 134 uint_fast32_t f3 = UINT_FAST32_MAX;
 135 uint_fast64_t f4 = UINT_FAST64_MAX;
 136 #ifdef INTPTR_MAX
 137 intptr_t g = INTPTR_MAX;
 138 intptr_t gmin = INTPTR_MIN;
 139 #endif
 140 #ifdef UINTPTR_MAX
 141 uintptr_t h = UINTPTR_MAX;
 142 #endif
 143 intmax_t i = INTMAX_MAX;
 144 uintmax_t j = UINTMAX_MAX;
 145
 146 #include <limits.h> /* for CHAR_BIT */
 147 #define TYPE_MINIMUM(t) \
 148   ((t) ((t) 0 < (t) -1 ? (t) 0 : ~ TYPE_MAXIMUM (t)))
 149 #define TYPE_MAXIMUM(t) \
 150   ((t) ((t) 0 < (t) -1 \
 151         ? (t) -1 \
 152         : ((((t) 1 << (sizeof (t) * CHAR_BIT - 2)) - 1) * 2 + 1)))
 153 struct s {
 154   int check_PTRDIFF:
 155       PTRDIFF_MIN == TYPE_MINIMUM (ptrdiff_t)
 156       && PTRDIFF_MAX == TYPE_MAXIMUM (ptrdiff_t)
 157       ? 1 : -1;
 158   /* Detect bug in FreeBSD 6.0 / ia64.  */
 159   int check_SIG_ATOMIC:
 160       SIG_ATOMIC_MIN == TYPE_MINIMUM (sig_atomic_t)
 161       && SIG_ATOMIC_MAX == TYPE_MAXIMUM (sig_atomic_t)
 162       ? 1 : -1;
 163   int check_SIZE: SIZE_MAX == TYPE_MAXIMUM (size_t) ? 1 : -1;
 164   int check_WCHAR:
 165       WCHAR_MIN == TYPE_MINIMUM (wchar_t)
 166       && WCHAR_MAX == TYPE_MAXIMUM (wchar_t)
 167       ? 1 : -1;
 168   /* Detect bug in mingw.  */
 169   int check_WINT:
 170       WINT_MIN == TYPE_MINIMUM (wint_t)
 171       && WINT_MAX == TYPE_MAXIMUM (wint_t)
 172       ? 1 : -1;
 173
 174   /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others.  */
 175   int check_UINT8_C:
 176         (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1;
 177   int check_UINT16_C:
 178         (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1;
 179
 180   /* Detect bugs in OpenBSD 3.9 stdint.h.  */
 181 #ifdef UINT8_MAX
 182   int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1;
 183 #endif
 184 #ifdef UINT16_MAX
 185   int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1;
 186 #endif
 187 #ifdef UINT32_MAX
 188   int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1;
 189 #endif
 190 #ifdef UINT64_MAX
 191   int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1;
 192 #endif
 193   int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1;
 194   int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1;
 195   int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1;
 196   int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1;
 197   int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1;
 198   int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1;
 199   int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1;
 200   int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1;
 201   int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1;
 202   int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1;
 203   int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1;
 204 };
 205          ]])],
 206          [dnl Determine whether the various *_MIN, *_MAX macros are usable
 207           dnl in preprocessor expression. We could do it by compiling a test
 208           dnl program for each of these macros. It is faster to run a program
 209           dnl that inspects the macro expansion.
 210           dnl This detects a bug on HP-UX 11.23/ia64.
 211           AC_RUN_IFELSE([
 212             AC_LANG_PROGRAM([[
 213 #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
 214 #define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */
 215 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
 216 #include <stdint.h>
 217 ]
 218 gl_STDINT_INCLUDES
 219 [
 220 #include <stdio.h>
 221 #include <string.h>
 222 #define MVAL(macro) MVAL1(macro)
 223 #define MVAL1(expression) #expression
 224 static const char *macro_values[] =
 225   {
 226 #ifdef INT8_MAX
 227     MVAL (INT8_MAX),
 228 #endif
 229 #ifdef INT16_MAX
 230     MVAL (INT16_MAX),
 231 #endif
 232 #ifdef INT32_MAX
 233     MVAL (INT32_MAX),
 234 #endif
 235 #ifdef INT64_MAX
 236     MVAL (INT64_MAX),
 237 #endif
 238 #ifdef UINT8_MAX
 239     MVAL (UINT8_MAX),
 240 #endif
 241 #ifdef UINT16_MAX
 242     MVAL (UINT16_MAX),
 243 #endif
 244 #ifdef UINT32_MAX
 245     MVAL (UINT32_MAX),
 246 #endif
 247 #ifdef UINT64_MAX
 248     MVAL (UINT64_MAX),
 249 #endif
 250     NULL
 251   };
 252 ]], [[
 253   const char **mv;
 254   for (mv = macro_values; *mv != NULL; mv++)
 255     {
 256       const char *value = *mv;
 257       /* Test whether it looks like a cast expression.  */
 258       if (strncmp (value, "((unsigned int)"/*)*/, 15) == 0
 259           || strncmp (value, "((unsigned short)"/*)*/, 17) == 0
 260           || strncmp (value, "((unsigned char)"/*)*/, 16) == 0
 261           || strncmp (value, "((int)"/*)*/, 6) == 0
 262           || strncmp (value, "((signed short)"/*)*/, 15) == 0
 263           || strncmp (value, "((signed char)"/*)*/, 14) == 0)
 264         return mv - macro_values + 1;
 265     }
 266   return 0;
 267 ]])],
 268               [gl_cv_header_working_stdint_h=yes],
 269               [],
 270               [dnl When cross-compiling, assume it works.
 271                gl_cv_header_working_stdint_h=yes
 272               ])
 273          ])
 274       ])
 275   fi
 276   if test "$gl_cv_header_working_stdint_h" = yes; then
 277     STDINT_H=
 278   else
 279     dnl Check for <sys/inttypes.h>, and for
 280     dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
 281     AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h])
 282     if test $ac_cv_header_sys_inttypes_h = yes; then
 283       HAVE_SYS_INTTYPES_H=1
 284     else
 285       HAVE_SYS_INTTYPES_H=0
 286     fi
 287     AC_SUBST([HAVE_SYS_INTTYPES_H])
 288     if test $ac_cv_header_sys_bitypes_h = yes; then
 289       HAVE_SYS_BITYPES_H=1
 290     else
 291       HAVE_SYS_BITYPES_H=0
 292     fi
 293     AC_SUBST([HAVE_SYS_BITYPES_H])
 294
 295     dnl Check for <wchar.h> (missing in Linux uClibc when built without wide
 296     dnl character support).
 297     AC_CHECK_HEADERS_ONCE([wchar.h])
 298
 299     gl_STDINT_TYPE_PROPERTIES
 300     STDINT_H=stdint.h
 301   fi
 302   AC_SUBST([STDINT_H])
 303 ])
 304
 305 dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES)
 306 dnl Determine the size of each of the given types in bits.
 307 AC_DEFUN([gl_STDINT_BITSIZEOF],
 308 [
 309   dnl Use a shell loop, to avoid bloating configure, and
 310   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 311   dnl   config.h.in,
 312   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 313   m4_foreach_w([gltype], [$1],
 314     [AH_TEMPLATE([BITSIZEOF_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 315        [Define to the number of bits in type ']gltype['.])])
 316   for gltype in $1 ; do
 317     AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}],
 318       [AC_COMPUTE_INT([result], [sizeof ($gltype) * CHAR_BIT],
 319          [$2
 320 #include <limits.h>], [result=unknown])
 321        eval gl_cv_bitsizeof_${gltype}=\$result
 322       ])
 323     eval result=\$gl_cv_bitsizeof_${gltype}
 324     if test $result = unknown; then
 325       dnl Use a nonempty default, because some compilers, such as IRIX 5 cc,
 326       dnl do a syntax check even on unused #if conditions and give an error
 327       dnl on valid C code like this:
 328       dnl   #if 0
 329       dnl   # if  > 32
 330       dnl   # endif
 331       dnl   #endif
 332       result=0
 333     fi
 334     GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 335     AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result])
 336     eval BITSIZEOF_${GLTYPE}=\$result
 337   done
 338   m4_foreach_w([gltype], [$1],
 339     [AC_SUBST([BITSIZEOF_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 340 ])
 341
 342 dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES)
 343 dnl Determine the signedness of each of the given types.
 344 dnl Define HAVE_SIGNED_TYPE if type is signed.
 345 AC_DEFUN([gl_CHECK_TYPES_SIGNED],
 346 [
 347   dnl Use a shell loop, to avoid bloating configure, and
 348   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 349   dnl   config.h.in,
 350   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 351   m4_foreach_w([gltype], [$1],
 352     [AH_TEMPLATE([HAVE_SIGNED_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 353        [Define to 1 if ']gltype[' is a signed integer type.])])
 354   for gltype in $1 ; do
 355     AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed],
 356       [AC_COMPILE_IFELSE(
 357          [AC_LANG_PROGRAM([$2[
 358             int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])],
 359          result=yes, result=no)
 360        eval gl_cv_type_${gltype}_signed=\$result
 361       ])
 362     eval result=\$gl_cv_type_${gltype}_signed
 363     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 364     if test "$result" = yes; then
 365       AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], [1])
 366       eval HAVE_SIGNED_${GLTYPE}=1
 367     else
 368       eval HAVE_SIGNED_${GLTYPE}=0
 369     fi
 370   done
 371   m4_foreach_w([gltype], [$1],
 372     [AC_SUBST([HAVE_SIGNED_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 373 ])
 374
 375 dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES)
 376 dnl Determine the suffix to use for integer constants of the given types.
 377 dnl Define t_SUFFIX for each such type.
 378 AC_DEFUN([gl_INTEGER_TYPE_SUFFIX],
 379 [
 380   dnl Use a shell loop, to avoid bloating configure, and
 381   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 382   dnl   config.h.in,
 383   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 384   m4_foreach_w([gltype], [$1],
 385     [AH_TEMPLATE(m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX],
 386        [Define to l, ll, u, ul, ull, etc., as suitable for
 387         constants of type ']gltype['.])])
 388   for gltype in $1 ; do
 389     AC_CACHE_CHECK([for $gltype integer literal suffix],
 390       [gl_cv_type_${gltype}_suffix],
 391       [eval gl_cv_type_${gltype}_suffix=no
 392        eval result=\$gl_cv_type_${gltype}_signed
 393        if test "$result" = yes; then
 394          glsufu=
 395        else
 396          glsufu=u
 397        fi
 398        for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do
 399          case $glsuf in
 400            '')  gltype1='int';;
 401            l)   gltype1='long int';;
 402            ll)  gltype1='long long int';;
 403            i64) gltype1='__int64';;
 404            u)   gltype1='unsigned int';;
 405            ul)  gltype1='unsigned long int';;
 406            ull) gltype1='unsigned long long int';;
 407            ui64)gltype1='unsigned __int64';;
 408          esac
 409          AC_COMPILE_IFELSE(
 410            [AC_LANG_PROGRAM([$2[
 411               extern $gltype foo;
 412               extern $gltype1 foo;]])],
 413            [eval gl_cv_type_${gltype}_suffix=\$glsuf])
 414          eval result=\$gl_cv_type_${gltype}_suffix
 415          test "$result" != no && break
 416        done])
 417     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 418     eval result=\$gl_cv_type_${gltype}_suffix
 419     test "$result" = no && result=
 420     eval ${GLTYPE}_SUFFIX=\$result
 421     AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], [$result])
 422   done
 423   m4_foreach_w([gltype], [$1],
 424     [AC_SUBST(m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])])
 425 ])
 426
 427 dnl gl_STDINT_INCLUDES
 428 AC_DEFUN([gl_STDINT_INCLUDES],
 429 [[
 430   /* BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
 431      included before <wchar.h>.  */
 432   #include <stddef.h>
 433   #include <signal.h>
 434   #if HAVE_WCHAR_H
 435   # include <stdio.h>
 436   # include <time.h>
 437   # include <wchar.h>
 438   #endif
 439 ]])
 440
 441 dnl gl_STDINT_TYPE_PROPERTIES
 442 dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t
 443 dnl of interest to stdint.in.h.
 444 AC_DEFUN([gl_STDINT_TYPE_PROPERTIES],
 445 [
 446   AC_REQUIRE([gl_MULTIARCH])
 447   if test $APPLE_UNIVERSAL_BUILD = 0; then
 448     gl_STDINT_BITSIZEOF([ptrdiff_t size_t],
 449       [gl_STDINT_INCLUDES])
 450   fi
 451   gl_STDINT_BITSIZEOF([sig_atomic_t wchar_t wint_t],
 452     [gl_STDINT_INCLUDES])
 453   gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t],
 454     [gl_STDINT_INCLUDES])
 455   gl_cv_type_ptrdiff_t_signed=yes
 456   gl_cv_type_size_t_signed=no
 457   if test $APPLE_UNIVERSAL_BUILD = 0; then
 458     gl_INTEGER_TYPE_SUFFIX([ptrdiff_t size_t],
 459       [gl_STDINT_INCLUDES])
 460   fi
 461   gl_INTEGER_TYPE_SUFFIX([sig_atomic_t wchar_t wint_t],
 462     [gl_STDINT_INCLUDES])
 463 ])
 464
 465 dnl Autoconf >= 2.61 has AC_COMPUTE_INT built-in.
 466 dnl Remove this when we can assume autoconf >= 2.61.
 467 m4_ifdef([AC_COMPUTE_INT], [], [
 468   AC_DEFUN([AC_COMPUTE_INT], [_AC_COMPUTE_INT([$2],[$1],[$3],[$4])])
 469 ])
 470
 471 # Hey Emacs!
 472 # Local Variables:
 473 # indent-tabs-mode: nil
 474 # End: