m4/wcwidth.m4

   1 # wcwidth.m4 serial 20
   2 dnl Copyright (C) 2006-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_WCWIDTH],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  11
  12   dnl Persuade glibc <wchar.h> to declare wcwidth().
  13   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  14
  15   AC_REQUIRE([gt_TYPE_WCHAR_T])
  16   AC_REQUIRE([gt_TYPE_WINT_T])
  17
  18   AC_CHECK_HEADERS_ONCE([wchar.h])
  19   AC_CHECK_FUNCS_ONCE([wcwidth])
  20
  21   AC_CHECK_DECLS([wcwidth], [], [], [
  22 /* AIX 3.2.5 declares wcwidth in <string.h>. */
  23 #include <string.h>
  24 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  25    <wchar.h>.
  26    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
  27    before <wchar.h>.  */
  28 #include <stddef.h>
  29 #include <stdio.h>
  30 #include <time.h>
  31 #include <wchar.h>
  32 ])
  33   if test $ac_cv_have_decl_wcwidth != yes; then
  34     HAVE_DECL_WCWIDTH=0
  35   fi
  36
  37   if test $ac_cv_func_wcwidth = yes; then
  38     HAVE_WCWIDTH=1
  39     dnl On MacOS X 10.3, wcwidth(0x0301) (COMBINING ACUTE ACCENT) returns 1.
  40     dnl On OSF/1 5.1, wcwidth(0x200B) (ZERO WIDTH SPACE) returns 1.
  41     dnl This leads to bugs in 'ls' (coreutils).
  42     AC_CACHE_CHECK([whether wcwidth works reasonably in UTF-8 locales],
  43       [gl_cv_func_wcwidth_works],
  44       [
  45         AC_RUN_IFELSE(
  46           [AC_LANG_SOURCE([[
  47 #include <locale.h>
  48 /* AIX 3.2.5 declares wcwidth in <string.h>. */
  49 #include <string.h>
  50 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  51    <wchar.h>.
  52    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
  53    before <wchar.h>.  */
  54 #include <stddef.h>
  55 #include <stdio.h>
  56 #include <time.h>
  57 #include <wchar.h>
  58 #if !HAVE_DECL_WCWIDTH
  59 extern
  60 # ifdef __cplusplus
  61 "C"
  62 # endif
  63 int wcwidth (int);
  64 #endif
  65 int main ()
  66 {
  67   int result = 0;
  68   if (setlocale (LC_ALL, "fr_FR.UTF-8") != NULL)
  69     {
  70       if (wcwidth (0x0301) > 0)
  71         result |= 1;
  72       if (wcwidth (0x200B) > 0)
  73         result |= 2;
  74     }
  75   return result;
  76 }]])],
  77           [gl_cv_func_wcwidth_works=yes],
  78           [gl_cv_func_wcwidth_works=no],
  79           [
  80 changequote(,)dnl
  81            case "$host_os" in
  82                      # Guess yes on glibc and AIX 7 systems.
  83              *-gnu* | aix[7-9]*) gl_cv_func_wcwidth_works="guessing yes";;
  84              *)                  gl_cv_func_wcwidth_works="guessing no";;
  85            esac
  86 changequote([,])dnl
  87           ])
  88       ])
  89     case "$gl_cv_func_wcwidth_works" in
  90       *yes) ;;
  91       *no) REPLACE_WCWIDTH=1 ;;
  92     esac
  93   else
  94     HAVE_WCWIDTH=0
  95   fi
  96   dnl We don't substitute HAVE_WCWIDTH. We assume that if the system does not
  97   dnl have the wcwidth function, then it does not declare it.
  98 ])