m4/sys_utsname_h.m4

   1 # sys_utsname_h.m4 serial 6
   2 dnl Copyright (C) 2009-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl Written by Bruno Haible.
   8
   9 AC_DEFUN([gl_SYS_UTSNAME_H],
  10 [
  11   dnl Use AC_REQUIRE here, so that the default behavior below is expanded
  12   dnl once only, before all statements that occur in other macros.
  13   AC_REQUIRE([gl_SYS_UTSNAME_H_DEFAULTS])
  14
  15   dnl <sys/utsname.h> is always overridden, because of GNULIB_POSIXCHECK.
  16   gl_CHECK_NEXT_HEADERS([sys/utsname.h])
  17   AC_CHECK_HEADERS_ONCE([sys/utsname.h])
  18   if test $ac_cv_header_sys_utsname_h != yes; then
  19     HAVE_SYS_UTSNAME_H=0
  20     HAVE_STRUCT_UTSNAME=0
  21   else
  22     HAVE_SYS_UTSNAME_H=1
  23     AC_CHECK_TYPES([struct utsname], [], [HAVE_STRUCT_UTSNAME=0], [[
  24 #include <sys/utsname.h>
  25       ]])
  26   fi
  27   AC_SUBST([HAVE_SYS_UTSNAME_H])
  28
  29   dnl Check for declarations of anything we want to poison if the
  30   dnl corresponding gnulib module is not in use.
  31   gl_WARN_ON_USE_PREPARE([[#include <sys/utsname.h>
  32     ]], [uname])
  33 ])
  34
  35 AC_DEFUN([gl_SYS_UTSNAME_MODULE_INDICATOR],
  36 [
  37   dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
  38   AC_REQUIRE([gl_SYS_UTSNAME_H_DEFAULTS])
  39   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
  40 ])
  41
  42 AC_DEFUN([gl_SYS_UTSNAME_H_DEFAULTS],
  43 [
  44   GNULIB_UNAME=0;         AC_SUBST([GNULIB_UNAME])
  45   dnl Assume proper GNU behavior unless another module says otherwise.
  46   HAVE_UNAME=1;           AC_SUBST([HAVE_UNAME])
  47   HAVE_STRUCT_UTSNAME=1;  AC_SUBST([HAVE_STRUCT_UTSNAME])
  48 ])