m4/unlink-busy.m4

   1 #serial 8
   2
   3 dnl From J. David Anglin.
   4
   5 dnl HPUX and other systems can't unlink shared text that is being executed.
   6
   7 # Copyright (C) 2000, 2001, 2004 Free Software Foundation, Inc.
   8 # This file is free software; the Free Software Foundation
   9 # gives unlimited permission to copy and/or distribute it,
  10 # with or without modifications, as long as this notice is preserved.
  11
  12 AC_DEFUN([gl_FUNC_UNLINK_BUSY_TEXT],
  13 [dnl
  14   AC_CACHE_CHECK([whether a running program can be unlinked],
  15     jm_cv_func_unlink_busy_text,
  16     [
  17       AC_TRY_RUN([
  18         main (argc, argv)
  19           int argc;
  20           char **argv;
  21         {
  22           if (!argc)
  23             exit (-1);
  24           exit (unlink (argv[0]));
  25         }
  26         ],
  27       jm_cv_func_unlink_busy_text=yes,
  28       jm_cv_func_unlink_busy_text=no,
  29       jm_cv_func_unlink_busy_text=no
  30       )
  31     ]
  32   )
  33
  34   if test $jm_cv_func_unlink_busy_text = no; then
  35     INSTALL=$ac_install_sh
  36   fi
  37 ])