unigbrk: New modules for grapheme clusters.

[gnulib.git] / m4 / locale-ar.m4

diff --git a/m4/locale-ar.m4 b/m4/locale-ar.m4
new file mode 100644 (file)
index 0000000..beb8ab3
--- /dev/null
+++ b/m4/locale-ar.m4
@@ -0,0 +1,69 @@
+# locale-ar.m4 serial 1
+dnl Copyright (C) 2003, 2005-2010 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl From Ben Pfaff, based on locale-fr.m4 by Bruno Haible.
+
+dnl Determine the name of an Arabic locale with traditional encoding.
+AC_DEFUN([gt_LOCALE_AR],
+[
+  AC_REQUIRE([AC_CANONICAL_HOST])
+  AC_REQUIRE([AM_LANGINFO_CODESET])
+  AC_CACHE_CHECK([for a traditional Arabic locale], [gt_cv_locale_ar], [
+    AC_LANG_CONFTEST([AC_LANG_SOURCE([
+changequote(,)dnl
+#include <locale.h>
+#include <time.h>
+#if HAVE_LANGINFO_CODESET
+# include <langinfo.h>
+#endif
+#include <stdlib.h>
+#include <string.h>
+struct tm t;
+char buf[16];
+int main () {
+  /* Check whether the given locale name is recognized by the system.  */
+  if (setlocale (LC_ALL, "") == NULL) return 1;
+  /* Check that nl_langinfo(CODESET) is nonempty and not "ASCII" or "646". */
+#if HAVE_LANGINFO_CODESET
+  {
+    const char *cs = nl_langinfo (CODESET);
+    if (cs[0] == '\0' || strcmp (cs, "ASCII") == 0 || strcmp (cs, "646") == 0
+        || strcmp (cs, "UTF-8") == 0)
+      return 1;
+  }
+#endif
+#ifdef __CYGWIN__
+  /* On Cygwin, avoid locale names without encoding suffix, because the
+     locale_charset() function relies on the encoding suffix.  Note that
+     LC_ALL is set on the command line.  */
+  if (strchr (getenv ("LC_ALL"), '.') == NULL) return 1;
+#endif
+  /* Check that the name of the first month begins with U+0643 (ك) as encoded
+     by ISO 8859-6.  This excludes the UTF-8 encoding.  */
+  t.tm_year = 1975 - 1900; t.tm_mon = 1 - 1; t.tm_mday = 4;
+  strftime (buf, sizeof (buf), "%B", &t);
+  if ((unsigned char) buf[0] != 0xe3) return 1;
+  return 0;
+}
+changequote([,])dnl
+      ])])
+    if AC_TRY_EVAL([ac_link]) && test -s conftest$ac_exeext; then
+      # Setting LC_ALL is not enough. Need to set LC_TIME to empty, because
+      # otherwise on MacOS X 10.3.5 the LC_TIME=C from the beginning of the
+      # configure script would override the LC_ALL setting. Likewise for
+      # LC_CTYPE, which is also set at the beginning of the configure script.
+      # Test for the usual locale name.
+      for gt_cv_locale_ar in ar_SA ar_SA.ISO-8859-6 ar_EG ar_EG.ISO-8859-6 none; do
+        if test $gt_cv_locale_ar = none || (LC_ALL=$gt_cv_locale_ar LC_TIME= LC_CTYPE= ./conftest; exit) 2>/dev/null; then
+         break
+       fi
+      done
+    fi
+    rm -fr conftest*
+  ])
+  LOCALE_AR=$gt_cv_locale_ar
+  AC_SUBST([LOCALE_AR])
+])