m4/strerror_r.m4

   1 # strerror_r.m4 serial 11
   2 dnl Copyright (C) 2002, 2007-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_STRERROR_R],
   8 [
   9   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  10   AC_REQUIRE([gl_FUNC_STRERROR_R_WORKS])
  11
  12   dnl Persuade Solaris <string.h> to declare strerror_r().
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   dnl Some systems don't declare strerror_r() if _THREAD_SAFE and _REENTRANT
  16   dnl are not defined.
  17   AC_CHECK_DECLS_ONCE([strerror_r])
  18   if test $ac_cv_have_decl_strerror_r = no; then
  19     HAVE_DECL_STRERROR_R=0
  20   fi
  21
  22   if test $ac_cv_func_strerror_r = yes; then
  23     if test -z "$ERRNO_H"; then
  24       if test $gl_cv_func_strerror_r_posix_signature = yes; then
  25         case "$gl_cv_func_strerror_r_works" in
  26           dnl The system's strerror_r has bugs.  Replace it.
  27           *no) REPLACE_STRERROR_R=1 ;;
  28         esac
  29       else
  30         dnl The system's strerror_r() has a wrong signature. Replace it.
  31         REPLACE_STRERROR_R=1
  32       fi
  33     else
  34       dnl The system's strerror_r() cannot know about the new errno values we
  35       dnl add to <errno.h>. Replace it.
  36       REPLACE_STRERROR_R=1
  37     fi
  38   fi
  39 ])
  40
  41 # Prerequisites of lib/strerror_r.c.
  42 AC_DEFUN([gl_PREREQ_STRERROR_R], [
  43   dnl glibc >= 2.3.4 and cygwin 1.7.9 have a function __xpg_strerror_r.
  44   AC_CHECK_FUNCS([__xpg_strerror_r])
  45   AC_CHECK_FUNCS_ONCE([catgets])
  46 ])
  47
  48 # Detect if strerror_r works, but without affecting whether a replacement
  49 # strerror_r will be used.
  50 AC_DEFUN([gl_FUNC_STRERROR_R_WORKS],
  51 [
  52   AC_REQUIRE([gl_HEADER_ERRNO_H])
  53   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  54
  55   AC_CHECK_FUNCS_ONCE([strerror_r])
  56   if test $ac_cv_func_strerror_r = yes; then
  57     if test -z "$ERRNO_H"; then
  58       dnl The POSIX prototype is:  int strerror_r (int, char *, size_t);
  59       dnl glibc, Cygwin:           char *strerror_r (int, char *, size_t);
  60       dnl AIX 5.1, OSF/1 5.1:      int strerror_r (int, char *, int);
  61       AC_CACHE_CHECK([for strerror_r with POSIX signature],
  62         [gl_cv_func_strerror_r_posix_signature],
  63         [AC_COMPILE_IFELSE(
  64            [AC_LANG_PROGRAM(
  65               [[#include <string.h>
  66                 int strerror_r (int, char *, size_t);
  67               ]],
  68               [])],
  69            [gl_cv_func_strerror_r_posix_signature=yes],
  70            [gl_cv_func_strerror_r_posix_signature=no])
  71         ])
  72       if test $gl_cv_func_strerror_r_posix_signature = yes; then
  73         dnl AIX 6.1 strerror_r fails by returning -1, not an error number.
  74         dnl HP-UX 11.31 strerror_r always fails when the buffer length argument
  75         dnl is less than 80.
  76         dnl FreeBSD 8.s strerror_r claims failure on 0
  77         dnl MacOS X 10.5 strerror_r treats 0 like -1
  78         dnl Solaris 10 strerror_r corrupts errno on failure
  79         AC_CACHE_CHECK([whether strerror_r works],
  80           [gl_cv_func_strerror_r_works],
  81           [AC_RUN_IFELSE(
  82              [AC_LANG_PROGRAM(
  83                 [[#include <errno.h>
  84                   #include <string.h>
  85                 ]],
  86                 [[int result = 0;
  87                   char buf[79];
  88                   if (strerror_r (EACCES, buf, 0) < 0)
  89                     result |= 1;
  90                   errno = 0;
  91                   if (strerror_r (EACCES, buf, sizeof buf) != 0)
  92                     result |= 2;
  93                   strcpy (buf, "Unknown");
  94                   if (strerror_r (0, buf, sizeof buf) != 0)
  95                     result |= 4;
  96                   if (errno)
  97                     result |= 8;
  98                   if (strstr (buf, "nknown") || strstr (buf, "ndefined"))
  99                     result |= 0x10;
 100                   errno = 0;
 101                   *buf = 0;
 102                   if (strerror_r (-3, buf, sizeof buf) < 0)
 103                     result |= 0x20;
 104                   if (errno)
 105                     result |= 0x40;
 106                   if (!*buf)
 107                     result |= 0x80;
 108                   return result;
 109                 ]])],
 110              [gl_cv_func_strerror_r_works=yes],
 111              [gl_cv_func_strerror_r_works=no],
 112              [
 113 changequote(,)dnl
 114               case "$host_os" in
 115                        # Guess no on AIX.
 116                 aix*)  gl_cv_func_strerror_r_works="guessing no";;
 117                        # Guess no on HP-UX.
 118                 hpux*) gl_cv_func_strerror_r_works="guessing no";;
 119                        # Guess no on FreeBSD.
 120                 freebsd*)  gl_cv_func_strerror_r_works="guessing no";;
 121                        # Guess yes otherwise.
 122                 *)     gl_cv_func_strerror_r_works="guessing yes";;
 123               esac
 124 changequote([,])dnl
 125              ])
 126           ])
 127       else
 128         dnl The system's strerror() has a wrong signature.
 129         dnl glibc >= 2.3.4 and cygwin 1.7.9 have a function __xpg_strerror_r.
 130         AC_CHECK_FUNCS([__xpg_strerror_r])
 131         dnl In glibc < 2.14, __xpg_strerror_r does not populate buf on failure.
 132         dnl In cygwin < 1.7.10, __xpg_strerror_r clobbers strerror's buffer.
 133         if test $ac_cv_func___xpg_strerror_r = yes; then
 134           AC_CACHE_CHECK([whether __xpg_strerror_r works],
 135             [gl_cv_func_strerror_r_works],
 136             [AC_RUN_IFELSE(
 137                [AC_LANG_PROGRAM(
 138                   [[#include <errno.h>
 139                     #include <string.h>
 140                     extern int __xpg_strerror_r(int, char *, size_t);
 141                   ]],
 142                   [[int result = 0;
 143                     char buf[256] = "^";
 144                     char copy[256];
 145                     char *str = strerror (-1);
 146                     strcpy (copy, str);
 147                     if (__xpg_strerror_r (-2, buf, 1) == 0)
 148                       result |= 1;
 149                     if (*buf)
 150                       result |= 2;
 151                     __xpg_strerror_r (-2, buf, 256);
 152                     if (strcmp (str, copy))
 153                       result |= 4;
 154                     return result;
 155                   ]])],
 156                [gl_cv_func_strerror_r_works=yes],
 157                [gl_cv_func_strerror_r_works=no],
 158                [dnl Guess no on all platforms that have __xpg_strerror_r,
 159                 dnl at least until fixed glibc and cygwin are more common.
 160                 gl_cv_func_strerror_r_works="guessing no"
 161                ])
 162             ])
 163         fi
 164       fi
 165     fi
 166   fi
 167 ])