# frexpl.m4 serial 2
dnl Copyright (C) 2007 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

AC_DEFUN([gl_FUNC_FREXPL],
[
  AC_REQUIRE([gl_MATH_H_DEFAULTS])
  FREXPL_LIBM=
  AC_CACHE_CHECK([whether frexpl() can be used without linking with libm],
    [gl_cv_func_frexpl_no_libm],
    [
      AC_TRY_LINK([#include <math.h>
                   long double x;],
                  [int e; return frexpl (x, &e) > 0;],
        [gl_cv_func_frexpl_no_libm=yes],
        [gl_cv_func_frexpl_no_libm=no])
    ])
  if test $gl_cv_func_frexpl_no_libm = no; then
    AC_CACHE_CHECK([whether frexpl() can be used with libm],
      [gl_cv_func_frexpl_in_libm],
      [
        save_LIBS="$LIBS"
        LIBS="$LIBS -lm"
        AC_TRY_LINK([#include <math.h>
                     long double x;],
                    [int e; return frexpl (x, &e) > 0;],
          [gl_cv_func_frexpl_in_libm=yes],
          [gl_cv_func_frexpl_in_libm=no])
        LIBS="$save_LIBS"
      ])
    if test $gl_cv_func_frexpl_in_libm = yes; then
      FREXPL_LIBM=-lm
    fi
  fi
  if test $gl_cv_func_frexpl_no_libm = yes \
     || test $gl_cv_func_frexpl_in_libm = yes; then
    save_LIBS="$LIBS"
    LIBS="$LIBS $FREXPL_LIBM"
    gl_FUNC_FREXPL_WORKS
    LIBS="$save_LIBS"
    case "$gl_cv_func_frexpl_works" in
      *yes) gl_func_frexpl=yes ;;
      *)    gl_func_frexpl=no; REPLACE_FREXPL=1; FREXPL_LIBM= ;;
    esac
  else
    gl_func_frexpl=no
  fi
  if test $gl_func_frexpl = yes; then
    AC_DEFINE([HAVE_FREXPL], 1,
      [Define if the frexpl() function is available.])
    dnl Also check whether it's declared.
    dnl MacOS X 10.3 has frexpl() in libc but doesn't declare it in <math.h>.
    AC_CHECK_DECL([frexpl], , [HAVE_DECL_FREXPL=0], [#include <math.h>])
  else
    HAVE_DECL_FREXPL=0
    AC_LIBOBJ([frexpl])
  fi
  AC_SUBST([FREXPL_LIBM])
])

dnl Test whether frexpl() works on finite numbers (this fails on AIX 5.1) and
dnl also on infinite numbers (this fails e.g. on IRIX 6.5).
AC_DEFUN([gl_FUNC_FREXPL_WORKS],
[
  AC_REQUIRE([AC_PROG_CC])
  AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  AC_CACHE_CHECK([whether frexpl works], [gl_cv_func_frexpl_works],
    [
      AC_TRY_RUN([
#include <math.h>
extern long double frexpl (long double, int *);
int main()
{
  volatile long double x;
  /* Test on finite numbers.  */
  {
    int exp = -9999;
    x = 16.0L;
    frexpl (x, &exp);
    if (exp != 5)
      return 1;
  }
  /* Test on infinite numbers.  */
  {
    x = 1.0L / 0.0L;
    int exp;
    long double y = frexpl (x, &exp);
    if (y != x)
      return 1;
  }
  return 0;
}], [gl_cv_func_frexpl_works=yes], [gl_cv_func_frexpl_works=no],
      [case "$host_os" in
         aix* | irix*) gl_cv_func_frexpl_works="guessing no";;
         *)            gl_cv_func_frexpl_works="guessing yes";;
       esac
      ])
    ])
])