m4/vsnprintf-posix.m4

   1 # vsnprintf-posix.m4 serial 1
   2 dnl Copyright (C) 2007 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_VSNPRINTF_POSIX],
   8 [
   9   AC_REQUIRE([gl_EOVERFLOW])
  10   AC_REQUIRE([gl_PRINTF_SIZES_C99])
  11   AC_REQUIRE([gl_PRINTF_DIRECTIVE_A])
  12   AC_REQUIRE([gl_PRINTF_DIRECTIVE_N])
  13   AC_REQUIRE([gl_PRINTF_POSITIONS])
  14   gl_cv_func_vsnprintf_posix=no
  15   AC_CHECK_FUNCS([vsnprintf])
  16   if test $ac_cv_func_vsnprintf = yes; then
  17     dnl Assume that if vsnprintf() exists, snprintf() also exists.
  18     gl_SNPRINTF_TRUNCATION_C99
  19     gl_SNPRINTF_RETVAL_C99
  20     gl_SNPRINTF_DIRECTIVE_N
  21     case "$gl_cv_func_printf_sizes_c99" in
  22       *yes)
  23         case "$gl_cv_func_printf_directive_a" in
  24           *yes)
  25             case "$gl_cv_func_printf_directive_n" in
  26               *yes)
  27                 case "$gl_cv_func_printf_positions" in
  28                   *yes)
  29                     case "$gl_cv_func_snprintf_truncation_c99" in
  30                       *yes)
  31                         case "$gl_cv_func_snprintf_retval_c99" in
  32                           *yes)
  33                             case "$gl_cv_func_snprintf_directive_n" in
  34                               *yes)
  35                                 # vsnprintf exists and is already POSIX
  36                                 # compliant.
  37                                 gl_cv_func_vsnprintf_posix=yes
  38                                 ;;
  39                             esac
  40                             ;;
  41                         esac
  42                         ;;
  43                     esac
  44                     ;;
  45                 esac
  46                 ;;
  47             esac
  48             ;;
  49         esac
  50         ;;
  51     esac
  52   fi
  53   if test $gl_cv_func_vsnprintf_posix = no; then
  54     if ! expr "$gl_cv_func_printf_directive_a" : ".*yes" > /dev/null; then
  55       AC_DEFINE([NEED_PRINTF_DIRECTIVE_A], 1,
  56         [Define if the vasnprintf implementation needs special code for
  57          the 'a' and 'A' directives.])
  58     fi
  59     gl_REPLACE_VASNPRINTF
  60     gl_REPLACE_VSNPRINTF
  61   fi
  62 ])