m4/vsnprintf-posix.m4

   1 # vsnprintf-posix.m4 serial 8
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_VSNPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_LONG_DOUBLE])
  12   AC_REQUIRE([gl_PRINTF_INFINITE])
  13   AC_REQUIRE([gl_PRINTF_INFINITE_LONG_DOUBLE])
  14   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  15   AC_REQUIRE([gl_PRINTF_DIRECTIVE_F])
  16   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  17   AC_REQUIRE([gl_PRINTF_POSITIONS])
  18   AC_REQUIRE([gl_PRINTF_FLAG_GROUPING])
  19   AC_REQUIRE([gl_PRINTF_FLAG_ZERO])
  20   gl_cv_func_vsnprintf_posix=no
  21   AC_CHECK_FUNCS([vsnprintf])
  22   if test $ac_cv_func_vsnprintf = yes; then
  23     dnl Assume that if vsnprintf() exists, snprintf() also exists.
  24     gl_SNPRINTF_TRUNCATION_C99
  25     gl_SNPRINTF_RETVAL_C99
  26     gl_SNPRINTF_DIRECTIVE_N
  27     gl_VSNPRINTF_ZEROSIZE_C99
  28     case "$gl_cv_func_printf_sizes_c99" in
  29       *yes)
  30         case "$gl_cv_func_printf_long_double" in
  31           *yes)
  32             case "$gl_cv_func_printf_infinite" in
  33               *yes)
  34                 case "$gl_cv_func_printf_infinite_long_double" in
  35                   *yes)
  36                     case "$gl_cv_func_printf_directive_a" in
  37                       *yes)
  38                         case "$gl_cv_func_printf_directive_f" in
  39                           *yes)
  40                             case "$gl_cv_func_printf_directive_n" in
  41                               *yes)
  42                                 case "$gl_cv_func_printf_positions" in
  43                                   *yes)
  44                                     case "$gl_cv_func_printf_flag_grouping" in
  45                                       *yes)
  46                                         case "$gl_cv_func_printf_flag_zero" in
  47                                           *yes)
  48                                             case "$gl_cv_func_snprintf_truncation_c99" in
  49                                               *yes)
  50                                                 case "$gl_cv_func_snprintf_retval_c99" in
  51                                                   *yes)
  52                                                     case "$gl_cv_func_snprintf_directive_n" in
  53                                                       *yes)
  54                                                         case "$gl_cv_func_vsnprintf_zerosize_c99" in
  55                                                           *yes)
  56                                                             # vsnprintf exists and is
  57                                                             # already POSIX compliant.
  58                                                             gl_cv_func_vsnprintf_posix=yes
  59                                                             ;;
  60                                                         esac
  61                                                         ;;
  62                                                     esac
  63                                                     ;;
  64                                                 esac
  65                                                 ;;
  66                                             esac
  67                                             ;;
  68                                         esac
  69                                         ;;
  70                                     esac
  71                                     ;;
  72                                 esac
  73                                 ;;
  74                             esac
  75                             ;;
  76                         esac
  77                         ;;
  78                     esac
  79                     ;;
  80                 esac
  81                 ;;
  82             esac
  83             ;;
  84         esac
  85         ;;
  86     esac
  87   fi
  88   if test $gl_cv_func_vsnprintf_posix = no; then
  89     gl_PREREQ_VASNPRINTF_LONG_DOUBLE
  90     gl_PREREQ_VASNPRINTF_INFINITE_DOUBLE
  91     gl_PREREQ_VASNPRINTF_INFINITE_LONG_DOUBLE
  92     gl_PREREQ_VASNPRINTF_DIRECTIVE_A
  93     gl_PREREQ_VASNPRINTF_DIRECTIVE_F
  94     gl_PREREQ_VASNPRINTF_FLAG_GROUPING
  95     gl_PREREQ_VASNPRINTF_FLAG_ZERO
  96     gl_REPLACE_VASNPRINTF
  97     gl_REPLACE_VSNPRINTF
  98   fi
  99 ])