m4/vasnprintf-posix.m4

   1 # vasnprintf-posix.m4 serial 9
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_VASNPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_LONG_DOUBLE])
  12   AC_REQUIRE([gl_PRINTF_INFINITE])
  13   AC_REQUIRE([gl_PRINTF_INFINITE_LONG_DOUBLE])
  14   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  15   AC_REQUIRE([gl_PRINTF_DIRECTIVE_F])
  16   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  17   AC_REQUIRE([gl_PRINTF_POSITIONS])
  18   AC_REQUIRE([gl_PRINTF_FLAG_GROUPING])
  19   AC_REQUIRE([gl_PRINTF_FLAG_ZERO])
  20   AC_REQUIRE([gl_PRINTF_ENOMEM])
  21   gl_cv_func_vasnprintf_posix=no
  22   AC_CHECK_FUNCS_ONCE([vasnprintf])
  23   case "$gl_cv_func_printf_sizes_c99" in
  24     *yes)
  25       case "$gl_cv_func_printf_long_double" in
  26         *yes)
  27           case "$gl_cv_func_printf_infinite" in
  28             *yes)
  29               case "$gl_cv_func_printf_infinite_long_double" in
  30                 *yes)
  31                   case "$gl_cv_func_printf_directive_a" in
  32                     *yes)
  33                       case "$gl_cv_func_printf_directive_f" in
  34                         *yes)
  35                           case "$gl_cv_func_printf_directive_n" in
  36                             *yes)
  37                               case "$gl_cv_func_printf_positions" in
  38                                 *yes)
  39                                   case "$gl_cv_func_printf_flag_grouping" in
  40                                     *yes)
  41                                       case "$gl_cv_func_printf_flag_zero" in
  42                                         *yes)
  43                                           case "$gl_cv_func_printf_enomem" in
  44                                             *yes)
  45                                               if test $ac_cv_func_vasnprintf = yes; then
  46                                                 # vasnprintf exists and is already
  47                                                 # POSIX compliant.
  48                                                 gl_cv_func_vasnprintf_posix=yes
  49                                               fi
  50                                               ;;
  51                                           esac
  52                                           ;;
  53                                       esac
  54                                       ;;
  55                                   esac
  56                                   ;;
  57                               esac
  58                               ;;
  59                           esac
  60                           ;;
  61                       esac
  62                       ;;
  63                   esac
  64                   ;;
  65               esac
  66               ;;
  67           esac
  68           ;;
  69       esac
  70       ;;
  71   esac
  72   if test $gl_cv_func_vasnprintf_posix = no; then
  73     gl_PREREQ_VASNPRINTF_LONG_DOUBLE
  74     gl_PREREQ_VASNPRINTF_INFINITE_DOUBLE
  75     gl_PREREQ_VASNPRINTF_INFINITE_LONG_DOUBLE
  76     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
  77     gl_PREREQ_VASNPRINTF_DIRECTIVE_F
  78     gl_PREREQ_VASNPRINTF_FLAG_GROUPING
  79     gl_PREREQ_VASNPRINTF_FLAG_ZERO
  80     gl_PREREQ_VASNPRINTF_ENOMEM
  81     gl_REPLACE_VASNPRINTF
  82   fi
  83 ])