m4/timegm.m4

   1 # timegm.m4 serial 4
   2 dnl Copyright (C) 2003, 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_TIMEGM],
   8 [
   9   AC_REQUIRE([gl_FUNC_MKTIME])
  10   if test $ac_cv_func_working_mktime = no; then
  11     # Assume that timegm is buggy if mktime is.
  12     AC_LIBOBJ([timegm])
  13     ac_cv_func_timegm=no
  14   else
  15     AC_REPLACE_FUNCS(timegm)
  16   fi
  17   REPLACE_TIMEGM=1
  18   if test $ac_cv_func_timegm = yes; then
  19     AC_CHECK_DECLS([timegm], [REPLACE_TIMEGM=0], [], [#include <time.h>])
  20   fi
  21   if test $REPLACE_TIMEGM = 1; then
  22     gl_PREREQ_TIMEGM
  23   fi
  24 ])
  25
  26 # Prerequisites of lib/timegm.c.
  27 AC_DEFUN([gl_PREREQ_TIMEGM], [
  28   AC_REQUIRE([gl_TIME_R])
  29   AC_REQUIRE([gl_FUNC_MKTIME])
  30   if test $ac_cv_func_working_mktime = yes; then
  31     AC_CHECK_FUNC(__mktime_internal, ,
  32       [# mktime works but it doesn't export __mktime_internal,
  33        # so we need to substitute our own mktime implementation.
  34        AC_LIBOBJ([mktime])
  35        AC_DEFINE([mktime], [rpl_mktime],
  36          [Define to rpl_mktime if the replacement function should be used.])
  37        gl_PREREQ_MKTIME])
  38   fi
  39 ])