m4/stdint.m4

   1 # stdint.m4 serial 18
   2 dnl Copyright (C) 2001-2002, 2004-2006 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Paul Eggert and Bruno Haible.
   8 dnl Test whether <stdint.h> is supported or must be substituted.
   9
  10 AC_DEFUN([gl_STDINT_H],
  11 [
  12   AC_PREREQ(2.59)dnl
  13
  14   dnl Check for long long int.
  15   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
  16   if test $ac_cv_type_long_long_int = yes; then
  17     HAVE_LONG_LONG_INT=1
  18   else
  19     HAVE_LONG_LONG_INT=0
  20   fi
  21   AC_SUBST([HAVE_LONG_LONG_INT])
  22
  23   dnl Check for <wchar.h>.
  24   AC_CHECK_HEADERS_ONCE([wchar.h])
  25   if test $ac_cv_header_wchar_h = yes; then
  26     HAVE_WCHAR_H=1
  27   else
  28     HAVE_WCHAR_H=0
  29   fi
  30   AC_SUBST([HAVE_WCHAR_H])
  31
  32   dnl Check for <inttypes.h>.
  33   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
  34   if test $ac_cv_header_inttypes_h = yes; then
  35     HAVE_INTTYPES_H=1
  36   else
  37     HAVE_INTTYPES_H=0
  38   fi
  39   AC_SUBST([HAVE_INTTYPES_H])
  40
  41   dnl Check for <sys/types.h>.
  42   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h.
  43   if test $ac_cv_header_sys_types_h = yes; then
  44     HAVE_SYS_TYPES_H=1
  45   else
  46     HAVE_SYS_TYPES_H=0
  47   fi
  48   AC_SUBST([HAVE_SYS_TYPES_H])
  49
  50   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_stdint_h.
  51   if test $ac_cv_header_stdint_h = yes; then
  52     gl_ABSOLUTE_HEADER([stdint.h])
  53     ABSOLUTE_STDINT_H=\"$gl_cv_absolute_stdint_h\"
  54     HAVE_STDINT_H=1
  55   else
  56     ABSOLUTE_STDINT_H=\"no/such/file/stdint.h\"
  57     HAVE_STDINT_H=0
  58   fi
  59   AC_SUBST([ABSOLUTE_STDINT_H])
  60   AC_SUBST([HAVE_STDINT_H])
  61
  62   dnl Now see whether we need a substitute <stdint.h>.  Use
  63   dnl ABSOLUTE_STDINT_H, not <stdint.h>, so that it also works during
  64   dnl a "config.status --recheck" if a stdint.h has been
  65   dnl created in the build directory.
  66   if test $ac_cv_header_stdint_h = yes; then
  67     AC_CACHE_CHECK([whether stdint.h conforms to C99],
  68       [gl_cv_header_working_stdint_h],
  69       [gl_cv_header_working_stdint_h=no
  70        AC_COMPILE_IFELSE([
  71          AC_LANG_PROGRAM([[
  72 #include <stddef.h>
  73 #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
  74 #define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */
  75 #include ABSOLUTE_STDINT_H
  76 #ifdef INT8_MAX
  77 int8_t a1 = INT8_MAX;
  78 int8_t a1min = INT8_MIN;
  79 #endif
  80 #ifdef INT16_MAX
  81 int16_t a2 = INT16_MAX;
  82 int16_t a2min = INT16_MIN;
  83 #endif
  84 #ifdef INT32_MAX
  85 int32_t a3 = INT32_MAX;
  86 int32_t a3min = INT32_MIN;
  87 #endif
  88 #ifdef INT64_MAX
  89 int64_t a4 = INT64_MAX;
  90 int64_t a4min = INT64_MIN;
  91 #endif
  92 #ifdef UINT8_MAX
  93 uint8_t b1 = UINT8_MAX;
  94 #else
  95 typedef int b1[(unsigned char) -1 != 255 ? 1 : -1];
  96 #endif
  97 #ifdef UINT16_MAX
  98 uint16_t b2 = UINT16_MAX;
  99 #endif
 100 #ifdef UINT32_MAX
 101 uint32_t b3 = UINT32_MAX;
 102 #endif
 103 #ifdef UINT64_MAX
 104 uint64_t b4 = UINT64_MAX;
 105 #endif
 106 int_least8_t c1 = INT8_C (0x7f);
 107 int_least8_t c1max = INT_LEAST8_MAX;
 108 int_least8_t c1min = INT_LEAST8_MIN;
 109 int_least16_t c2 = INT16_C (0x7fff);
 110 int_least16_t c2max = INT_LEAST16_MAX;
 111 int_least16_t c2min = INT_LEAST16_MIN;
 112 int_least32_t c3 = INT32_C (0x7fffffff);
 113 int_least32_t c3max = INT_LEAST32_MAX;
 114 int_least32_t c3min = INT_LEAST32_MIN;
 115 int_least64_t c4 = INT64_C (0x7fffffffffffffff);
 116 int_least64_t c4max = INT_LEAST64_MAX;
 117 int_least64_t c4min = INT_LEAST64_MIN;
 118 uint_least8_t d1 = UINT8_C (0xff);
 119 uint_least8_t d1max = UINT_LEAST8_MAX;
 120 uint_least16_t d2 = UINT16_C (0xffff);
 121 uint_least16_t d2max = UINT_LEAST16_MAX;
 122 uint_least32_t d3 = UINT32_C (0xffffffff);
 123 uint_least32_t d3max = UINT_LEAST32_MAX;
 124 uint_least64_t d4 = UINT64_C (0xffffffffffffffff);
 125 uint_least64_t d4max = UINT_LEAST64_MAX;
 126 int_fast8_t e1 = INT_FAST8_MAX;
 127 int_fast8_t e1min = INT_FAST8_MIN;
 128 int_fast16_t e2 = INT_FAST16_MAX;
 129 int_fast16_t e2min = INT_FAST16_MIN;
 130 int_fast32_t e3 = INT_FAST32_MAX;
 131 int_fast32_t e3min = INT_FAST32_MIN;
 132 int_fast64_t e4 = INT_FAST64_MAX;
 133 int_fast64_t e4min = INT_FAST64_MIN;
 134 uint_fast8_t f1 = UINT_FAST8_MAX;
 135 uint_fast16_t f2 = UINT_FAST16_MAX;
 136 uint_fast32_t f3 = UINT_FAST32_MAX;
 137 uint_fast64_t f4 = UINT_FAST64_MAX;
 138 #ifdef INTPTR_MAX
 139 intptr_t g = INTPTR_MAX;
 140 intptr_t gmin = INTPTR_MIN;
 141 #endif
 142 #ifdef UINTPTR_MAX
 143 uintptr_t h = UINTPTR_MAX;
 144 #endif
 145 intmax_t i = INTMAX_MAX;
 146 uintmax_t j = UINTMAX_MAX;
 147 struct s {
 148   int check_PTRDIFF: PTRDIFF_MIN < 0 && 0 < PTRDIFF_MAX ? 1 : -1;
 149   int check_SIG_ATOMIC: SIG_ATOMIC_MIN <= 0 && 0 < SIG_ATOMIC_MAX ? 1 : -1;
 150   int check_SIZE: 0 < SIZE_MAX ? 1 : -1;
 151   int check_WCHAR: WCHAR_MIN <= 0 && 0 < WCHAR_MAX ? 1 : -1;
 152   int check_WINT: WINT_MIN <= 0 && 0 < WINT_MAX ? 1 : -1;
 153
 154   /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others.  */
 155   int check_UINT8_C:
 156         (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1;
 157   int check_UINT16_C:
 158         (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1;
 159
 160   /* Detect bugs in OpenBSD 3.9 stdint.h.  */
 161 #ifdef UINT8_MAX
 162   int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1;
 163 #endif
 164 #ifdef UINT16_MAX
 165   int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1;
 166 #endif
 167 #ifdef UINT32_MAX
 168   int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1;
 169 #endif
 170 #ifdef UINT64_MAX
 171   int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1;
 172 #endif
 173   int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1;
 174   int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1;
 175   int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1;
 176   int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1;
 177   int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1;
 178   int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1;
 179   int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1;
 180   int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1;
 181   int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1;
 182   int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1;
 183   int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1;
 184 };
 185          ]])],
 186          [gl_cv_header_working_stdint_h=yes])])
 187   fi
 188   if test "$gl_cv_header_working_stdint_h" != yes; then
 189
 190     dnl Check for <sys/inttypes.h>, and for
 191     dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
 192     AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h])
 193     if test $ac_cv_header_sys_inttypes_h = yes; then
 194       HAVE_SYS_INTTYPES_H=1
 195     else
 196       HAVE_SYS_INTTYPES_H=0
 197     fi
 198     AC_SUBST([HAVE_SYS_INTTYPES_H])
 199     if test $ac_cv_header_sys_bitypes_h = yes; then
 200       HAVE_SYS_BITYPES_H=1
 201     else
 202       HAVE_SYS_BITYPES_H=0
 203     fi
 204     AC_SUBST([HAVE_SYS_BITYPES_H])
 205
 206     gl_STDINT_TYPE_PROPERTIES
 207     STDINT_H=stdint.h
 208   fi
 209   AC_SUBST(STDINT_H)
 210 ])
 211
 212 dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES)
 213 dnl Determine the size of each of the given types in bits.
 214 AC_DEFUN([gl_STDINT_BITSIZEOF],
 215 [
 216   dnl Use a shell loop, to avoid bloating configure, and
 217   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 218   dnl   config.h.in,
 219   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 220   AC_FOREACH([gltype], [$1],
 221     [AH_TEMPLATE([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 222        [Define to the number of bits in type ']gltype['.])])
 223   for gltype in $1 ; do
 224     AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}],
 225       [_AC_COMPUTE_INT([sizeof ($gltype) * CHAR_BIT], result,
 226          [$2
 227 #include <limits.h>], [result=unknown])
 228        eval gl_cv_bitsizeof_${gltype}=\$result
 229       ])
 230     eval result=\$gl_cv_bitsizeof_${gltype}
 231     if test $result = unknown; then
 232       dnl Use a nonempty default, because some compilers, such as IRIX 5 cc,
 233       dnl do a syntax check even on unused #if conditions and give an error
 234       dnl on valid C code like this:
 235       dnl   #if 0
 236       dnl   # if  > 32
 237       dnl   # endif
 238       dnl   #endif
 239       result=0
 240     fi
 241     GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 242     AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result])
 243     eval BITSIZEOF_${GLTYPE}=\$result
 244   done
 245   AC_FOREACH([gltype], [$1],
 246     [AC_SUBST([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 247 ])
 248
 249 dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES)
 250 dnl Determine the signedness of each of the given types.
 251 dnl Define HAVE_SIGNED_TYPE if type is signed.
 252 AC_DEFUN([gl_CHECK_TYPES_SIGNED],
 253 [
 254   dnl Use a shell loop, to avoid bloating configure, and
 255   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 256   dnl   config.h.in,
 257   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 258   AC_FOREACH([gltype], [$1],
 259     [AH_TEMPLATE([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
 260        [Define to 1 if ']gltype[' is a signed integer type.])])
 261   for gltype in $1 ; do
 262     AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed],
 263       [AC_COMPILE_IFELSE(
 264          [AC_LANG_PROGRAM([$2[
 265             int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])],
 266          result=yes, result=no)
 267        eval gl_cv_type_${gltype}_signed=\$result
 268       ])
 269     eval result=\$gl_cv_type_${gltype}_signed
 270     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 271     if test "$result" = yes; then
 272       AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], 1)
 273       eval HAVE_SIGNED_${GLTYPE}=1
 274     else
 275       eval HAVE_SIGNED_${GLTYPE}=0
 276     fi
 277   done
 278   AC_FOREACH([gltype], [$1],
 279     [AC_SUBST([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
 280 ])
 281
 282 dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES)
 283 dnl Determine the suffix to use for integer constants of the given types.
 284 dnl Define t_SUFFIX for each such type.
 285 AC_DEFUN([gl_INTEGER_TYPE_SUFFIX],
 286 [
 287   dnl Use a shell loop, to avoid bloating configure, and
 288   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
 289   dnl   config.h.in,
 290   dnl - extra AC_SUBST calls, so that the right substitutions are made.
 291   AC_FOREACH([gltype], [$1],
 292     [AH_TEMPLATE(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX],
 293        [Define to l, ll, u, ul, ull, etc., as suitable for
 294         constants of type ']gltype['.])])
 295   for gltype in $1 ; do
 296     AC_CACHE_CHECK([for $gltype integer literal suffix],
 297       [gl_cv_type_${gltype}_suffix],
 298       [eval gl_cv_type_${gltype}_suffix=no
 299        eval result=\$gl_cv_type_${gltype}_signed
 300        if test "$result" = yes; then
 301          glsufu=
 302        else
 303          glsufu=u
 304        fi
 305        for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do
 306          case $glsuf in
 307            '')  gltype1='int';;
 308            l)   gltype1='long int';;
 309            ll)  gltype1='long long int';;
 310            i64) gltype1='__int64';;
 311            u)   gltype1='unsigned int';;
 312            ul)  gltype1='unsigned long int';;
 313            ull) gltype1='unsigned long long int';;
 314            ui64)gltype1='unsigned __int64';;
 315          esac
 316          AC_COMPILE_IFELSE(
 317            [AC_LANG_PROGRAM([$2
 318               extern $gltype foo;
 319               extern $gltype1 foo;])],
 320            [eval gl_cv_type_${gltype}_suffix=\$glsuf])
 321          eval result=\$gl_cv_type_${gltype}_suffix
 322          test "$result" != no && break
 323        done])
 324     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
 325     eval result=\$gl_cv_type_${gltype}_suffix
 326     test "$result" = no && result=
 327     eval ${GLTYPE}_SUFFIX=\$result
 328     AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], $result)
 329   done
 330   AC_FOREACH([gltype], [$1],
 331     [AC_SUBST(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])])
 332 ])
 333
 334 dnl gl_STDINT_INCLUDES
 335 AC_DEFUN([gl_STDINT_INCLUDES],
 336 [[
 337   #include <stddef.h>
 338   #include <signal.h>
 339   #if HAVE_WCHAR_H
 340     /* BSD/OS 4.1 has a bug: <stdio.h> and <time.h> must be included before
 341        <wchar.h>.  */
 342   # include <stdio.h>
 343   # include <time.h>
 344   # include <wchar.h>
 345   #endif
 346 ]])
 347
 348 dnl gl_STDINT_TYPE_PROPERTIES
 349 dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t
 350 dnl of interest to stdint_.h.
 351 AC_DEFUN([gl_STDINT_TYPE_PROPERTIES],
 352 [
 353   gl_STDINT_BITSIZEOF([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
 354     [gl_STDINT_INCLUDES])
 355   gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t],
 356     [gl_STDINT_INCLUDES])
 357   gl_cv_type_ptrdiff_t_signed=yes
 358   gl_cv_type_size_t_signed=no
 359   gl_INTEGER_TYPE_SUFFIX([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
 360     [gl_STDINT_INCLUDES])
 361 ])