utimes.m4

   1 # Detect some bugs in glibc's implementation of utimes.
   2
   3 dnl Copyright (C) 2003, 2004, 2005 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 # See if we need to work around bugs in glibc's implementation of
   9 # utimes from 2003-07-12 to 2003-09-17.
  10 # First, there was a bug that would make utimes set mtime
  11 # and atime to zero (1970-01-01) unconditionally.
  12 # Then, there was code to round rather than truncate.
  13 # Then, there was an implementation (sparc64, Linux-2.4.28, glibc-2.3.3)
  14 # that didn't honor the NULL-means-set-to-current-time semantics.
  15 #
  16 # From Jim Meyering, with suggestions from Paul Eggert.
  17
  18 AC_DEFUN([gl_FUNC_UTIMES],
  19 [
  20   AC_CACHE_CHECK([determine whether the utimes function works],
  21                  gl_cv_func_working_utimes,
  22   [
  23   AC_RUN_IFELSE([AC_LANG_SOURCE([[
  24 #include <sys/types.h>
  25 #include <sys/stat.h>
  26 #include <sys/time.h>
  27 #include <time.h>
  28 #include <unistd.h>
  29 #include <stdlib.h>
  30 #include <stdio.h>
  31 #include <utime.h>
  32
  33 int
  34 main ()
  35 {
  36   static struct timeval timeval[2] = {{9, 10}, {999999, 999999}};
  37   struct stat sbuf;
  38   char const *file = "conftest.utimes";
  39   FILE *f;
  40   time_t now;
  41
  42   int ok = ((f = fopen (file, "w"))
  43             && fclose (f) == 0
  44             && utimes (file, timeval) == 0
  45             && lstat (file, &sbuf) == 0
  46             && sbuf.st_atime == timeval[0].tv_sec
  47             && sbuf.st_mtime == timeval[1].tv_sec);
  48   unlink (file);
  49   if (!ok)
  50     exit (1);
  51
  52   ok =
  53     ((f = fopen (file, "w"))
  54      && fclose (f) == 0
  55      && time (&now) != (time_t)-1
  56      && utimes (file, NULL) == 0
  57      && lstat (file, &sbuf) == 0
  58      && now - sbuf.st_atime <= 2
  59      && now - sbuf.st_mtime <= 2);
  60   unlink (file);
  61
  62   exit (!ok);
  63 }
  64   ]])],
  65        [gl_cv_func_working_utimes=yes],
  66        [gl_cv_func_working_utimes=no],
  67        [gl_cv_func_working_utimes=no])])
  68
  69   if test $gl_cv_func_working_utimes = yes; then
  70     AC_DEFINE([HAVE_WORKING_UTIMES], 1, [Define if utimes works properly. ])
  71   fi
  72 ])