m4/sys_socket_h.m4

   1 # sys_socket_h.m4 serial 19
   2 dnl Copyright (C) 2005-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Simon Josefsson.
   8
   9 AC_DEFUN([gl_HEADER_SYS_SOCKET],
  10 [
  11   AC_REQUIRE([gl_SYS_SOCKET_H_DEFAULTS])
  12   AC_REQUIRE([AC_C_INLINE])
  13
  14   AC_CACHE_CHECK([whether <sys/socket.h> is self-contained],
  15     [gl_cv_header_sys_socket_h_selfcontained],
  16     [
  17       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]], [[]])],
  18         [gl_cv_header_sys_socket_h_selfcontained=yes],
  19         [gl_cv_header_sys_socket_h_selfcontained=no])
  20     ])
  21   if test $gl_cv_header_sys_socket_h_selfcontained = yes; then
  22     dnl If the shutdown function exists, <sys/socket.h> should define
  23     dnl SHUT_RD, SHUT_WR, SHUT_RDWR.
  24     AC_CHECK_FUNCS([shutdown])
  25     if test $ac_cv_func_shutdown = yes; then
  26       AC_CACHE_CHECK([whether <sys/socket.h> defines the SHUT_* macros],
  27         [gl_cv_header_sys_socket_h_shut],
  28         [
  29           AC_COMPILE_IFELSE(
  30             [AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  31                [[int a[] = { SHUT_RD, SHUT_WR, SHUT_RDWR };]])],
  32             [gl_cv_header_sys_socket_h_shut=yes],
  33             [gl_cv_header_sys_socket_h_shut=no])
  34         ])
  35       if test $gl_cv_header_sys_socket_h_shut = no; then
  36         SYS_SOCKET_H='sys/socket.h'
  37       fi
  38     fi
  39   fi
  40   # We need to check for ws2tcpip.h now.
  41   gl_PREREQ_SYS_H_SOCKET
  42   AC_CHECK_TYPES([struct sockaddr_storage, sa_family_t],,,[
  43   /* sys/types.h is not needed according to POSIX, but the
  44      sys/socket.h in i386-unknown-freebsd4.10 and
  45      powerpc-apple-darwin5.5 required it. */
  46 #include <sys/types.h>
  47 #ifdef HAVE_SYS_SOCKET_H
  48 #include <sys/socket.h>
  49 #endif
  50 #ifdef HAVE_WS2TCPIP_H
  51 #include <ws2tcpip.h>
  52 #endif
  53 ])
  54   if test $ac_cv_type_struct_sockaddr_storage = no; then
  55     HAVE_STRUCT_SOCKADDR_STORAGE=0
  56   fi
  57   if test $ac_cv_type_sa_family_t = no; then
  58     HAVE_SA_FAMILY_T=0
  59   fi
  60   gl_PREREQ_SYS_H_WINSOCK2
  61
  62   dnl Check for declarations of anything we want to poison if the
  63   dnl corresponding gnulib module is not in use.
  64   gl_WARN_ON_USE_PREPARE([[
  65 /* Some systems require prerequisite headers.  */
  66 #include <sys/types.h>
  67 #include <sys/socket.h>
  68     ]], [socket connect accept bind getpeername getsockname getsockopt
  69     listen recv send recvfrom sendto setsockopt shutdown accept4])
  70 ])
  71
  72 AC_DEFUN([gl_PREREQ_SYS_H_SOCKET],
  73 [
  74   dnl Check prerequisites of the <sys/socket.h> replacement.
  75   gl_CHECK_NEXT_HEADERS([sys/socket.h])
  76   if test $ac_cv_header_sys_socket_h = yes; then
  77     HAVE_SYS_SOCKET_H=1
  78     HAVE_WS2TCPIP_H=0
  79   else
  80     HAVE_SYS_SOCKET_H=0
  81     dnl We cannot use AC_CHECK_HEADERS_ONCE here, because that would make
  82     dnl the check for those headers unconditional; yet cygwin reports
  83     dnl that the headers are present but cannot be compiled (since on
  84     dnl cygwin, all socket information should come from sys/socket.h).
  85     AC_CHECK_HEADERS([ws2tcpip.h])
  86     if test $ac_cv_header_ws2tcpip_h = yes; then
  87       HAVE_WS2TCPIP_H=1
  88     else
  89       HAVE_WS2TCPIP_H=0
  90     fi
  91   fi
  92   AC_SUBST([HAVE_SYS_SOCKET_H])
  93   AC_SUBST([HAVE_WS2TCPIP_H])
  94 ])
  95
  96 # Common prerequisites of the <sys/socket.h> replacement and of the
  97 # <sys/select.h> replacement.
  98 # Sets and substitutes HAVE_WINSOCK2_H.
  99 AC_DEFUN([gl_PREREQ_SYS_H_WINSOCK2],
 100 [
 101   m4_ifdef([gl_UNISTD_H_DEFAULTS], [AC_REQUIRE([gl_UNISTD_H_DEFAULTS])])
 102   m4_ifdef([gl_SYS_IOCTL_H_DEFAULTS], [AC_REQUIRE([gl_SYS_IOCTL_H_DEFAULTS])])
 103   AC_CHECK_HEADERS_ONCE([sys/socket.h])
 104   if test $ac_cv_header_sys_socket_h != yes; then
 105     dnl We cannot use AC_CHECK_HEADERS_ONCE here, because that would make
 106     dnl the check for those headers unconditional; yet cygwin reports
 107     dnl that the headers are present but cannot be compiled (since on
 108     dnl cygwin, all socket information should come from sys/socket.h).
 109     AC_CHECK_HEADERS([winsock2.h])
 110   fi
 111   if test "$ac_cv_header_winsock2_h" = yes; then
 112     HAVE_WINSOCK2_H=1
 113     UNISTD_H_HAVE_WINSOCK2_H=1
 114     SYS_IOCTL_H_HAVE_WINSOCK2_H=1
 115   else
 116     HAVE_WINSOCK2_H=0
 117   fi
 118   AC_SUBST([HAVE_WINSOCK2_H])
 119 ])
 120
 121 AC_DEFUN([gl_SYS_SOCKET_MODULE_INDICATOR],
 122 [
 123   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
 124   AC_REQUIRE([gl_SYS_SOCKET_H_DEFAULTS])
 125   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
 126   dnl Define it also as a C macro, for the benefit of the unit tests.
 127   gl_MODULE_INDICATOR_FOR_TESTS([$1])
 128 ])
 129
 130 AC_DEFUN([gl_SYS_SOCKET_H_DEFAULTS],
 131 [
 132   GNULIB_SOCKET=0;      AC_SUBST([GNULIB_SOCKET])
 133   GNULIB_CONNECT=0;     AC_SUBST([GNULIB_CONNECT])
 134   GNULIB_ACCEPT=0;      AC_SUBST([GNULIB_ACCEPT])
 135   GNULIB_BIND=0;        AC_SUBST([GNULIB_BIND])
 136   GNULIB_GETPEERNAME=0; AC_SUBST([GNULIB_GETPEERNAME])
 137   GNULIB_GETSOCKNAME=0; AC_SUBST([GNULIB_GETSOCKNAME])
 138   GNULIB_GETSOCKOPT=0;  AC_SUBST([GNULIB_GETSOCKOPT])
 139   GNULIB_LISTEN=0;      AC_SUBST([GNULIB_LISTEN])
 140   GNULIB_RECV=0;        AC_SUBST([GNULIB_RECV])
 141   GNULIB_SEND=0;        AC_SUBST([GNULIB_SEND])
 142   GNULIB_RECVFROM=0;    AC_SUBST([GNULIB_RECVFROM])
 143   GNULIB_SENDTO=0;      AC_SUBST([GNULIB_SENDTO])
 144   GNULIB_SETSOCKOPT=0;  AC_SUBST([GNULIB_SETSOCKOPT])
 145   GNULIB_SHUTDOWN=0;    AC_SUBST([GNULIB_SHUTDOWN])
 146   GNULIB_ACCEPT4=0;     AC_SUBST([GNULIB_ACCEPT4])
 147   HAVE_STRUCT_SOCKADDR_STORAGE=1; AC_SUBST([HAVE_STRUCT_SOCKADDR_STORAGE])
 148   HAVE_SA_FAMILY_T=1;   AC_SUBST([HAVE_SA_FAMILY_T])
 149   HAVE_ACCEPT4=1;       AC_SUBST([HAVE_ACCEPT4])
 150 ])