Change jm_ to gl_ in AC_DEFINE'd names. Update all uses.

[gnulib.git] / m4 / regex.m4

diff --git a/m4/regex.m4 b/m4/regex.m4
index 733ad3a..696fce1 100644 (file)
--- a/m4/regex.m4
+++ b/m4/regex.m4
@@ -1,31 +1,119 @@
-#serial 1
+#serial 21
 
-dnl From grep.
+dnl Initially derived from code in GNU grep.
+dnl Mostly written by Jim Meyering.
 
-AC_DEFUN(jm_WITH_REGEX,
+AC_DEFUN([gl_REGEX],
+[
+  gl_INCLUDED_REGEX([lib/regex.c])
+])
+
+dnl Usage: gl_INCLUDED_REGEX([lib/regex.c])
+dnl
+AC_DEFUN([gl_INCLUDED_REGEX],
   [
-    AC_ARG_WITH(included-regex,
-               [  --without-included-regex         don't compile regex],
-               USE_REGEX=$withval,
-               USE_REGEX=yes)
-
-    if test "$USE_REGEX" = yes; then
-
-      LIBOBJS="$LIBOBJS regex.o"
-
-    else
-      if test x = y; then
-       # This code is deliberately never run via ./configure.
-       # FIXME: this is a hack to make autoheader put the corresponding
-       # HAVE_* undef for this symbol in config.h.in.  This saves me the
-       # trouble of having to maintain the #undef in acconfig.h manually.
-       AC_CHECK_FUNCS(LIBC_REGEX)
-      fi
-      # Defining it this way (rather than via AC_DEFINE) short-circuits the
-      # autoheader check -- autoheader doesn't know it's already been taken
-      # care of by the hack above.
-      ac_kludge=HAVE_LIBC_REGEX
-      AC_DEFINE_UNQUOTED($ac_kludge)
+    dnl Even packages that don't use regex.c can use this macro.
+    dnl Of course, for them it doesn't do anything.
+
+    # Assume we'll default to using the included regex.c.
+    ac_use_included_regex=yes
+
+    # However, if the system regex support is good enough that it passes the
+    # the following run test, then default to *not* using the included regex.c.
+    # If cross compiling, assume the test would fail and use the included
+    # regex.c.  The first failing regular expression is from `Spencer ere
+    # test #75' in grep-2.3.
+    AC_CACHE_CHECK([for working re_compile_pattern],
+                  jm_cv_func_working_re_compile_pattern,
+      AC_TRY_RUN(
+[#include <stdio.h>
+#include <string.h>
+#include <regex.h>
+         int
+         main ()
+         {
+           static struct re_pattern_buffer regex;
+           const char *s;
+           struct re_registers regs;
+           re_set_syntax (RE_SYNTAX_POSIX_EGREP);
+           memset (&regex, 0, sizeof (regex));
+           [s = re_compile_pattern ("a[[:@:>@:]]b\n", 9, &regex);]
+           /* This should fail with _Invalid character class name_ error.  */
+           if (!s)
+             exit (1);
+
+           /* This should succeed, but doesn't for e.g. glibc-2.1.3.  */
+           memset (&regex, 0, sizeof (regex));
+           s = re_compile_pattern ("{1", 2, &regex);
+
+           if (s)
+             exit (1);
+
+           /* The following example is derived from a problem report
+               against gawk from Jorge Stolfi <stolfi@ic.unicamp.br>.  */
+           memset (&regex, 0, sizeof (regex));
+           s = re_compile_pattern ("[[an\371]]*n", 7, &regex);
+           if (s)
+             exit (1);
+
+           /* This should match, but doesn't for e.g. glibc-2.2.1.  */
+           if (re_match (&regex, "an", 2, 0, &regs) != 2)
+             exit (1);
+
+           memset (&regex, 0, sizeof (regex));
+           s = re_compile_pattern ("x", 1, &regex);
+           if (s)
+             exit (1);
+
+           /* The version of regex.c in e.g. GNU libc-2.2.93 didn't
+              work with a negative RANGE argument.  */
+           if (re_search (&regex, "wxy", 3, 2, -2, &regs) != 1)
+             exit (1);
+
+           exit (0);
+         }
+       ],
+              jm_cv_func_working_re_compile_pattern=yes,
+              jm_cv_func_working_re_compile_pattern=no,
+              dnl When crosscompiling, assume it's broken.
+              jm_cv_func_working_re_compile_pattern=no))
+    if test $jm_cv_func_working_re_compile_pattern = yes; then
+      ac_use_included_regex=no
     fi
+
+    test -n "$1" || AC_MSG_ERROR([missing argument])
+    m4_syscmd([test -f $1])
+    ifelse(m4_sysval, 0,
+      [
+       AC_ARG_WITH(included-regex,
+       [  --without-included-regex don't compile regex; this is the default on
+                          systems with version 2 of the GNU C library
+                          (use with caution on other system)],
+                   jm_with_regex=$withval,
+                   jm_with_regex=$ac_use_included_regex)
+       if test "$jm_with_regex" = yes; then
+         AC_LIBOBJ(regex)
+         gl_PREREQ_REGEX
+       fi
+      ],
+    )
   ]
 )
+
+# Prerequisites of lib/regex.c.
+AC_DEFUN([gl_PREREQ_REGEX],
+[
+  dnl FIXME: Maybe provide a btowc replacement someday: Solaris 2.5.1 lacks it.
+  dnl FIXME: Check for wctype and iswctype, and and add -lw if necessary
+  dnl to get them.
+
+  dnl Persuade glibc <string.h> to declare mempcpy().
+  AC_REQUIRE([AC_GNU_SOURCE])
+
+  AC_REQUIRE([gl_C_RESTRICT])
+  AC_REQUIRE([AC_FUNC_ALLOCA])
+  AC_REQUIRE([AC_HEADER_STDC])
+  AC_CHECK_HEADERS_ONCE(wchar.h wctype.h)
+  AC_CHECK_FUNCS_ONCE(isascii mempcpy)
+  AC_CHECK_FUNCS(btowc)
+])