X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fansi-c%2B%2B.m4;h=fbb5d64240d7f858be26c144d62e17b33e075ffc;hb=2b14869442bce932cf1d805387928484d4914d59;hp=1b65cec3e1c8eb55d02f0db1e56e3e91f02065d0;hpb=5f1dc805decae66f75d568218166f3ffa67387c9;p=gnulib.git

diff --git a/m4/ansi-c++.m4 b/m4/ansi-c++.m4
index 1b65cec3e..fbb5d6424 100644
--- a/m4/ansi-c++.m4
+++ b/m4/ansi-c++.m4
@@ -1,5 +1,5 @@
-# ansi-c++.m4 serial 3
-dnl Copyright (C) 2002-2003, 2005, 2010 Free Software Foundation, Inc.
+# ansi-c++.m4 serial 8
+dnl Copyright (C) 2002-2003, 2005, 2010-2011 Free Software Foundation, Inc.
 dnl This file is free software; the Free Software Foundation
 dnl gives unlimited permission to copy and/or distribute it,
 dnl with or without modifications, as long as this notice is preserved.
@@ -7,23 +7,41 @@ dnl with or without modifications, as long as this notice is preserved.
 dnl From Bruno Haible.
 
 # Sets CXX_CHOICE to 'yes' or 'no', depending on the preferred use of C++.
+# The default is 'yes'. If the configure.ac contains a definition of the
+# macro gl_CXX_CHOICE_DEFAULT_NO, then the default is 'no'. In both cases,
+# the user can change the value by passing the option --disable-cxx or
+# --enable-cxx, respectively.
 
 AC_DEFUN([gl_CXX_CHOICE],
 [
   AC_MSG_CHECKING([whether to use C++])
-  dnl It would be so nice if plus signs were supported in AC_ARG_ENABLE.
-  dnl Feature request submitted on 2010-03-13.
-  AC_ARG_ENABLE([cxx],
-    [  --disable-cxx           do not build C++ sources],
-    [CXX_CHOICE="$enableval"],
-    [CXX_CHOICE=yes])
+  dnl Plus signs are supported in AC_ARG_ENABLE starting with autoconf-2.66.
+  m4_version_prereq([2.66],
+    [m4_ifdef([gl_CXX_CHOICE_DEFAULT_NO],
+       [AC_ARG_ENABLE([c++],
+          [  --enable-c++            also build C++ sources],
+          [CXX_CHOICE="$enableval"],
+          [CXX_CHOICE=no])],
+       [AC_ARG_ENABLE([c++],
+          [  --disable-c++           do not build C++ sources],
+          [CXX_CHOICE="$enableval"],
+          [CXX_CHOICE=yes])])],
+    [m4_ifdef([gl_CXX_CHOICE_DEFAULT_NO],
+       [AC_ARG_ENABLE([cxx],
+          [  --enable-cxx            also build C++ sources],
+          [CXX_CHOICE="$enableval"],
+          [CXX_CHOICE=no])],
+       [AC_ARG_ENABLE([cxx],
+          [  --disable-cxx           do not build C++ sources],
+          [CXX_CHOICE="$enableval"],
+          [CXX_CHOICE=yes])])])
   AC_MSG_RESULT([$CXX_CHOICE])
   AC_SUBST([CXX_CHOICE])
 ])
 
 # gl_PROG_ANSI_CXX([ANSICXX_VARIABLE], [ANSICXX_CONDITIONAL])
 # Sets ANSICXX_VARIABLE to the name of a sufficiently ANSI C++ compliant
-# compiler, or to ":" if none is found.
+# compiler, or to "no" if none is found.
 # Defines the Automake condition ANSICXX_CONDITIONAL to true if such a compiler
 # was found, or to false if not.
 
@@ -33,16 +51,18 @@ AC_DEFUN([gl_PROG_ANSI_CXX],
   m4_if([$1], [CXX], [],
     [gl_save_CXX="$CXX"])
   if test "$CXX_CHOICE" = no; then
-    CXX=":"
+    CXX=no
   fi
   if test -z "$CXX"; then
     if test -n "$CCC"; then
       CXX="$CCC"
     else
-      AC_CHECK_PROGS([CXX], [g++ c++ gpp aCC CC cxx cc++ cl FCC KCC RCC xlC_r xlC], [:])
+      AC_CHECK_TOOLS([CXX],
+                     [g++ c++ gpp aCC CC cxx cc++ cl FCC KCC RCC xlC_r xlC],
+                     [:])
     fi
   fi
-  if test "$CXX" != ":"; then
+  if test "$CXX" != no; then
     dnl Use a modified version of AC_PROG_CXX_WORKS that does not exit
     dnl upon failure.
     AC_MSG_CHECKING([whether the C++ compiler ($CXX $CXXFLAGS $LDFLAGS) works])
@@ -94,11 +114,15 @@ EOF
      CXX="$gl_save_CXX"])
   AC_SUBST([$1])
 
-  AM_CONDITIONAL([$2], [test "$$1" != ":"])
+  AM_CONDITIONAL([$2], [test "$$1" != no])
 
-  dnl This macro invocation resolves an automake error:
-  dnl /usr/local/share/automake-1.11/am/depend2.am: am__fastdepCXX does not appear in AM_CONDITIONAL
-  dnl /usr/local/share/automake-1.11/am/depend2.am:   The usual way to define `am__fastdepCXX' is to add `AC_PROG_CXX'
-  dnl /usr/local/share/automake-1.11/am/depend2.am:   to `configure.ac' and run `aclocal' and `autoconf' again.
-  _AM_DEPENDENCIES([CXX])
+  if test "$$1" != no; then
+    dnl This macro invocation resolves an automake error:
+    dnl /usr/local/share/automake-1.11/am/depend2.am: am__fastdepCXX does not appear in AM_CONDITIONAL
+    dnl /usr/local/share/automake-1.11/am/depend2.am:   The usual way to define `am__fastdepCXX' is to add `AC_PROG_CXX'
+    dnl /usr/local/share/automake-1.11/am/depend2.am:   to `configure.ac' and run `aclocal' and `autoconf' again.
+    _AM_DEPENDENCIES([CXX])
+  else
+    AM_CONDITIONAL([am__fastdepCXX], [false])
+  fi
 ])