m4/unlink.m4

   1 # unlink.m4 serial 4
   2 dnl Copyright (C) 2009, 2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_UNLINK],
   8 [
   9   AC_REQUIRE([gl_AC_DOS])
  10   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  11   AC_REQUIRE([AC_CANONICAL_HOST])
  12   dnl Detect Solaris 9 and FreeBSD 7.2 bug.
  13   AC_CACHE_CHECK([whether unlink honors trailing slashes],
  14     [gl_cv_func_unlink_honors_slashes],
  15     [touch conftest.file
  16      # Assume that if we have lstat, we can also check symlinks.
  17      if test $ac_cv_func_lstat = yes; then
  18        ln -s conftest.file conftest.lnk
  19      fi
  20      AC_RUN_IFELSE(
  21        [AC_LANG_PROGRAM(
  22          [[#include <unistd.h>
  23            #include <errno.h>
  24 ]], [[if (!unlink ("conftest.file/") || errno != ENOTDIR) return 1;
  25 #if HAVE_LSTAT
  26       if (!unlink ("conftest.lnk/") || errno != ENOTDIR) return 2;
  27 #endif
  28       ]])],
  29       [gl_cv_func_unlink_honors_slashes=yes],
  30       [gl_cv_func_unlink_honors_slashes=no],
  31       [gl_cv_func_unlink_honors_slashes="guessing no"])
  32      rm -f conftest.file conftest.lnk])
  33   dnl Detect MacOS X 10.5.6 bug: On read-write HFS mounts, unlink("..") or
  34   dnl unlink("../..") succeeds without doing anything.
  35   AC_CACHE_CHECK([whether unlink of a parent directory fails is it should],
  36     [gl_cv_func_unlink_parent_fails],
  37     [case "$host_os" in
  38        darwin*)
  39          if {
  40               # Use the mktemp program if available. If not available, hide the error
  41               # message.
  42               tmp=`(umask 077 && mktemp -d /tmp/gtXXXXXX) 2>/dev/null` &&
  43               test -n "$tmp" && test -d "$tmp"
  44             } ||
  45             {
  46               # Use a simple mkdir command. It is guaranteed to fail if the directory
  47               # already exists.  $RANDOM is bash specific and expands to empty in shells
  48               # other than bash, ksh and zsh.  Its use does not increase security;
  49               # rather, it minimizes the probability of failure in a very cluttered /tmp
  50               # directory.
  51               tmp=/tmp/gt$$-$RANDOM
  52               (umask 077 && mkdir "$tmp")
  53             }; then
  54            mkdir "$tmp/subdir"
  55            export tmp
  56            AC_RUN_IFELSE(
  57              [AC_LANG_SOURCE([[
  58                 #include <stdlib.h>
  59                 #include <unistd.h>
  60                 int main ()
  61                 {
  62                   if (chdir (getenv ("tmp")) != 0)
  63                     return 1;
  64                   return unlink ("..") == 0;
  65                 }
  66               ]])],
  67              [gl_cv_func_unlink_parent_fails=yes],
  68              [gl_cv_func_unlink_parent_fails=no],
  69              [gl_cv_func_unlink_parent_fails="guessing no"])
  70            rm -rf "$tmp"
  71            unset tmp
  72          else
  73            gl_cv_func_unlink_parent_fails="guessing no"
  74          fi
  75          ;;
  76        *)
  77          gl_cv_func_unlink_parent_fails="guessing yes"
  78          ;;
  79      esac
  80     ])
  81   case "$gl_cv_func_unlink_parent_fails" in
  82     *no)
  83       AC_DEFINE([UNLINK_PARENT_BUG], [1],
  84         [Define to 1 if unlink() on a parent directory may succeed])
  85       ;;
  86   esac
  87   if test "$gl_cv_func_unlink_honors_slashes" != yes \
  88      || { case "$gl_cv_func_unlink_parent_fails" in
  89             *yes) false;;
  90             *no) true;;
  91           esac
  92         }; then
  93     REPLACE_UNLINK=1
  94     AC_LIBOBJ([unlink])
  95   fi
  96 ])