m4/stpncpy.m4

   1 # stpncpy.m4 serial 6
   2 dnl Copyright (C) 2002-2003, 2005-2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_STPNCPY],
   8 [
   9   dnl Persuade glibc <string.h> to declare stpncpy().
  10   AC_REQUIRE([AC_GNU_SOURCE])
  11
  12   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  13
  14   dnl Both glibc and AIX (4.3.3, 5.1) have an stpncpy() function
  15   dnl declared in <string.h>. Its side effects are the same as those
  16   dnl of strncpy():
  17   dnl      stpncpy (dest, src, n)
  18   dnl overwrites dest[0..n-1], min(strlen(src),n) bytes coming from src,
  19   dnl and the remaining bytes being NULs.  However, the return value is
  20   dnl   in glibc:   dest + min(strlen(src),n)
  21   dnl   in AIX:     dest + max(0,n-1)
  22   dnl Only the glibc return value is useful in practice.
  23
  24   AC_CACHE_CHECK([for working stpncpy], gl_cv_func_stpncpy, [
  25     AC_TRY_RUN([
  26 #include <stdlib.h>
  27 #include <string.h> /* for strcpy */
  28 /* The stpncpy prototype is missing in <string.h> on AIX 4.  */
  29 extern char *stpncpy (char *dest, const char *src, size_t n);
  30 int main () {
  31   const char *src = "Hello";
  32   char dest[10];
  33   /* AIX 4.3.3 and AIX 5.1 stpncpy() returns dest+1 here.  */
  34   strcpy (dest, "\377\377\377\377\377\377");
  35   if (stpncpy (dest, src, 2) != dest + 2) exit(1);
  36   /* AIX 4.3.3 and AIX 5.1 stpncpy() returns dest+4 here.  */
  37   strcpy (dest, "\377\377\377\377\377\377");
  38   if (stpncpy (dest, src, 5) != dest + 5) exit(1);
  39   /* AIX 4.3.3 and AIX 5.1 stpncpy() returns dest+6 here.  */
  40   strcpy (dest, "\377\377\377\377\377\377");
  41   if (stpncpy (dest, src, 7) != dest + 5) exit(1);
  42   exit(0);
  43 }
  44 ], gl_cv_func_stpncpy=yes, gl_cv_func_stpncpy=no,
  45   [AC_EGREP_CPP([Thanks for using GNU], [
  46 #include <features.h>
  47 #ifdef __GNU_LIBRARY__
  48   Thanks for using GNU
  49 #endif
  50 ], gl_cv_func_stpncpy=yes, gl_cv_func_stpncpy=no)])])
  51
  52   if test $gl_cv_func_stpncpy = yes; then
  53     AC_DEFINE(HAVE_STPNCPY, 1,
  54       [Define if you have the stpncpy() function and it works.])
  55   else
  56     HAVE_STPNCPY=0
  57     AC_LIBOBJ([stpncpy])
  58     gl_PREREQ_STPNCPY
  59   fi
  60 ])
  61
  62 # Prerequisites of lib/stpncpy.c.
  63 AC_DEFUN([gl_PREREQ_STPNCPY], [
  64   :
  65 ])