m4/strtod.m4

   1 # strtod.m4 serial 8
   2 dnl Copyright (C) 2002, 2003, 2006, 2007, 2008 Free Software
   3 dnl Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_DEFUN([gl_FUNC_STRTOD],
   9 [
  10   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  11   AC_FUNC_STRTOD
  12   dnl Note: AC_FUNC_STRTOD does AC_LIBOBJ(strtod).
  13   if test $ac_cv_func_strtod = no; then
  14     HAVE_STRTOD=0
  15     REPLACE_STRTOD=1
  16     gl_PREREQ_STRTOD
  17   else
  18     AC_CACHE_CHECK([whether strtod obeys C99], [gl_cv_func_strtod_works],
  19       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  20 #include <stdlib.h>
  21 #include <math.h>
  22 ]], [[
  23   {
  24     /* Older glibc and Cygwin mis-parse "-0x".  */
  25     const char *string = "-0x";
  26     char *term;
  27     double value = strtod (string, &term);
  28     double zero = 0.0;
  29     if (1.0 / value != -1.0 / zero || term != (string + 2))
  30       return 1;
  31   }
  32   {
  33     /* Many platforms do not parse hex floats.  */
  34     const char *string = "0XaP+1";
  35     char *term;
  36     double value = strtod (string, &term);
  37     if (value != 20.0 || term != (string + 6))
  38       return 1;
  39   }
  40   {
  41     /* Many platforms do not parse infinities.  */
  42     const char *string = "inf";
  43     char *term;
  44     double value = strtod (string, &term);
  45     if (value != HUGE_VAL || term != (string + 3))
  46       return 1;
  47   }
  48 ]])],
  49         [gl_cv_func_strtod_works=yes],
  50         [gl_cv_func_strtod_works=no],
  51         [gl_cv_func_strtod_works="guessing no"])])
  52     if test "$gl_cv_func_strtod_works" != yes; then
  53       REPLACE_STRTOD=1
  54       gl_PREREQ_STRTOD
  55       dnl Use undocumented macro to set POW_LIB correctly.
  56       _AC_LIBOBJ_STRTOD
  57     fi
  58   fi
  59 ])
  60
  61 # Prerequisites of lib/strtod.c.
  62 # The need for pow() is already handled by AC_FUNC_STRTOD.
  63 AC_DEFUN([gl_PREREQ_STRTOD], [:])