m4/sys_select_h.m4

   1 # sys_select_h.m4 serial 19
   2 dnl Copyright (C) 2006-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_HEADER_SYS_SELECT],
   8 [
   9   AC_REQUIRE([AC_C_RESTRICT])
  10   AC_REQUIRE([gl_SYS_SELECT_H_DEFAULTS])
  11   AC_CACHE_CHECK([whether <sys/select.h> is self-contained],
  12     [gl_cv_header_sys_select_h_selfcontained],
  13     [
  14       dnl Test against two bugs:
  15       dnl 1. On many platforms, <sys/select.h> assumes prior inclusion of
  16       dnl    <sys/types.h>.
  17       dnl 2. On OSF/1 4.0, <sys/select.h> provides only a forward declaration
  18       dnl    of 'struct timeval', and no definition of this type.
  19       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/select.h>]],
  20                                          [[struct timeval b;]])],
  21         [gl_cv_header_sys_select_h_selfcontained=yes],
  22         [gl_cv_header_sys_select_h_selfcontained=no])
  23       dnl Test against another bug:
  24       dnl 3. On Solaris 10, <sys/select.h> provides an FD_ZERO implementation
  25       dnl    that relies on memset(), but without including <string.h>.
  26       if test $gl_cv_header_sys_select_h_selfcontained = yes; then
  27         AC_COMPILE_IFELSE(
  28           [AC_LANG_PROGRAM([[#include <sys/select.h>]],
  29                            [[int memset; int bzero;]])
  30           ],
  31           [AC_LINK_IFELSE(
  32              [AC_LANG_PROGRAM([[#include <sys/select.h>]], [[
  33                   #undef memset
  34                   #define memset nonexistent_memset
  35                   extern void *memset (void *, int, unsigned long);
  36                   #undef bzero
  37                   #define bzero nonexistent_bzero
  38                   extern void bzero (void *, unsigned long);
  39                   fd_set fds;
  40                   FD_ZERO (&fds);
  41                 ]])
  42              ],
  43              [],
  44              [gl_cv_header_sys_select_h_selfcontained=no])
  45           ])
  46       fi
  47     ])
  48   dnl <sys/select.h> is always overridden, because of GNULIB_POSIXCHECK.
  49   gl_CHECK_NEXT_HEADERS([sys/select.h])
  50   if test $ac_cv_header_sys_select_h = yes; then
  51     HAVE_SYS_SELECT_H=1
  52   else
  53     HAVE_SYS_SELECT_H=0
  54   fi
  55   AC_SUBST([HAVE_SYS_SELECT_H])
  56   gl_PREREQ_SYS_H_WINSOCK2
  57
  58   dnl Check for declarations of anything we want to poison if the
  59   dnl corresponding gnulib module is not in use.
  60   gl_WARN_ON_USE_PREPARE([[
  61 /* Some systems require prerequisite headers.  */
  62 #include <sys/types.h>
  63 #if !(defined __GLIBC__ && !defined __UCLIBC__) && HAVE_SYS_TIME_H
  64 # include <sys/time.h>
  65 #endif
  66 #include <sys/select.h>
  67     ]], [pselect select])
  68 ])
  69
  70 AC_DEFUN([gl_SYS_SELECT_MODULE_INDICATOR],
  71 [
  72   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  73   AC_REQUIRE([gl_SYS_SELECT_H_DEFAULTS])
  74   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
  75   dnl Define it also as a C macro, for the benefit of the unit tests.
  76   gl_MODULE_INDICATOR_FOR_TESTS([$1])
  77 ])
  78
  79 AC_DEFUN([gl_SYS_SELECT_H_DEFAULTS],
  80 [
  81   GNULIB_PSELECT=0; AC_SUBST([GNULIB_PSELECT])
  82   GNULIB_SELECT=0; AC_SUBST([GNULIB_SELECT])
  83   dnl Assume proper GNU behavior unless another module says otherwise.
  84   HAVE_PSELECT=1; AC_SUBST([HAVE_PSELECT])
  85   REPLACE_PSELECT=0; AC_SUBST([REPLACE_PSELECT])
  86   REPLACE_SELECT=0; AC_SUBST([REPLACE_SELECT])
  87 ])