m4/tzset.m4

   1 # serial 4
   2
   3 # Copyright (C) 2003, 2007, 2009-2010 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # See if we have a working tzset function.
   9 # If so, arrange to compile the wrapper function.
  10 # For at least Solaris 2.5.1 and 2.6, this is necessary
  11 # because tzset can clobber the contents of the buffer
  12 # used by localtime.
  13
  14 # Written by Paul Eggert and Jim Meyering.
  15
  16 AC_DEFUN([gl_FUNC_TZSET_CLOBBER],
  17 [
  18   AC_REQUIRE([gl_HEADER_SYS_TIME_H])
  19   AC_CACHE_CHECK([whether tzset clobbers localtime buffer],
  20                  gl_cv_func_tzset_clobber,
  21   [
  22   AC_RUN_IFELSE([AC_LANG_SOURCE([[
  23 #include <time.h>
  24 #include <stdlib.h>
  25
  26 int
  27 main ()
  28 {
  29   time_t t1 = 853958121;
  30   struct tm *p, s;
  31   putenv ("TZ=GMT0");
  32   p = localtime (&t1);
  33   s = *p;
  34   putenv ("TZ=EST+3EDT+2,M10.1.0/00:00:00,M2.3.0/00:00:00");
  35   tzset ();
  36   return (p->tm_year != s.tm_year
  37           || p->tm_mon != s.tm_mon
  38           || p->tm_mday != s.tm_mday
  39           || p->tm_hour != s.tm_hour
  40           || p->tm_min != s.tm_min
  41           || p->tm_sec != s.tm_sec);
  42 }
  43   ]])],
  44        [gl_cv_func_tzset_clobber=no],
  45        [gl_cv_func_tzset_clobber=yes],
  46        [gl_cv_func_tzset_clobber=yes])])
  47
  48   AC_DEFINE([HAVE_RUN_TZSET_TEST], [1],
  49     [Define to 1 if you have run the test for working tzset.])
  50
  51   if test $gl_cv_func_tzset_clobber = yes; then
  52     gl_GETTIMEOFDAY_REPLACE_LOCALTIME
  53
  54     AC_DEFINE([tzset], [rpl_tzset],
  55       [Define to rpl_tzset if the wrapper function should be used.])
  56     AC_DEFINE([TZSET_CLOBBERS_LOCALTIME], [1],
  57       [Define if tzset clobbers localtime's static buffer.])
  58   fi
  59 ])