m4/wcrtomb.m4

   1 # wcrtomb.m4 serial 7
   2 dnl Copyright (C) 2008-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_WCRTOMB],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10
  11   AC_REQUIRE([AC_TYPE_MBSTATE_T])
  12   gl_MBSTATE_T_BROKEN
  13
  14   AC_CHECK_FUNCS_ONCE([wcrtomb])
  15   if test $ac_cv_func_wcrtomb = no; then
  16     HAVE_WCRTOMB=0
  17   else
  18     if test $REPLACE_MBSTATE_T = 1; then
  19       REPLACE_WCRTOMB=1
  20     else
  21       dnl On AIX 4.3, OSF/1 5.1 and Solaris 10, wcrtomb (NULL, 0, NULL) sometimes
  22       dnl returns 0 instead of 1.
  23       AC_REQUIRE([AC_PROG_CC])
  24       AC_REQUIRE([gt_LOCALE_FR])
  25       AC_REQUIRE([gt_LOCALE_FR_UTF8])
  26       AC_REQUIRE([gt_LOCALE_JA])
  27       AC_REQUIRE([gt_LOCALE_ZH_CN])
  28       AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  29       AC_CACHE_CHECK([whether wcrtomb return value is correct],
  30         [gl_cv_func_wcrtomb_retval],
  31         [
  32           dnl Initial guess, used when cross-compiling or when no suitable locale
  33           dnl is present.
  34 changequote(,)dnl
  35           case "$host_os" in
  36                                      # Guess no on AIX 4, OSF/1 and Solaris.
  37             aix4* | osf* | solaris*) gl_cv_func_wcrtomb_retval="guessing no" ;;
  38                                      # Guess yes otherwise.
  39             *)                       gl_cv_func_wcrtomb_retval="guessing yes" ;;
  40           esac
  41 changequote([,])dnl
  42           if test $LOCALE_FR != none || test $LOCALE_FR_UTF8 != none || test $LOCALE_JA != none || test $LOCALE_ZH_CN != none; then
  43             AC_RUN_IFELSE(
  44               [AC_LANG_SOURCE([[
  45 #include <locale.h>
  46 #include <stdio.h>
  47 #include <string.h>
  48 #include <wchar.h>
  49 int main ()
  50 {
  51   int result = 0;
  52   if (setlocale (LC_ALL, "$LOCALE_FR") != NULL)
  53     {
  54       if (wcrtomb (NULL, 0, NULL) != 1)
  55         result |= 1;
  56     }
  57   if (setlocale (LC_ALL, "$LOCALE_FR_UTF8") != NULL)
  58     {
  59       if (wcrtomb (NULL, 0, NULL) != 1)
  60         result |= 2;
  61     }
  62   if (setlocale (LC_ALL, "$LOCALE_JA") != NULL)
  63     {
  64       if (wcrtomb (NULL, 0, NULL) != 1)
  65         result |= 4;
  66     }
  67   if (setlocale (LC_ALL, "$LOCALE_ZH_CN") != NULL)
  68     {
  69       if (wcrtomb (NULL, 0, NULL) != 1)
  70         result |= 8;
  71     }
  72   return result;
  73 }]])],
  74               [gl_cv_func_wcrtomb_retval=yes],
  75               [gl_cv_func_wcrtomb_retval=no],
  76               [:])
  77           fi
  78         ])
  79       case "$gl_cv_func_wcrtomb_retval" in
  80         *yes) ;;
  81         *) REPLACE_WCRTOMB=1 ;;
  82       esac
  83     fi
  84   fi
  85   if test $HAVE_WCRTOMB = 0 || test $REPLACE_WCRTOMB = 1; then
  86     gl_REPLACE_WCHAR_H
  87     AC_LIBOBJ([wcrtomb])
  88     gl_PREREQ_WCRTOMB
  89   fi
  90 ])
  91
  92 # Prerequisites of lib/wcrtomb.c.
  93 AC_DEFUN([gl_PREREQ_WCRTOMB], [
  94   :
  95 ])