(jm_INCLUDED_REGEX): Change "\201" to "\371"; apparently Emacs's

[gnulib.git] / m4 / regex.m4

diff --git a/m4/regex.m4 b/m4/regex.m4
index 007b166..93efa3a 100644 (file)
--- a/m4/regex.m4
+++ b/m4/regex.m4
@@ -1,37 +1,119 @@
-## --------------------------------- ##
-## Check if --with-regex was given.  ##
-## --------------------------------- ##
-
-# serial 1
-
-# The idea is to distribute rx.[hc] and regex.[hc] together, for a while.
-# The WITH_REGEX symbol (which should also be documented in acconfig.h)
-# is used to decide which of regex.h or rx.h should be included in the
-# application.  If `./configure --with-regex' is given (the default), the
-# package will use gawk's regex.  If `./configure --without-regex', a
-# check is made to see if rx is already installed, as with newer Linux'es.
-# If not found, the package will use the rx from the distribution.
-# If found, the package will use the system's rx which, on Linux at least,
-# will result in a smaller executable file.
-
-AC_DEFUN(AM_WITH_REGEX,
-[AC_MSG_CHECKING(which of GNU rx or gawk's regex is wanted)
-AC_ARG_WITH(regex,
-[  --without-regex         use GNU rx in lieu of gawk's regex for matching],
-[test "$withval" = yes && am_with_regex=1],
-[am_with_regex=1])
-if test -n "$am_with_regex"; then
-  AC_MSG_RESULT(regex)
-  AC_DEFINE(WITH_REGEX)
-  AC_CACHE_CHECK([for GNU regex in libc], am_cv_gnu_regex,
-    AC_TRY_LINK([], [extern int re_max_failures; re_max_failures = 1],
-               am_cv_gnu_regex=yes, am_cv_gnu_regex=no))
-  if test $am_cv_gnu_regex = no; then
-    LIBOBJS="$LIBOBJS regex.o"
-  fi
-else
-  AC_MSG_RESULT(rx)
-  AC_CHECK_FUNC(re_rx_search, , [LIBOBJS="$LIBOBJS rx.o"])
-fi
-AC_SUBST(LIBOBJS)dnl
+#serial 19
+
+dnl Initially derived from code in GNU grep.
+dnl Mostly written by Jim Meyering.
+
+AC_DEFUN([gl_REGEX],
+[
+  jm_INCLUDED_REGEX([lib/regex.c])
+])
+
+dnl Usage: jm_INCLUDED_REGEX([lib/regex.c])
+dnl
+AC_DEFUN([jm_INCLUDED_REGEX],
+  [
+    dnl Even packages that don't use regex.c can use this macro.
+    dnl Of course, for them it doesn't do anything.
+
+    # Assume we'll default to using the included regex.c.
+    ac_use_included_regex=yes
+
+    # However, if the system regex support is good enough that it passes the
+    # the following run test, then default to *not* using the included regex.c.
+    # If cross compiling, assume the test would fail and use the included
+    # regex.c.  The first failing regular expression is from `Spencer ere
+    # test #75' in grep-2.3.
+    AC_CACHE_CHECK([for working re_compile_pattern],
+                  jm_cv_func_working_re_compile_pattern,
+      AC_TRY_RUN(
+[#include <stdio.h>
+#include <string.h>
+#include <regex.h>
+         int
+         main ()
+         {
+           static struct re_pattern_buffer regex;
+           const char *s;
+           struct re_registers regs;
+           re_set_syntax (RE_SYNTAX_POSIX_EGREP);
+           memset (&regex, 0, sizeof (regex));
+           [s = re_compile_pattern ("a[[:@:>@:]]b\n", 9, &regex);]
+           /* This should fail with _Invalid character class name_ error.  */
+           if (!s)
+             exit (1);
+
+           /* This should succeed, but doesn't for e.g. glibc-2.1.3.  */
+           memset (&regex, 0, sizeof (regex));
+           s = re_compile_pattern ("{1", 2, &regex);
+
+           if (s)
+             exit (1);
+
+           /* The following example is derived from a problem report
+               against gawk from Jorge Stolfi <stolfi@ic.unicamp.br>.  */
+           memset (&regex, 0, sizeof (regex));
+           s = re_compile_pattern ("[[an\371]]*n", 7, &regex);
+           if (s)
+             exit (1);
+
+           /* This should match, but doesn't for e.g. glibc-2.2.1.  */
+           if (re_match (&regex, "an", 2, 0, &regs) != 2)
+             exit (1);
+
+           memset (&regex, 0, sizeof (regex));
+           s = re_compile_pattern ("x", 1, &regex);
+           if (s)
+             exit (1);
+
+           /* The version of regex.c in e.g. GNU libc-2.2.93 didn't
+              work with a negative RANGE argument.  */
+           if (re_search (&regex, "wxy", 3, 2, -2, &regs) != 1)
+             exit (1);
+
+           exit (0);
+         }
+       ],
+              jm_cv_func_working_re_compile_pattern=yes,
+              jm_cv_func_working_re_compile_pattern=no,
+              dnl When crosscompiling, assume it's broken.
+              jm_cv_func_working_re_compile_pattern=no))
+    if test $jm_cv_func_working_re_compile_pattern = yes; then
+      ac_use_included_regex=no
+    fi
+
+    test -n "$1" || AC_MSG_ERROR([missing argument])
+    m4_syscmd([test -f $1])
+    ifelse(m4_sysval, 0,
+      [
+       AC_ARG_WITH(included-regex,
+       [  --without-included-regex don't compile regex; this is the default on
+                          systems with version 2 of the GNU C library
+                          (use with caution on other system)],
+                   jm_with_regex=$withval,
+                   jm_with_regex=$ac_use_included_regex)
+       if test "$jm_with_regex" = yes; then
+         AC_LIBOBJ(regex)
+         jm_PREREQ_REGEX
+       fi
+      ],
+    )
+  ]
+)
+
+# Prerequisites of lib/regex.c.
+AC_DEFUN([jm_PREREQ_REGEX],
+[
+  dnl FIXME: Maybe provide a btowc replacement someday: Solaris 2.5.1 lacks it.
+  dnl FIXME: Check for wctype and iswctype, and and add -lw if necessary
+  dnl to get them.
+
+  dnl Persuade glibc <string.h> to declare mempcpy().
+  AC_REQUIRE([AC_GNU_SOURCE])
+
+  AC_REQUIRE([gl_C_RESTRICT])
+  AC_REQUIRE([AC_FUNC_ALLOCA])
+  AC_REQUIRE([AC_HEADER_STDC])
+  AC_CHECK_HEADERS_ONCE(limits.h string.h wchar.h wctype.h)
+  AC_CHECK_FUNCS_ONCE(isascii mempcpy)
+  AC_CHECK_FUNCS(btowc)
 ])