m4/tanl.m4

   1 # tanl.m4 serial 2
   2 dnl Copyright (C) 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_TANL],
   8 [
   9   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  10   dnl Persuade glibc <math.h> to declare tanl().
  11   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  12
  13   TANL_LIBM=
  14   AC_CACHE_CHECK([whether tanl() can be used without linking with libm],
  15     [gl_cv_func_tanl_no_libm],
  16     [
  17       AC_TRY_LINK([#ifndef __NO_MATH_INLINES
  18                    # define __NO_MATH_INLINES 1 /* for glibc */
  19                    #endif
  20                    #include <math.h>
  21                    long double x;],
  22                   [return tanl (x) > 0.4;],
  23         [gl_cv_func_tanl_no_libm=yes],
  24         [gl_cv_func_tanl_no_libm=no])
  25     ])
  26   if test $gl_cv_func_tanl_no_libm = no; then
  27     AC_CACHE_CHECK([whether tanl() can be used with libm],
  28       [gl_cv_func_tanl_in_libm],
  29       [
  30         save_LIBS="$LIBS"
  31         LIBS="$LIBS -lm"
  32         AC_TRY_LINK([#ifndef __NO_MATH_INLINES
  33                      # define __NO_MATH_INLINES 1 /* for glibc */
  34                      #endif
  35                      #include <math.h>
  36                      long double x;],
  37                     [return tanl (x) > 0.4;],
  38           [gl_cv_func_tanl_in_libm=yes],
  39           [gl_cv_func_tanl_in_libm=no])
  40         LIBS="$save_LIBS"
  41       ])
  42     if test $gl_cv_func_tanl_in_libm = yes; then
  43       TANL_LIBM=-lm
  44     fi
  45   fi
  46   if test $gl_cv_func_tanl_no_libm = yes \
  47      || test $gl_cv_func_tanl_in_libm = yes; then
  48     dnl Also check whether it's declared.
  49     dnl MacOS X 10.3 has tanl() in libc but doesn't declare it in <math.h>.
  50     AC_CHECK_DECL([tanl], , [HAVE_DECL_TANL=0], [#include <math.h>])
  51   else
  52     HAVE_DECL_TANL=0
  53     HAVE_TANL=0
  54     AC_LIBOBJ([tanl])
  55     AC_LIBOBJ([trigl])
  56     AC_REQUIRE([gl_FUNC_ISNANL])
  57     AC_REQUIRE([gl_FUNC_FLOOR])
  58     AC_REQUIRE([gl_FUNC_FLOORL])
  59     dnl Append $ISNANL_LIBM to TANL_LIBM, avoiding gratuitous duplicates.
  60     case " $TANL_LIBM " in
  61       *" $ISNANL_LIBM "*) ;;
  62       *) TANL_LIBM="$TANL_LIBM $ISNANL_LIBM" ;;
  63     esac
  64     dnl Append $FLOOR_LIBM to TANL_LIBM, avoiding gratuitous duplicates.
  65     case " $TANL_LIBM " in
  66       *" $FLOOR_LIBM "*) ;;
  67       *) TANL_LIBM="$TANL_LIBM $FLOOR_LIBM" ;;
  68     esac
  69     dnl Append $FLOORL_LIBM to TANL_LIBM, avoiding gratuitous duplicates.
  70     case " $TANL_LIBM " in
  71       *" $FLOORL_LIBM "*) ;;
  72       *) TANL_LIBM="$TANL_LIBM $FLOORL_LIBM" ;;
  73     esac
  74   fi
  75   AC_SUBST([TANL_LIBM])
  76 ])