gitlog-to-changelog: give better diagnostic for failed pipe-open
[gnulib.git] / m4 / strcasestr.m4
1 # strcasestr.m4 serial 12
2 dnl Copyright (C) 2005, 2007, 2008 Free Software Foundation, Inc.
3 dnl This file is free software; the Free Software Foundation
4 dnl gives unlimited permission to copy and/or distribute it,
5 dnl with or without modifications, as long as this notice is preserved.
6
7 dnl Check that strcasestr is present.
8 AC_DEFUN([gl_FUNC_STRCASESTR_SIMPLE],
9 [
10   dnl Persuade glibc <string.h> to declare strcasestr().
11   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
12
13   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
14   AC_REPLACE_FUNCS([strcasestr])
15   if test $ac_cv_func_strcasestr = no; then
16     HAVE_STRCASESTR=0
17     gl_PREREQ_STRCASESTR
18   fi
19 ]) # gl_FUNC_STRCASESTR_SIMPLE
20
21 dnl Additionally, check that strcasestr is efficient.
22 AC_DEFUN([gl_FUNC_STRCASESTR],
23 [
24   AC_REQUIRE([gl_FUNC_STRCASESTR_SIMPLE])
25   if test $ac_cv_func_strcasestr = yes; then
26     AC_CACHE_CHECK([whether strcasestr works in linear time],
27       [gl_cv_func_strcasestr_linear],
28       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
29 #include <signal.h> /* for signal */
30 #include <string.h> /* for memmem */
31 #include <stdlib.h> /* for malloc */
32 #include <unistd.h> /* for alarm */
33 ]], [[size_t m = 1000000;
34     char *haystack = (char *) malloc (2 * m + 2);
35     char *needle = (char *) malloc (m + 2);
36     void *result = 0;
37     /* Failure to compile this test due to missing alarm is okay,
38        since all such platforms (mingw) also lack strcasestr.  */
39     signal (SIGALRM, SIG_DFL);
40     alarm (5);
41     /* Check for quadratic performance.  */
42     if (haystack && needle)
43       {
44         memset (haystack, 'A', 2 * m);
45         haystack[2 * m] = 'B';
46         haystack[2 * m + 1] = 0;
47         memset (needle, 'A', m);
48         needle[m] = 'B';
49         needle[m + 1] = 0;
50         result = strcasestr (haystack, needle);
51       }
52     return !result;]])],
53         [gl_cv_func_strcasestr_linear=yes], [gl_cv_func_strcasestr_linear=no],
54         [dnl Only glibc >= 2.9 and cygwin >= 1.7.0 are known to have a
55          dnl strcasestr that works in linear time.
56          AC_EGREP_CPP([Lucky user],
57            [
58 #include <features.h>
59 #ifdef __GNU_LIBRARY__
60  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 9) || (__GLIBC__ > 2)
61   Lucky user
62  #endif
63 #endif
64 #ifdef __CYGWIN__
65  #include <cygwin/version.h>
66  #if CYGWIN_VERSION_DLL_MAJOR >= 1007
67   Lucky user
68  #endif
69 #endif
70            ],
71            [gl_cv_func_strcasestr_linear=yes],
72            [gl_cv_func_strcasestr_linear="guessing no"])
73         ])
74       ])
75     if test "$gl_cv_func_strcasestr_linear" != yes; then
76       REPLACE_STRCASESTR=1
77       AC_LIBOBJ([strcasestr])
78     fi
79   fi
80 ]) # gl_FUNC_STRCASESTR
81
82 # Prerequisites of lib/strcasestr.c.
83 AC_DEFUN([gl_PREREQ_STRCASESTR], [
84   :
85 ])