m4/stdint.m4

   1 # stdint.m4 serial 13
   2 dnl Copyright (C) 2001-2002, 2004-2006 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert and Bruno Haible.
   8 dnl Test whether <stdint.h> is supported or must be substituted.
   9
  10 AC_DEFUN([gl_STDINT_H],
  11 [
  12   AC_PREREQ(2.59)dnl
  13
  14   dnl Check for long long int.
  15   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  16   if test $ac_cv_type_long_long_int = yes; then
  17     HAVE_LONG_LONG_INT=1
  18   else
  19     HAVE_LONG_LONG_INT=0
  20   fi
  21   AC_SUBST([HAVE_LONG_LONG_INT])
  22
  23   dnl Check for <wchar.h>.
  24   AC_CHECK_HEADERS_ONCE([wchar.h])
  25   if test $ac_cv_header_wchar_h = yes; then
  26     HAVE_WCHAR_H=1
  27   else
  28     HAVE_WCHAR_H=0
  29   fi
  30   AC_SUBST([HAVE_WCHAR_H])
  31
  32   dnl Check for <inttypes.h>.
  33   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
  34   if test $ac_cv_header_inttypes_h = yes; then
  35     HAVE_INTTYPES_H=1
  36   else
  37     HAVE_INTTYPES_H=0
  38   fi
  39   AC_SUBST([HAVE_INTTYPES_H])
  40
  41   dnl Check for <sys/types.h>.
  42   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h.
  43   if test $ac_cv_header_sys_types_h = yes; then
  44     HAVE_SYS_TYPES_H=1
  45   else
  46     HAVE_SYS_TYPES_H=0
  47   fi
  48   AC_SUBST([HAVE_SYS_TYPES_H])
  49
  50   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_stdint_h.
  51   if test $ac_cv_header_stdint_h = yes; then
  52     gl_FULL_HEADER_PATH([stdint.h])
  53     FULL_PATH_STDINT_H="<$gl_cv_full_path_stdint_h>"
  54     AC_SUBST([FULL_PATH_STDINT_H])
  55     HAVE_STDINT_H=1
  56   else
  57     HAVE_STDINT_H=0
  58   fi
  59   AC_SUBST([HAVE_STDINT_H])
  60
  61   dnl Now see whether we need a substitute <stdint.h>.  Use
  62   dnl FULL_PATH_STDINT_H, not <stdint.h>, so that it also works during
  63   dnl a "config.status --recheck" if a stdint.h has been
  64   dnl created in the build directory.
  65   if test $ac_cv_header_stdint_h = yes; then
  66     AC_CACHE_CHECK([whether stdint.h conforms to C99],
  67       [gl_cv_header_working_stdint_h],
  68       [gl_cv_header_working_stdint_h=no
  69        AC_COMPILE_IFELSE([
  70          AC_LANG_PROGRAM([[
  71 #include <stddef.h>
  72 #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
  73 #include FULL_PATH_STDINT_H
  74 #ifdef INT8_MAX
  75 int8_t a1 = INT8_MAX;
  76 #endif
  77 #ifdef INT16_MAX
  78 int16_t a2 = INT16_MAX;
  79 #endif
  80 #ifdef INT32_MAX
  81 int32_t a3 = INT32_MAX;
  82 #endif
  83 #ifdef INT64_MAX
  84 int64_t a4 = INT64_MAX;
  85 #endif
  86 #ifdef UINT8_MAX
  87 uint8_t b1 = UINT8_MAX;
  88 #else
  89 typedef int b1[(unsigned char) -1 != 255 ? 1 : -1];
  90 #endif
  91 #ifdef UINT16_MAX
  92 uint16_t b2 = UINT16_MAX;
  93 #endif
  94 #ifdef UINT32_MAX
  95 uint32_t b3 = UINT32_MAX;
  96 #endif
  97 #ifdef UINT64_MAX
  98 uint64_t b4 = UINT64_MAX;
  99 #endif
 100 int_least8_t c1 = INT8_C (0x7f);
 101 int_least16_t c2 = INT16_C (0x7fff);
 102 int_least32_t c3 = INT32_C (0x7fffffff);
 103 int_least64_t c4 = INT64_C (0x7fffffffffffffff);
 104 uint_least8_t d1 = UINT8_C (0xff);
 105 uint_least16_t d2 = UINT16_C (0xffff);
 106 uint_least32_t d3 = UINT32_C (0xffffffff);
 107 uint_least64_t d4 = UINT64_C (0xffffffffffffffff);
 108 int_fast8_t e1 = INT_FAST8_MAX;
 109 int_fast16_t e2 = INT_FAST16_MAX;
 110 int_fast32_t e3 = INT_FAST32_MAX;
 111 int_fast64_t e4 = INT_FAST64_MAX;
 112 uint_fast8_t f1 = UINT_FAST8_MAX;
 113 uint_fast16_t f2 = UINT_FAST16_MAX;
 114 uint_fast32_t f3 = UINT_FAST32_MAX;
 115 uint_fast64_t f4 = UINT_FAST64_MAX;
 116 #ifdef INTPTR_MAX
 117 intptr_t g = INTPTR_MAX;
 118 #endif
 119 #ifdef UINTPTR_MAX
 120 uintptr_t h = UINTPTR_MAX;
 121 #endif
 122 intmax_t i = INTMAX_MAX;
 123 uintmax_t j = UINTMAX_MAX;
 124 struct s {
 125   int check_PTRDIFF: PTRDIFF_MIN < 0 && 0 < PTRDIFF_MAX ? 1 : -1;
 126   int check_SIG_ATOMIC: SIG_ATOMIC_MIN <= 0 && 0 < SIG_ATOMIC_MAX ? 1 : -1;
 127   int check_SIZE: 0 < SIZE_MAX ? 1 : -1;
 128   int check_WCHAR: WCHAR_MIN <= 0 && 0 < WCHAR_MAX ? 1 : -1;
 129   int check_WINT: WINT_MIN <= 0 && 0 < WINT_MAX ? 1 : -1;
 130
 131   /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others.  */
 132   int check_UINT8_C:
 133         (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1;
 134   int check_UINT16_C:
 135         (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1;
 136
 137   /* Detect bugs in OpenBSD 3.9 stdint.h.  */
 138 #ifdef UINT8_MAX
 139   int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1;
 140 #endif
 141 #ifdef UINT16_MAX
 142   int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1;
 143 #endif
 144 #ifdef UINT32_MAX
 145   int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1;
 146 #endif
 147 #ifdef UINT64_MAX
 148   int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1;
 149 #endif
 150   int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1;
 151   int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1;
 152   int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1;
 153   int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1;
 154   int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1;
 155   int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1;
 156   int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1;
 157   int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1;
 158   int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1;
 159   int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1;
 160   int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1;
 161 };
 162          ]])],
 163          [gl_cv_header_working_stdint_h=yes])])
 164   fi
 165   if test "$gl_cv_header_working_stdint_h" != yes; then
 166
 167     dnl Check for <sys/inttypes.h>, and for
 168     dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
 169     AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h])
 170     if test $ac_cv_header_sys_inttypes_h = yes; then
 171       HAVE_SYS_INTTYPES_H=1
 172     else
 173       HAVE_SYS_INTTYPES_H=0
 174     fi
 175     AC_SUBST([HAVE_SYS_INTTYPES_H])
 176     if test $ac_cv_header_sys_bitypes_h = yes; then
 177       HAVE_SYS_BITYPES_H=1
 178     else
 179       HAVE_SYS_BITYPES_H=0
 180     fi
 181     AC_SUBST([HAVE_SYS_BITYPES_H])
 182
 183     gl_STDINT_TYPE_PROPERTIES
 184     STDINT_H=stdint.h
 185   fi
 186   AC_SUBST(STDINT_H)
 187 ])
 188
 189 dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES)
 190 dnl Determine the size of each of the given types in bits.
 191 AC_DEFUN([gl_STDINT_BITSIZEOF],
 192 [
 193   dnl Use a shell loop, to avoid bloating configure, and
 194   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 195   dnl   config.h.in,
 196   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 197   AC_FOREACH([gltype], [$1],
 198     [AH_TEMPLATE([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 199        [Define to the number of bits in type ']gltype['.])])
 200   for gltype in $1 ; do
 201     AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}],
 202       [_AC_COMPUTE_INT([sizeof ($gltype) * CHAR_BIT], result,
 203          [$2
 204 #include <limits.h>], [result=unknown])
 205        eval gl_cv_bitsizeof_${gltype}=\$result
 206       ])
 207     eval result=\$gl_cv_bitsizeof_${gltype}
 208     if test $result = unknown; then
 209       dnl Use a nonempty default, because some compilers, such as IRIX 5 cc,
 210       dnl do a syntax check even on unused #if conditions and give an error
 211       dnl on valid C code like this:
 212       dnl   #if 0
 213       dnl   # if  > 32
 214       dnl   # endif
 215       dnl   #endif
 216       result=0
 217     fi
 218     GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 219     AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result])
 220     eval BITSIZEOF_${GLTYPE}=\$result
 221   done
 222   AC_FOREACH([gltype], [$1],
 223     [AC_SUBST([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 224 ])
 225
 226 dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES)
 227 dnl Determine the signedness of each of the given types.
 228 dnl Define HAVE_SIGNED_TYPE if type is signed.
 229 AC_DEFUN([gl_CHECK_TYPES_SIGNED],
 230 [
 231   dnl Use a shell loop, to avoid bloating configure, and
 232   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 233   dnl   config.h.in,
 234   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 235   AC_FOREACH([gltype], [$1],
 236     [AH_TEMPLATE([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 237        [Define to 1 if ']gltype[' is a signed integer type.])])
 238   for gltype in $1 ; do
 239     AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed],
 240       [AC_COMPILE_IFELSE(
 241          [AC_LANG_PROGRAM([$2[
 242             int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])],
 243          result=yes, result=no)
 244        eval gl_cv_type_${gltype}_signed=\$result
 245       ])
 246     eval result=\$gl_cv_type_${gltype}_signed
 247     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 248     if test "$result" = yes; then
 249       AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], 1)
 250       eval HAVE_SIGNED_${GLTYPE}=1
 251     else
 252       eval HAVE_SIGNED_${GLTYPE}=0
 253     fi
 254   done
 255   AC_FOREACH([gltype], [$1],
 256     [AC_SUBST([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 257 ])
 258
 259 dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES)
 260 dnl Determine the suffix to use for integer constants of the given types.
 261 dnl Define t_SUFFIX for each such type.
 262 AC_DEFUN([gl_INTEGER_TYPE_SUFFIX],
 263 [
 264   dnl Use a shell loop, to avoid bloating configure, and
 265   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 266   dnl   config.h.in,
 267   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 268   AC_FOREACH([gltype], [$1],
 269     [AH_TEMPLATE(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX],
 270        [Define to l, ll, u, ul, ull, etc., as suitable for
 271         constants of type ']gltype['.])])
 272   for gltype in $1 ; do
 273     AC_CACHE_CHECK([for $gltype integer literal suffix],
 274       [gl_cv_type_${gltype}_suffix],
 275       [eval gl_cv_type_${gltype}_suffix=no
 276        eval result=\$gl_cv_type_${gltype}_signed
 277        if test "$result" = yes; then
 278          glsufu=
 279        else
 280          glsufu=u
 281        fi
 282        for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do
 283          case $glsuf in
 284            '')  gltype1='int';;
 285            l)   gltype1='long int';;
 286            ll)  gltype1='long long int';;
 287            i64) gltype1='__int64';;
 288            u)   gltype1='unsigned int';;
 289            ul)  gltype1='unsigned long int';;
 290            ull) gltype1='unsigned long long int';;
 291            ui64)gltype1='unsigned __int64';;
 292          esac
 293          AC_COMPILE_IFELSE(
 294            [AC_LANG_PROGRAM([$2
 295               extern $gltype foo;
 296               extern $gltype1 foo;])],
 297            [eval gl_cv_type_${gltype}_suffix=\$glsuf])
 298          eval test \"\$gl_cv_type_${gltype}_suffix\" != no && break
 299        done])
 300     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 301     eval result=\$gl_cv_type_${gltype}_suffix
 302     test "$result" = no && result=
 303     eval ${GLTYPE}_SUFFIX=\$result
 304     AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], $result)
 305   done
 306   AC_FOREACH([gltype], [$1],
 307     [AC_SUBST(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])])
 308 ])
 309
 310 dnl gl_STDINT_INCLUDES
 311 AC_DEFUN([gl_STDINT_INCLUDES],
 312 [[
 313   #include <stddef.h>
 314   #include <signal.h>
 315   #if HAVE_WCHAR_H
 316     /* BSD/OS 4.1 has a bug: <stdio.h> and <time.h> must be included before
 317        <wchar.h>.  */
 318   # include <stdio.h>
 319   # include <time.h>
 320   # include <wchar.h>
 321   #endif
 322 ]])
 323
 324 dnl gl_STDINT_TYPE_PROPERTIES
 325 dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t
 326 dnl of interest to stdint_.h.
 327 AC_DEFUN([gl_STDINT_TYPE_PROPERTIES],
 328 [
 329   gl_STDINT_BITSIZEOF([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
 330     [gl_STDINT_INCLUDES])
 331   gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t],
 332     [gl_STDINT_INCLUDES])
 333   gl_cv_type_ptrdiff_t_signed=yes
 334   gl_cv_type_size_t_signed=no
 335   gl_INTEGER_TYPE_SUFFIX([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
 336     [gl_STDINT_INCLUDES])
 337 ])