m4/sys_socket_h.m4

   1 # sys_socket_h.m4 serial 6
   2 dnl Copyright (C) 2005-2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Simon Josefsson.
   8
   9 AC_DEFUN([gl_HEADER_SYS_SOCKET],
  10 [
  11   AC_REQUIRE([AC_C_INLINE])
  12
  13   AC_CACHE_CHECK([whether <sys/socket.h> is self-contained],
  14     [gl_cv_header_sys_socket_h_selfcontained],
  15     [
  16       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/socket.h>]], [[]])],
  17         [gl_cv_header_sys_socket_h_selfcontained=yes],
  18         [gl_cv_header_sys_socket_h_selfcontained=no])
  19     ])
  20   if test $gl_cv_header_sys_socket_h_selfcontained = yes; then
  21     SYS_SOCKET_H=''
  22     dnl If the shutdown function exists, <sys/socket.h> should define
  23     dnl SHUT_RD, SHUT_WR, SHUT_RDWR.
  24     AC_CHECK_FUNCS([shutdown])
  25     if test $ac_cv_func_shutdown = yes; then
  26       AC_CACHE_CHECK([whether <sys/socket.h> defines the SHUT_* macros],
  27         [gl_cv_header_sys_socket_h_shut],
  28         [
  29           AC_COMPILE_IFELSE(
  30             [AC_LANG_PROGRAM([[#include <sys/socket.h>]],
  31                [[int a[] = { SHUT_RD, SHUT_WR, SHUT_RDWR };]])],
  32             [gl_cv_header_sys_socket_h_shut=yes],
  33             [gl_cv_header_sys_socket_h_shut=no])
  34         ])
  35       if test $gl_cv_header_sys_socket_h_shut = no; then
  36         SYS_SOCKET_H='sys/socket.h'
  37       fi
  38     fi
  39   else
  40     SYS_SOCKET_H='sys/socket.h'
  41   fi
  42   if test -n "$SYS_SOCKET_H"; then
  43     dnl Check prerequisites of the <sys/socket.h> replacement.
  44     gl_CHECK_NEXT_HEADERS([sys/socket.h])
  45     if test $ac_cv_header_sys_socket_h = yes; then
  46       HAVE_SYS_SOCKET_H=1
  47       HAVE_WINSOCK2_H=0
  48       HAVE_WS2TCPIP_H=0
  49     else
  50       HAVE_SYS_SOCKET_H=0
  51       dnl We cannot use AC_CHECK_HEADERS_ONCE here, because that would make
  52       dnl the check for those headers unconditional; yet cygwin reports
  53       dnl that the headers are present but cannot be compiled (since on
  54       dnl cygwin, all socket information should come from sys/socket.h).
  55       AC_CHECK_HEADERS([winsock2.h ws2tcpip.h])
  56       if test $ac_cv_header_winsock2_h = yes; then
  57         HAVE_WINSOCK2_H=1
  58       else
  59         HAVE_WINSOCK2_H=0
  60       fi
  61       if test $ac_cv_header_ws2tcpip_h = yes; then
  62         HAVE_WS2TCPIP_H=1
  63       else
  64         HAVE_WS2TCPIP_H=0
  65       fi
  66     fi
  67     AC_SUBST([HAVE_SYS_SOCKET_H])
  68     AC_SUBST([HAVE_WINSOCK2_H])
  69     AC_SUBST([HAVE_WS2TCPIP_H])
  70   fi
  71   AC_SUBST([SYS_SOCKET_H])
  72 ])