m4/vasnprintf-posix.m4

   1 # vasnprintf-posix.m4 serial 8
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_VASNPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_INFINITE])
  12   AC_REQUIRE([gl_PRINTF_LONG_DOUBLE])
  13   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  14   AC_REQUIRE([gl_PRINTF_DIRECTIVE_F])
  15   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  16   AC_REQUIRE([gl_PRINTF_POSITIONS])
  17   AC_REQUIRE([gl_PRINTF_FLAG_GROUPING])
  18   AC_REQUIRE([gl_PRINTF_FLAG_ZERO])
  19   gl_cv_func_vasnprintf_posix=no
  20   AC_CHECK_FUNCS_ONCE([vasnprintf])
  21   case "$gl_cv_func_printf_sizes_c99" in
  22     *yes)
  23       case "$gl_cv_func_printf_infinite" in
  24         *yes)
  25           case "$gl_cv_func_printf_long_double" in
  26             *yes)
  27               case "$gl_cv_func_printf_directive_a" in
  28                 *yes)
  29                   case "$gl_cv_func_printf_directive_f" in
  30                     *yes)
  31                       case "$gl_cv_func_printf_directive_n" in
  32                         *yes)
  33                           case "$gl_cv_func_printf_positions" in
  34                             *yes)
  35                               case "$gl_cv_func_printf_flag_grouping" in
  36                                 *yes)
  37                                   case "$gl_cv_func_printf_flag_zero" in
  38                                     *yes)
  39                                       if test $ac_cv_func_vasnprintf = yes; then
  40                                         # vasnprintf exists and is already POSIX
  41                                         # compliant.
  42                                         gl_cv_func_vasnprintf_posix=yes
  43                                       fi
  44                                       ;;
  45                                   esac
  46                                   ;;
  47                               esac
  48                               ;;
  49                           esac
  50                           ;;
  51                       esac
  52                       ;;
  53                   esac
  54                   ;;
  55               esac
  56               ;;
  57           esac
  58           ;;
  59       esac
  60       ;;
  61   esac
  62   if test $gl_cv_func_vasnprintf_posix = no; then
  63     gl_PREREQ_VASNPRINTF_INFINITE
  64     gl_PREREQ_VASNPRINTF_LONG_DOUBLE
  65     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
  66     gl_PREREQ_VASNPRINTF_DIRECTIVE_F
  67     gl_PREREQ_VASNPRINTF_FLAG_GROUPING
  68     gl_PREREQ_VASNPRINTF_FLAG_ZERO
  69     gl_REPLACE_VASNPRINTF
  70   fi
  71 ])