m4/wctob.m4

   1 # wctob.m4 serial 6
   2 dnl Copyright (C) 2008-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_WCTOB],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10
  11   AC_CHECK_FUNCS_ONCE([wctob])
  12   if test $ac_cv_func_wctob = no; then
  13     HAVE_DECL_WCTOB=0
  14     gl_REPLACE_WCHAR_H
  15     AC_LIBOBJ([wctob])
  16     gl_PREREQ_WCTOB
  17   else
  18
  19     dnl Solaris 9 has the wctob() function but it does not work.
  20     dnl Cygwin 1.7.2 has the wctob() function but it clobbers caller-owned
  21     dnl registers, see <http://cygwin.com/ml/cygwin/2010-05/msg00015.html>.
  22     AC_REQUIRE([AC_PROG_CC])
  23     AC_REQUIRE([gt_LOCALE_FR])
  24     AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  25     AC_CACHE_CHECK([whether wctob works],
  26       [gl_cv_func_wctob_works],
  27       [
  28         dnl Initial guess, used when cross-compiling or when no suitable locale
  29         dnl is present.
  30 changequote(,)dnl
  31         case "$host_os" in
  32             # Guess no on Solaris <= 9 and Cygwin.
  33           solaris2.[1-9] | solaris2.[1-9].* | cygwin*)
  34             gl_cv_func_wctob_works="guessing no" ;;
  35             # Guess yes otherwise.
  36           *) gl_cv_func_wctob_works="guessing yes" ;;
  37         esac
  38 changequote([,])dnl
  39         case "$host_os" in
  40           cygwin*)
  41             AC_RUN_IFELSE(
  42               [AC_LANG_SOURCE([[
  43 #include <locale.h>
  44 #include <wchar.h>
  45
  46 register long global __asm__ ("%ebx");
  47
  48 int main ()
  49 {
  50   setlocale (LC_ALL, "en_US.UTF-8");
  51
  52   global = 0x12345678;
  53   if (wctob (0x00FC) != -1)
  54     return 1;
  55   if (global != 0x12345678)
  56     return 2;
  57   return 0;
  58 }]])],
  59               [:],
  60               [gl_cv_func_wctob_works=no],
  61               [:])
  62             ;;
  63         esac
  64         if test "$gl_cv_func_wctob_works" != no && test $LOCALE_FR != none; then
  65           AC_RUN_IFELSE(
  66             [AC_LANG_SOURCE([[
  67 #include <locale.h>
  68 #include <string.h>
  69 #include <wchar.h>
  70 int main ()
  71 {
  72   if (setlocale (LC_ALL, "$LOCALE_FR") != NULL)
  73     {
  74       wchar_t wc;
  75
  76       if (mbtowc (&wc, "\374", 1) == 1)
  77         if (wctob (wc) != (unsigned char) '\374')
  78           return 1;
  79     }
  80   return 0;
  81 }]])],
  82             [gl_cv_func_wctob_works=yes],
  83             [gl_cv_func_wctob_works=no],
  84             [:])
  85         fi
  86       ])
  87     case "$gl_cv_func_wctob_works" in
  88       *yes) ;;
  89       *) REPLACE_WCTOB=1 ;;
  90     esac
  91     if test $REPLACE_WCTOB = 1; then
  92       gl_REPLACE_WCHAR_H
  93       AC_LIBOBJ([wctob])
  94       gl_PREREQ_WCTOB
  95     else
  96
  97       dnl IRIX 6.5 has the wctob() function but does not declare it.
  98       AC_CHECK_DECLS([wctob], [], [], [
  99 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
 100    <wchar.h>.
 101    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
 102    before <wchar.h>.  */
 103 #include <stddef.h>
 104 #include <stdio.h>
 105 #include <time.h>
 106 #include <wchar.h>
 107 ])
 108       if test $ac_cv_have_decl_wctob != yes; then
 109         HAVE_DECL_WCTOB=0
 110         gl_REPLACE_WCHAR_H
 111       fi
 112     fi
 113   fi
 114 ])
 115
 116 # Prerequisites of lib/wctob.c.
 117 AC_DEFUN([gl_PREREQ_WCTOB], [
 118   :
 119 ])