m4/wcwidth.m4

   1 # wcwidth.m4 serial 1
   2 dnl Copyright (C) 2006 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl autoconf tests required for use of mbswidth.c
   8
   9 AC_DEFUN([gl_FUNC_WCWIDTH],
  10 [ AC_CHECK_HEADERS_ONCE([wchar.h wctype.h])
  11   AC_CHECK_FUNCS_ONCE([iswprint wcwidth])
  12
  13   AC_REQUIRE([AC_GNU_SOURCE])
  14
  15   AC_CACHE_CHECK([whether wcwidth is declared], [ac_cv_have_decl_wcwidth],
  16     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
  17 /* AIX 3.2.5 declares wcwidth in <string.h>. */
  18 #if HAVE_STRING_H
  19 # include <string.h>
  20 #endif
  21 #if HAVE_WCHAR_H
  22 # include <wchar.h>
  23 #endif
  24 ], [
  25 #ifndef wcwidth
  26   char *p = (char *) wcwidth;
  27 #endif
  28 ])], [ac_cv_have_decl_wcwidth=yes], [ac_cv_have_decl_wcwidth=no])])
  29   if test $ac_cv_have_decl_wcwidth = yes; then
  30     ac_val=1
  31   else
  32     ac_val=0
  33   fi
  34   AC_DEFINE_UNQUOTED([HAVE_DECL_WCWIDTH], [$ac_val],
  35     [Define to 1 if you have the declaration of wcwidth(), and to 0
  36      otherwise.])
  37 ])