m4/timegm.m4

   1 # timegm.m4 serial 3
   2 dnl Copyright (C) 2003 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_TIMEGM],
   8 [
   9   AC_REQUIRE([gl_FUNC_MKTIME])
  10   if test $ac_cv_func_working_mktime = no; then
  11     # Assume that timegm is buggy if mktime is.
  12     AC_LIBOBJ([timegm])
  13     ac_cv_func_timegm=no
  14   else
  15     AC_REPLACE_FUNCS(timegm)
  16   fi
  17   if test $ac_cv_func_timegm = no; then
  18     gl_PREREQ_TIMEGM
  19   fi
  20
  21   AC_CHECK_DECLS([timegm], , , [#include <time.h>])
  22 ])
  23
  24 # Prerequisites of lib/timegm.c.
  25 AC_DEFUN([gl_PREREQ_TIMEGM], [
  26   AC_REQUIRE([gl_TIME_R])
  27   AC_REQUIRE([gl_FUNC_MKTIME])
  28   if test $ac_cv_func_working_mktime = yes; then
  29     AC_CHECK_FUNC(__mktime_internal, ,
  30       [# mktime works but it doesn't export __mktime_internal,
  31        # so we need to substitute our own mktime implementation.
  32        AC_LIBOBJ([mktime])
  33        AC_DEFINE([mktime], [rpl_mktime],
  34          [Define to rpl_mktime if the replacement function should be used.])
  35        gl_PREREQ_MKTIME])
  36   fi
  37 ])