m4/strstr.m4

   1 # strstr.m4 serial 14
   2 dnl Copyright (C) 2008-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Check that strstr works.
   8 AC_DEFUN([gl_FUNC_STRSTR_SIMPLE],
   9 [
  10   AC_REQUIRE([gl_HEADER_STRING_H_DEFAULTS])
  11   AC_REQUIRE([gl_FUNC_MEMCHR])
  12   if test "$gl_cv_func_memchr_works" != yes; then
  13     REPLACE_STRSTR=1
  14   else
  15     dnl Detect http://sourceware.org/bugzilla/show_bug.cgi?id=12092.
  16     AC_CACHE_CHECK([whether strstr works],
  17       [gl_cv_func_strstr_works_always],
  18       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  19 #include <string.h> /* for strstr */
  20 #define P "_EF_BF_BD"
  21 #define HAYSTACK "F_BD_CE_BD" P P P P "_C3_88_20" P P P "_C3_A7_20" P
  22 #define NEEDLE P P P P P
  23 ]], [[return !!strstr (HAYSTACK, NEEDLE);
  24     ]])],
  25         [gl_cv_func_strstr_works_always=yes],
  26         [gl_cv_func_strstr_works_always=no],
  27         [dnl glibc 2.12 and cygwin 1.7.7 have a known bug.  uClibc is not
  28          dnl affected, since it uses different source code for strstr than
  29          dnl glibc.
  30          dnl Assume that it works on all other platforms, even if it is not
  31          dnl linear.
  32          AC_EGREP_CPP([Lucky user],
  33            [
  34 #ifdef __GNU_LIBRARY__
  35  #include <features.h>
  36  #if ((__GLIBC__ == 2 && __GLIBC_MINOR__ > 12) || (__GLIBC__ > 2)) \
  37      || defined __UCLIBC__
  38   Lucky user
  39  #endif
  40 #elif defined __CYGWIN__
  41  #include <cygwin/version.h>
  42  #if CYGWIN_VERSION_DLL_COMBINED > CYGWIN_VERSION_DLL_MAKE_COMBINED (1007, 7)
  43   Lucky user
  44  #endif
  45 #else
  46   Lucky user
  47 #endif
  48            ],
  49            [gl_cv_func_strstr_works_always=yes],
  50            [gl_cv_func_strstr_works_always="guessing no"])
  51         ])
  52       ])
  53     if test "$gl_cv_func_strstr_works_always" != yes; then
  54       REPLACE_STRSTR=1
  55     fi
  56   fi
  57 ]) # gl_FUNC_STRSTR_SIMPLE
  58
  59 dnl Additionally, check that strstr is efficient.
  60 AC_DEFUN([gl_FUNC_STRSTR],
  61 [
  62   AC_REQUIRE([gl_FUNC_STRSTR_SIMPLE])
  63   if test $REPLACE_STRSTR = 0; then
  64     AC_CACHE_CHECK([whether strstr works in linear time],
  65       [gl_cv_func_strstr_linear],
  66       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  67 #include <signal.h> /* for signal */
  68 #include <string.h> /* for strstr */
  69 #include <stdlib.h> /* for malloc */
  70 #include <unistd.h> /* for alarm */
  71 static void quit (int sig) { exit (sig + 128); }
  72 ]], [[
  73     int result = 0;
  74     size_t m = 1000000;
  75     char *haystack = (char *) malloc (2 * m + 2);
  76     char *needle = (char *) malloc (m + 2);
  77     /* Failure to compile this test due to missing alarm is okay,
  78        since all such platforms (mingw) also have quadratic strstr.  */
  79     signal (SIGALRM, quit);
  80     alarm (5);
  81     /* Check for quadratic performance.  */
  82     if (haystack && needle)
  83       {
  84         memset (haystack, 'A', 2 * m);
  85         haystack[2 * m] = 'B';
  86         haystack[2 * m + 1] = 0;
  87         memset (needle, 'A', m);
  88         needle[m] = 'B';
  89         needle[m + 1] = 0;
  90         if (!strstr (haystack, needle))
  91           result |= 1;
  92       }
  93     return result;
  94     ]])],
  95         [gl_cv_func_strstr_linear=yes], [gl_cv_func_strstr_linear=no],
  96         [dnl Only glibc > 2.12 and cygwin > 1.7.7 are known to have a
  97          dnl bug-free strstr that works in linear time.
  98          AC_EGREP_CPP([Lucky user],
  99            [
 100 #include <features.h>
 101 #ifdef __GNU_LIBRARY__
 102  #if ((__GLIBC__ == 2 && __GLIBC_MINOR__ > 12) || (__GLIBC__ > 2)) \
 103      && !defined __UCLIBC__
 104   Lucky user
 105  #endif
 106 #endif
 107 #ifdef __CYGWIN__
 108  #include <cygwin/version.h>
 109  #if CYGWIN_VERSION_DLL_COMBINED > CYGWIN_VERSION_DLL_MAKE_COMBINED (1007, 7)
 110   Lucky user
 111  #endif
 112 #endif
 113            ],
 114            [gl_cv_func_strstr_linear=yes],
 115            [gl_cv_func_strstr_linear="guessing no"])
 116         ])
 117       ])
 118     if test "$gl_cv_func_strstr_linear" != yes; then
 119       REPLACE_STRSTR=1
 120     fi
 121   fi
 122 ]) # gl_FUNC_STRSTR