m4/vasprintf-posix.m4

   1 # vasprintf-posix.m4 serial 6
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_VASPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  12   AC_REQUIRE([gl_PRINTF_DIRECTIVE_F])
  13   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  14   AC_REQUIRE([gl_PRINTF_POSITIONS])
  15   AC_REQUIRE([gl_PRINTF_FLAG_GROUPING])
  16   AC_REQUIRE([gl_PRINTF_FLAG_ZERO])
  17   gl_cv_func_vasprintf_posix=no
  18   AC_CHECK_FUNCS([vasprintf])
  19   case "$gl_cv_func_printf_sizes_c99" in
  20     *yes)
  21       case "$gl_cv_func_printf_directive_a" in
  22         *yes)
  23           case "$gl_cv_func_printf_directive_f" in
  24             *yes)
  25               case "$gl_cv_func_printf_directive_n" in
  26                 *yes)
  27                   case "$gl_cv_func_printf_positions" in
  28                     *yes)
  29                       case "$gl_cv_func_printf_flag_grouping" in
  30                         *yes)
  31                           case "$gl_cv_func_printf_flag_zero" in
  32                             *yes)
  33                               if test $ac_cv_func_vasprintf = yes; then
  34                                 # vasprintf exists and is already POSIX
  35                                 # compliant.
  36                                 gl_cv_func_vasprintf_posix=yes
  37                               fi
  38                               ;;
  39                           esac
  40                           ;;
  41                       esac
  42                       ;;
  43                   esac
  44                   ;;
  45               esac
  46               ;;
  47           esac
  48           ;;
  49       esac
  50       ;;
  51   esac
  52   if test $gl_cv_func_vasprintf_posix = no; then
  53     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
  54     gl_PREREQ_VASNPRINTF_DIRECTIVE_F
  55     gl_PREREQ_VASNPRINTF_FLAG_GROUPING
  56     gl_PREREQ_VASNPRINTF_FLAG_ZERO
  57     gl_REPLACE_VASNPRINTF
  58     gl_REPLACE_VASPRINTF
  59   fi
  60 ])