m4/wctob.m4

   1 # wctob.m4 serial 2
   2 dnl Copyright (C) 2008 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_WCTOB],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10
  11   AC_CHECK_FUNCS_ONCE([wctob])
  12   if test $ac_cv_func_wctob = no; then
  13     HAVE_DECL_WCTOB=0
  14     gl_REPLACE_WCHAR_H
  15     AC_LIBOBJ([wctob])
  16     gl_PREREQ_WCTOB
  17   else
  18     dnl IRIX 6.5 has the wctob() function but does not declare it.
  19     AC_CHECK_DECLS([wctob], [], [], [
  20 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  21    <wchar.h>.
  22    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
  23    before <wchar.h>.  */
  24 #include <stddef.h>
  25 #include <stdio.h>
  26 #include <time.h>
  27 #include <wchar.h>
  28 ])
  29     if test $ac_cv_have_decl_wctob != yes; then
  30       HAVE_DECL_WCTOB=0
  31       gl_REPLACE_WCHAR_H
  32     fi
  33   fi
  34 ])
  35
  36 # Prerequisites of lib/wctob.c.
  37 AC_DEFUN([gl_PREREQ_WCTOB], [
  38   :
  39 ])