m4/sys_stat_h.m4

   1 # sys_stat_h.m4 serial 3   -*- Autoconf -*-
   2 dnl Copyright (C) 2006 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Eric Blake.
   8 dnl Test whether <sys/stat.h> contains lstat and mkdir or must be substituted.
   9
  10 AC_DEFUN([gl_HEADER_SYS_STAT_H],
  11 [
  12   dnl Check for lstat.  Systems that lack it (mingw) also lack symlinks, so
  13   dnl stat is a good replacement.
  14   AC_CHECK_FUNCS_ONCE([lstat])
  15
  16   dnl Check for mkdir.  Mingw has _mkdir(name) in the nonstandard <io.h>
  17   dnl instead.
  18   AC_CHECK_DECLS([mkdir], [], [], [#include <sys/stat.h>])
  19
  20   dnl Check for broken stat macros.
  21   AC_REQUIRE([AC_HEADER_STAT])
  22
  23   SYS_STAT_H=
  24   if test $ac_cv_func_lstat:$ac_cv_have_decl_mkdir:$ac_cv_header_stat_broken \
  25       != yes:yes:no ; then
  26     gl_ABSOLUTE_HEADER([sys/stat.h])
  27     ABSOLUTE_SYS_STAT_H=\"$gl_cv_absolute_sys_stat_h\"
  28     AC_CHECK_HEADERS([io.h])
  29     AC_REQUIRE([AC_C_INLINE])
  30     SYS_STAT_H='sys/stat.h'
  31   else
  32     ABSOLUTE_SYS_STAT_H=\"no/such/file/sys/stat.h\"
  33   fi
  34   AC_SUBST([ABSOLUTE_SYS_STAT_H])
  35   AC_SUBST([SYS_STAT_H])
  36 ]) # gl_HEADER_SYS_STAT_H