m4/sys_ioctl_h.m4

   1 # sys_ioctl_h.m4 serial 4
   2 dnl Copyright (C) 2008-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Written by Bruno Haible.
   8
   9 AC_DEFUN([gl_SYS_IOCTL_H],
  10 [
  11   dnl Use AC_REQUIRE here, so that the default behavior below is expanded
  12   dnl once only, before all statements that occur in other macros.
  13   AC_REQUIRE([gl_SYS_IOCTL_H_DEFAULTS])
  14
  15   AC_CHECK_HEADERS_ONCE([sys/ioctl.h])
  16   if test $ac_cv_header_sys_ioctl_h = yes; then
  17     HAVE_SYS_IOCTL_H=1
  18     dnl Test whether <sys/ioctl.h> declares ioctl(), or whether some other
  19     dnl header file, such as <unistd.h> or <stropts.h>, is needed for that.
  20     AC_CACHE_CHECK([whether <sys/ioctl.h> declares ioctl],
  21       [gl_cv_decl_ioctl_in_sys_ioctl_h],
  22       [dnl We cannot use AC_CHECK_DECL because it produces its own messages.
  23        AC_COMPILE_IFELSE(
  24          [AC_LANG_PROGRAM(
  25             [AC_INCLUDES_DEFAULT([#include <sys/ioctl.h>])],
  26             [(void) ioctl;])],
  27          [gl_cv_decl_ioctl_in_sys_ioctl_h=yes],
  28          [gl_cv_decl_ioctl_in_sys_ioctl_h=no])
  29       ])
  30   else
  31     HAVE_SYS_IOCTL_H=0
  32   fi
  33   AC_SUBST([HAVE_SYS_IOCTL_H])
  34   dnl <sys/ioctl.h> is always overridden, because of GNULIB_POSIXCHECK.
  35   gl_CHECK_NEXT_HEADERS([sys/ioctl.h])
  36 ])
  37
  38 dnl Unconditionally enables the replacement of <sys/ioctl.h>.
  39 AC_DEFUN([gl_REPLACE_SYS_IOCTL_H],
  40 [
  41   dnl This is a no-op, because <sys/ioctl.h> is always overridden.
  42   :
  43 ])
  44
  45 AC_DEFUN([gl_SYS_IOCTL_MODULE_INDICATOR],
  46 [
  47   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  48   AC_REQUIRE([gl_SYS_IOCTL_H_DEFAULTS])
  49   GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
  50 ])
  51
  52 AC_DEFUN([gl_SYS_IOCTL_H_DEFAULTS],
  53 [
  54   GNULIB_IOCTL=0;         AC_SUBST([GNULIB_IOCTL])
  55   dnl Assume proper GNU behavior unless another module says otherwise.
  56   SYS_IOCTL_H_HAVE_WINSOCK2_H=0; AC_SUBST([SYS_IOCTL_H_HAVE_WINSOCK2_H])
  57   SYS_IOCTL_H_HAVE_WINSOCK2_H_AND_USE_SOCKETS=0;
  58                         AC_SUBST([SYS_IOCTL_H_HAVE_WINSOCK2_H_AND_USE_SOCKETS])
  59 ])