X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;ds=sidebyside;f=m4%2Fsqrtl.m4;h=0bc6ecd0d8690f8c1fe94f0deba502fb5e778666;hb=beae0bdcf7fe30f2415c16f6b8c1368d469e519c;hp=70de8240b8eeb146162ea314a0f510bca430a210;hpb=b9a2cb7e5c8141ccc40fe5c1a581ff89279080c5;p=gnulib.git

diff --git a/m4/sqrtl.m4 b/m4/sqrtl.m4
index 70de8240b..0bc6ecd0d 100644
--- a/m4/sqrtl.m4
+++ b/m4/sqrtl.m4
@@ -1,5 +1,5 @@
-# sqrtl.m4 serial 7
-dnl Copyright (C) 2010-2012 Free Software Foundation, Inc.
+# sqrtl.m4 serial 9
+dnl Copyright (C) 2010-2013 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
@@ -56,11 +56,22 @@ AC_DEFUN([gl_FUNC_SQRTL],
   if test $gl_cv_func_sqrtl_no_libm = yes \
      || test $gl_cv_func_sqrtl_in_libm = yes; then
     dnl Also check whether it's declared.
-    dnl MacOS X 10.3 has sqrtl() in libc but doesn't declare it in <math.h>.
+    dnl Mac OS X 10.3 has sqrtl() in libc but doesn't declare it in <math.h>.
     AC_CHECK_DECL([sqrtl], , [HAVE_DECL_SQRTL=0], [[#include <math.h>]])
+
+    save_LIBS="$LIBS"
+    LIBS="$LIBS $SQRTL_LIBM"
+    gl_FUNC_SQRTL_WORKS
+    LIBS="$save_LIBS"
+    case "$gl_cv_func_sqrtl_works" in
+      *yes) ;;
+      *) REPLACE_SQRTL=1 ;;
+    esac
   else
     HAVE_DECL_SQRTL=0
     HAVE_SQRTL=0
+  fi
+  if test $HAVE_SQRTL = 0 || test $REPLACE_SQRTL = 1; then
     dnl Find libraries needed to link lib/sqrtl.c.
     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
       AC_REQUIRE([gl_FUNC_SQRT])
@@ -94,3 +105,58 @@ AC_DEFUN([gl_FUNC_SQRTL],
   fi
   AC_SUBST([SQRTL_LIBM])
 ])
+
+dnl Test whether sqrtl() works.
+dnl On OpenBSD 5.1/SPARC, sqrtl(8.1974099812331540680810141969554806865L) has
+dnl rounding errors that eat up the last 8 to 9 decimal digits.
+AC_DEFUN([gl_FUNC_SQRTL_WORKS],
+[
+  AC_REQUIRE([AC_PROG_CC])
+  AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
+  AC_CACHE_CHECK([whether sqrtl works], [gl_cv_func_sqrtl_works],
+    [
+      AC_RUN_IFELSE(
+        [AC_LANG_SOURCE([[
+#include <float.h>
+#include <math.h>
+#ifndef sqrtl /* for AIX */
+extern
+#ifdef __cplusplus
+"C"
+#endif
+long double sqrtl (long double);
+#endif
+static long double
+my_ldexpl (long double x, int d)
+{
+  for (; d > 0; d--)
+    x *= 2.0L;
+  for (; d < 0; d++)
+    x *= 0.5L;
+  return x;
+}
+volatile long double x;
+volatile long double y;
+long double z;
+int main ()
+{
+  x = 8.1974099812331540680810141969554806865L;
+  y = sqrtl (x);
+  z = y * y - x;
+  z = my_ldexpl (z, LDBL_MANT_DIG);
+  if (z < 0)
+    z = - z;
+  if (z > 100.0L)
+    return 1;
+  return 0;
+}
+]])],
+        [gl_cv_func_sqrtl_works=yes],
+        [gl_cv_func_sqrtl_works=no],
+        [case "$host_os" in
+           openbsd*) gl_cv_func_sqrtl_works="guessing no";;
+           *)        gl_cv_func_sqrtl_works="guessing yes";;
+         esac
+        ])
+    ])
+])