m4/vasprintf-posix.m4

   1 # vasprintf-posix.m4 serial 8
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_VASPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_LONG_DOUBLE])
  12   AC_REQUIRE([gl_PRINTF_INFINITE])
  13   AC_REQUIRE([gl_PRINTF_INFINITE_LONG_DOUBLE])
  14   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  15   AC_REQUIRE([gl_PRINTF_DIRECTIVE_F])
  16   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  17   AC_REQUIRE([gl_PRINTF_POSITIONS])
  18   AC_REQUIRE([gl_PRINTF_FLAG_GROUPING])
  19   AC_REQUIRE([gl_PRINTF_FLAG_ZERO])
  20   gl_cv_func_vasprintf_posix=no
  21   AC_CHECK_FUNCS([vasprintf])
  22   case "$gl_cv_func_printf_sizes_c99" in
  23     *yes)
  24       case "$gl_cv_func_printf_long_double" in
  25         *yes)
  26           case "$gl_cv_func_printf_infinite" in
  27             *yes)
  28               case "$gl_cv_func_printf_infinite_long_double" in
  29                 *yes)
  30                   case "$gl_cv_func_printf_directive_a" in
  31                     *yes)
  32                       case "$gl_cv_func_printf_directive_f" in
  33                         *yes)
  34                           case "$gl_cv_func_printf_directive_n" in
  35                             *yes)
  36                               case "$gl_cv_func_printf_positions" in
  37                                 *yes)
  38                                   case "$gl_cv_func_printf_flag_grouping" in
  39                                     *yes)
  40                                       case "$gl_cv_func_printf_flag_zero" in
  41                                         *yes)
  42                                           if test $ac_cv_func_vasprintf = yes; then
  43                                             # vasprintf exists and is already
  44                                             # POSIX compliant.
  45                                             gl_cv_func_vasprintf_posix=yes
  46                                           fi
  47                                           ;;
  48                                       esac
  49                                       ;;
  50                                   esac
  51                                   ;;
  52                               esac
  53                               ;;
  54                           esac
  55                           ;;
  56                       esac
  57                       ;;
  58                   esac
  59                   ;;
  60               esac
  61               ;;
  62           esac
  63           ;;
  64       esac
  65       ;;
  66   esac
  67   if test $gl_cv_func_vasprintf_posix = no; then
  68     gl_PREREQ_VASNPRINTF_LONG_DOUBLE
  69     gl_PREREQ_VASNPRINTF_INFINITE_DOUBLE
  70     gl_PREREQ_VASNPRINTF_INFINITE_LONG_DOUBLE
  71     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
  72     gl_PREREQ_VASNPRINTF_DIRECTIVE_F
  73     gl_PREREQ_VASNPRINTF_FLAG_GROUPING
  74     gl_PREREQ_VASNPRINTF_FLAG_ZERO
  75     gl_REPLACE_VASNPRINTF
  76     gl_REPLACE_VASPRINTF
  77   fi
  78 ])