m4/wcwidth.m4

   1 # wcwidth.m4 serial 2
   2 dnl Copyright (C) 2006 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_WCWIDTH],
   8 [
   9   dnl Persuade glibc <wchar.h> to declare wcwidth().
  10   AC_REQUIRE([AC_GNU_SOURCE])
  11
  12   AC_REQUIRE([AC_C_INLINE])
  13   AC_REQUIRE([gt_TYPE_WCHAR_T])
  14
  15   AC_CHECK_HEADERS_ONCE([wchar.h wctype.h])
  16   AC_CHECK_FUNCS_ONCE([iswprint wcwidth])
  17
  18   AC_CACHE_CHECK([whether wcwidth is declared], [ac_cv_have_decl_wcwidth],
  19     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
  20 /* AIX 3.2.5 declares wcwidth in <string.h>. */
  21 #if HAVE_STRING_H
  22 # include <string.h>
  23 #endif
  24 #if HAVE_WCHAR_H
  25 # include <wchar.h>
  26 #endif
  27 ], [
  28 #ifndef wcwidth
  29   char *p = (char *) wcwidth;
  30 #endif
  31 ])], [ac_cv_have_decl_wcwidth=yes], [ac_cv_have_decl_wcwidth=no])])
  32   if test $ac_cv_have_decl_wcwidth = yes; then
  33     ac_val=1
  34   else
  35     ac_val=0
  36   fi
  37   AC_DEFINE_UNQUOTED([HAVE_DECL_WCWIDTH], [$ac_val],
  38     [Define to 1 if you have the declaration of wcwidth(), and to 0
  39      otherwise.])
  40 ])