utimens: fix regression on Solaris
[gnulib.git] / m4 / utimens.m4
1 dnl Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008, 2009 Free
2 dnl Software Foundation, Inc.
3 dnl This file is free software; the Free Software Foundation
4 dnl gives unlimited permission to copy and/or distribute it,
5 dnl with or without modifications, as long as this notice is preserved.
6
7 dnl serial 4
8
9 AC_DEFUN([gl_UTIMENS],
10 [
11   AC_LIBOBJ([utimens])
12
13   dnl Prerequisites of lib/utimens.c.
14   AC_REQUIRE([gl_FUNC_UTIMES])
15   AC_REQUIRE([gl_CHECK_TYPE_STRUCT_TIMESPEC])
16   AC_REQUIRE([gl_CHECK_TYPE_STRUCT_UTIMBUF])
17   AC_CHECK_FUNCS_ONCE([futimes futimesat futimens utimensat lutimes])
18
19   if test $ac_cv_func_futimens = no && test $ac_cv_func_futimesat = yes; then
20     dnl FreeBSD 8.0-rc2 mishandles futimesat(fd,NULL,time).  It is not
21     dnl standardized, but Solaris implemented it first and uses it as
22     dnl its only means to set fd time.
23     AC_CACHE_CHECK([whether futimesat handles NULL file],
24       [gl_cv_func_futimesat_works],
25       [touch conftest.file
26        AC_RUN_IFELSE([AC_LANG_PROGRAM([[
27 #include <stddef.h>
28 #include <sys/times.h>
29 ]], [[    int fd = open ("conftest.file", O_RDWR);
30           if (fd < 0) return 1;
31           if (futimesat (fd, NULL, NULL)) return 2;
32         ]])],
33         [gl_cv_func_futimesat_works=yes],
34         [gl_cv_func_futimesat_works=no],
35         [gl_cv_func_futimesat_works="guessing no"])
36       rm -f conftest.file])
37     if test "$gl_cv_func_futimesat_works" != yes; then
38       AC_DEFINE([FUTIMESAT_NULL_BUG], [1],
39         [Define to 1 if futimesat mishandles a NULL file name.])
40     fi
41   fi
42 ])