# strtoumax.m4 serial 2
dnl Copyright (C) 2002-2003 Free Software Foundation, Inc.
dnl This file is free software, distributed under the terms of the GNU
dnl General Public License.  As a special exception to the GNU General
dnl Public License, this file may be distributed as part of a program
dnl that contains a configuration script generated by Autoconf, under
dnl the same distribution terms as the rest of that program.

AC_DEFUN([gl_FUNC_STRTOUMAX],
[
  dnl Work around a bug of AC_EGREP_CPP in autoconf-2.57.
  AC_REQUIRE([AC_PROG_CPP])
  AC_REQUIRE([AC_PROG_EGREP])

  AC_CACHE_CHECK([whether <inttypes.h> defines strtoumax as a macro],
    jm_cv_func_strtoumax_macro,
    [AC_EGREP_CPP([inttypes_h_defines_strtoumax], [#include <inttypes.h>
#ifdef strtoumax
 inttypes_h_defines_strtoumax
#endif],
       jm_cv_func_strtoumax_macro=yes,
       jm_cv_func_strtoumax_macro=no)])

  if test "$jm_cv_func_strtoumax_macro" != yes; then
    AC_REPLACE_FUNCS(strtoumax)
    if test $ac_cv_func_strtoumax = no; then
      gl_PREREQ_STRTOUMAX
    fi
  fi
])

# Prerequisites of lib/strtoumax.c.
AC_DEFUN([gl_PREREQ_STRTOUMAX], [
  jm_AC_TYPE_UINTMAX_T
  AC_CHECK_HEADERS_ONCE(stdlib.h)
  AC_CHECK_DECLS_ONCE(strtoul)
  AC_CHECK_DECLS(strtoull)
  AC_REQUIRE([jm_AC_TYPE_UNSIGNED_LONG_LONG])
])