m4/tsearch.m4

   1 # tsearch.m4 serial 4
   2 dnl Copyright (C) 2006-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_TSEARCH],
   8 [
   9   AC_REQUIRE([gl_SEARCH_H_DEFAULTS])
  10   AC_CHECK_FUNCS([tsearch])
  11   if test $ac_cv_func_tsearch = yes; then
  12     dnl On OpenBSD 4.0, the return value of tdelete() is incorrect.
  13     AC_REQUIRE([AC_PROG_CC])
  14     AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  15     AC_CACHE_CHECK([whether tdelete works], [gl_cv_func_tdelete_works],
  16       [
  17         AC_RUN_IFELSE([AC_LANG_SOURCE([[
  18 #include <stddef.h>
  19 #include <search.h>
  20 static int
  21 cmp_fn (const void *a, const void *b)
  22 {
  23   return *(const int *) a - *(const int *) b;
  24 }
  25 int
  26 main ()
  27 {
  28   int x = 0;
  29   void *root = NULL;
  30   if (!(tfind (&x, &root, cmp_fn) == NULL)) return 1;
  31   tsearch (&x, &root, cmp_fn);
  32   if (!(tfind (&x, &root, cmp_fn) != NULL)) return 1;
  33   if (!(tdelete (&x, &root, cmp_fn) != NULL)) return 1;
  34   return 0;
  35 }]])], [gl_cv_func_tdelete_works=yes], [gl_cv_func_tdelete_works=no],
  36             [case "$host_os" in
  37                openbsd*) gl_cv_func_tdelete_works="guessing no";;
  38                *)        gl_cv_func_tdelete_works="guessing yes";;
  39              esac
  40             ])
  41       ])
  42     case "$gl_cv_func_tdelete_works" in
  43       *no)
  44         REPLACE_TSEARCH=1
  45         AC_LIBOBJ([tsearch])
  46         gl_PREREQ_TSEARCH
  47         ;;
  48     esac
  49   else
  50     HAVE_TSEARCH=0
  51     AC_LIBOBJ([tsearch])
  52     gl_PREREQ_TSEARCH
  53   fi
  54 ])
  55
  56 # Prerequisites of lib/tsearch.c.
  57 AC_DEFUN([gl_PREREQ_TSEARCH], [
  58   :
  59 ])