m4/vasnprintf-posix.m4

   1 # vasnprintf-posix.m4 serial 5
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_VASNPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  12   AC_REQUIRE([gl_PRINTF_DIRECTIVE_F])
  13   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  14   AC_REQUIRE([gl_PRINTF_POSITIONS])
  15   AC_REQUIRE([gl_PRINTF_FLAG_GROUPING])
  16   gl_cv_func_vasnprintf_posix=no
  17   AC_CHECK_FUNCS_ONCE([vasnprintf])
  18   case "$gl_cv_func_printf_sizes_c99" in
  19     *yes)
  20       case "$gl_cv_func_printf_directive_a" in
  21         *yes)
  22           case "$gl_cv_func_printf_directive_f" in
  23             *yes)
  24               case "$gl_cv_func_printf_directive_n" in
  25                 *yes)
  26                   case "$gl_cv_func_printf_positions" in
  27                     *yes)
  28                       case "$gl_cv_func_printf_flag_grouping" in
  29                         *yes)
  30                           if test $ac_cv_func_vasnprintf = yes; then
  31                             # vasnprintf exists and is already POSIX compliant.
  32                             gl_cv_func_vasnprintf_posix=yes
  33                           fi
  34                           ;;
  35                       esac
  36                       ;;
  37                   esac
  38                   ;;
  39               esac
  40               ;;
  41           esac
  42           ;;
  43       esac
  44       ;;
  45   esac
  46   if test $gl_cv_func_vasnprintf_posix = no; then
  47     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
  48     gl_PREREQ_VASNPRINTF_DIRECTIVE_F
  49     gl_PREREQ_VASNPRINTF_FLAG_GROUPING
  50     gl_REPLACE_VASNPRINTF
  51   fi
  52 ])