m4/utimes.m4

   1 # Detect some bugs in glibc's implementation of utimes.
   2 # serial 3
   3
   4 dnl Copyright (C) 2003-2005, 2009-2010 Free Software Foundation, Inc.
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # See if we need to work around bugs in glibc's implementation of
  10 # utimes from 2003-07-12 to 2003-09-17.
  11 # First, there was a bug that would make utimes set mtime
  12 # and atime to zero (1970-01-01) unconditionally.
  13 # Then, there was code to round rather than truncate.
  14 # Then, there was an implementation (sparc64, Linux-2.4.28, glibc-2.3.3)
  15 # that didn't honor the NULL-means-set-to-current-time semantics.
  16 # Finally, there was also a version of utimes that failed on read-only
  17 # files, while utime worked fine (linux-2.2.20, glibc-2.2.5).
  18 #
  19 # From Jim Meyering, with suggestions from Paul Eggert.
  20
  21 AC_DEFUN([gl_FUNC_UTIMES],
  22 [
  23   AC_CACHE_CHECK([whether the utimes function works],
  24                  [gl_cv_func_working_utimes],
  25   [
  26   AC_RUN_IFELSE([AC_LANG_SOURCE([[
  27 #include <sys/types.h>
  28 #include <sys/stat.h>
  29 #include <fcntl.h>
  30 #include <sys/time.h>
  31 #include <time.h>
  32 #include <unistd.h>
  33 #include <stdlib.h>
  34 #include <stdio.h>
  35 #include <utime.h>
  36
  37 int
  38 main ()
  39 {
  40   int result = 0;
  41   char const *file = "conftest.utimes";
  42
  43   /* Test whether utimes() essentially works.  */
  44   {
  45     static struct timeval timeval[2] = {{9, 10}, {999999, 999999}};
  46     struct stat sbuf;
  47     FILE *f = fopen (file, "w");
  48     if (f == NULL)
  49       result |= 1;
  50     else if (fclose (f) != 0)
  51       result |= 1;
  52     else if (utimes (file, timeval) != 0)
  53       result |= 2;
  54     else if (lstat (file, &sbuf) != 0)
  55       result |= 1;
  56     else if (!(sbuf.st_atime == timeval[0].tv_sec
  57                && sbuf.st_mtime == timeval[1].tv_sec))
  58       result |= 4;
  59     unlink (file);
  60   }
  61
  62   /* Test whether utimes() with a NULL argument sets the file's timestamp
  63      to the current time.  Note that this test fails on NFS file systems
  64      if there is a time skew between the host and the NFS server.  */
  65   {
  66     struct stat sbuf;
  67     FILE *f = fopen (file, "w");
  68     if (f == NULL)
  69       result |= 1;
  70     else if (fclose (f) != 0)
  71       result |= 1;
  72     else
  73       {
  74         time_t now;
  75         if (time (&now) == (time_t)-1)
  76           result |= 1;
  77         else if (utimes (file, NULL) != 0)
  78           result |= 8;
  79         else if (lstat (file, &sbuf) != 0)
  80           result |= 1;
  81         else
  82           {
  83             if (!(now - sbuf.st_atime <= 2))
  84               result |= 16;
  85             if (!(now - sbuf.st_mtime <= 2))
  86               result |= 32;
  87           }
  88       }
  89     unlink (file);
  90   }
  91
  92   /* Test whether utimes() with a NULL argument works on read-only files.  */
  93   {
  94     int fd = open (file, O_WRONLY|O_CREAT, 0444);
  95     if (fd < 0)
  96       result |= 1;
  97     else if (close (fd) != 0)
  98       result |= 1;
  99     else if (utimes (file, NULL) != 0)
 100       result |= 64;
 101     unlink (file);
 102   }
 103
 104   return result;
 105 }
 106   ]])],
 107        [gl_cv_func_working_utimes=yes],
 108        [gl_cv_func_working_utimes=no],
 109        [gl_cv_func_working_utimes=no])])
 110
 111   if test $gl_cv_func_working_utimes = yes; then
 112     AC_DEFINE([HAVE_WORKING_UTIMES], [1], [Define if utimes works properly. ])
 113   fi
 114 ])