m4/strerror.m4

   1 # strerror.m4 serial 13
   2 dnl Copyright (C) 2002, 2007-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_STRERROR],
   8 [
   9   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  10   AC_REQUIRE([gl_HEADER_ERRNO_H])
  11   m4_ifdef([gl_FUNC_STRERROR_R_WORKS], [
  12     AC_REQUIRE([gl_FUNC_STRERROR_R_WORKS])
  13   ])
  14   if test -z "$ERRNO_H"; then
  15     AC_CACHE_CHECK([for working strerror function],
  16      [gl_cv_func_working_strerror],
  17      [AC_RUN_IFELSE(
  18         [AC_LANG_PROGRAM(
  19            [[#include <string.h>
  20              #include <errno.h>
  21            ]],
  22            [[int result = 0;
  23              if (!*strerror (-2)) result |= 1;
  24              errno = 0;
  25              if (!*strerror (0)) result |= 2;
  26              if (errno) result |= 4;
  27              return result;]])],
  28         [gl_cv_func_working_strerror=yes],
  29         [gl_cv_func_working_strerror=no],
  30         [dnl Be pessimistic on cross-compiles for now.
  31          gl_cv_func_working_strerror=no])
  32     ])
  33     if test $gl_cv_func_working_strerror = no; then
  34       dnl The system's strerror() fails to return a string for out-of-range
  35       dnl integers. Replace it.
  36       REPLACE_STRERROR=1
  37     fi
  38     m4_ifdef([gl_FUNC_STRERROR_R_WORKS], [
  39       dnl If the system's strerror_r or __xpg_strerror_r clobbers strerror's
  40       dnl buffer, we must replace strerror.
  41       case "$gl_cv_func_strerror_r_works" in
  42         *no) REPLACE_STRERROR=1 ;;
  43       esac
  44     ])
  45   else
  46     dnl The system's strerror() cannot know about the new errno values we add
  47     dnl to <errno.h>. Replace it.
  48     REPLACE_STRERROR=1
  49   fi
  50 ])
  51
  52 # Prerequisites of lib/strerror.c.
  53 AC_DEFUN([gl_PREREQ_STRERROR], [
  54   AC_CHECK_DECLS([strerror])
  55   AC_CHECK_HEADERS_ONCE([sys/socket.h])
  56   if test $ac_cv_header_sys_socket_h != yes; then
  57     dnl We cannot use AC_CHECK_HEADERS_ONCE here, because that would make
  58     dnl the check for those headers unconditional; yet cygwin reports
  59     dnl that the headers are present but cannot be compiled (since on
  60     dnl cygwin, all socket information should come from sys/socket.h).
  61     AC_CHECK_HEADERS([winsock2.h])
  62   fi
  63 ])