X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fdirfd.m4;h=b422769484a560604bf101ce8fbf0117eaff466b;hb=46f5f314f34a08c9305758482d7d2fdb0e999d09;hp=fee5fb2ec7a7045c5d72b277daf6d95ca62434c2;hpb=39ce2a1909d1f2562f4a59974b97d3ec6217c5bc;p=gnulib.git

diff --git a/m4/dirfd.m4 b/m4/dirfd.m4
index fee5fb2ec..b42276948 100644
--- a/m4/dirfd.m4
+++ b/m4/dirfd.m4
@@ -1,66 +1,83 @@
-#serial 1
+# serial 22   -*- Autoconf -*-
 
 dnl Find out how to get the file descriptor associated with an open DIR*.
+
+# Copyright (C) 2001-2006, 2008-2014 Free Software Foundation, Inc.
+# This file is free software; the Free Software Foundation
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
+
 dnl From Jim Meyering
 
-AC_DEFUN([UTILS_FUNC_DIRFD],
+AC_DEFUN([gl_FUNC_DIRFD],
 [
-  AC_HEADER_DIRENT
-  AC_REPLACE_FUNCS([dirfd])
-  dirfd_headers='
-#if HAVE_DIRENT_H
-# include <dirent.h>
-#else /* not HAVE_DIRENT_H */
-# define dirent direct
-# if HAVE_SYS_NDIR_H
-#  include <sys/ndir.h>
-# endif /* HAVE_SYS_NDIR_H */
-# if HAVE_SYS_DIR_H
-#  include <sys/dir.h>
-# endif /* HAVE_SYS_DIR_H */
-# if HAVE_NDIR_H
-#  include <ndir.h>
-# endif /* HAVE_NDIR_H */
-#endif /* HAVE_DIRENT_H */
-'
-  AC_CHECK_DECLS([dirfd], , , $dirfd_headers)
-  if test $ac_cv_func_dirfd = no; then
-    AC_CACHE_CHECK(
-	      [how to get the file descriptor associated with an open DIR*],
-		   ac_cv_sys_dir_to_fd,
-      [
-        dirfd_save_DEFS=$DEFS
-	for ac_expr in						\
-								\
-	    '# Solaris'						\
-	    'dir_p->d_fd'					\
-								\
-	    '# Solaris'						\
-	    'dir_p->dd_fd'					\
-								\
-	    '# systems for which the info is not available'	\
-	    -1							\
-	    ; do
+  AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
+
+  dnl Persuade glibc <dirent.h> to declare dirfd().
+  AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
 
-	  # Skip each embedded comment.
-	  case "$ac_expr" in '#'*) continue;; esac
+  AC_CHECK_FUNCS([dirfd])
+  AC_CHECK_DECLS([dirfd], , ,
+    [[#include <sys/types.h>
+      #include <dirent.h>]])
+  if test $ac_cv_have_decl_dirfd = no; then
+    HAVE_DECL_DIRFD=0
+  fi
 
-	  DEFS="$DEFS -DDIR_TO_FD=$ac_expr"
-	  AC_TRY_COMPILE(
-	    [$dirfd_headers
-	    ],
-	    [DIR *dir_p = opendir("."); (void) ($ac_expr);],
-	    dir_fd_done=yes
-	  )
-	  DEFS=$dirfd_save_DEFS
-	  test "$dir_fd_done" = yes && break
-	done
+  AC_CACHE_CHECK([whether dirfd is a macro],
+    gl_cv_func_dirfd_macro,
+    [AC_EGREP_CPP([dirent_header_defines_dirfd], [
+#include <sys/types.h>
+#include <dirent.h>
+#ifdef dirfd
+ dirent_header_defines_dirfd
+#endif],
+       gl_cv_func_dirfd_macro=yes,
+       gl_cv_func_dirfd_macro=no)])
 
-	ac_cv_sys_dir_to_fd=$ac_expr
-      ]
-    )
-    AC_DEFINE_UNQUOTED(DIR_TO_FD,
-      $ac_cv_sys_dir_to_fd,
-      [the file descriptor associated with `dir_p'])
+  # Use the replacement only if we have no function or macro with that name.
+  if test $ac_cv_func_dirfd = no && test $gl_cv_func_dirfd_macro = no; then
+    if test $ac_cv_have_decl_dirfd = yes; then
+      # If the system declares dirfd already, let's declare rpl_dirfd instead.
+      REPLACE_DIRFD=1
+    fi
   fi
 ])
+
+dnl Prerequisites of lib/dirfd.c.
+AC_DEFUN([gl_PREREQ_DIRFD],
+[
+  AC_CACHE_CHECK([how to get the file descriptor associated with an open DIR*],
+                 [gl_cv_sys_dir_fd_member_name],
+    [
+      dirfd_save_CFLAGS=$CFLAGS
+      for ac_expr in d_fd dd_fd; do
+
+        CFLAGS="$CFLAGS -DDIR_FD_MEMBER_NAME=$ac_expr"
+        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+           #include <sys/types.h>
+           #include <dirent.h>]],
+          [[DIR *dir_p = opendir("."); (void) dir_p->DIR_FD_MEMBER_NAME;]])],
+          [dir_fd_found=yes]
+        )
+        CFLAGS=$dirfd_save_CFLAGS
+        test "$dir_fd_found" = yes && break
+      done
+      test "$dir_fd_found" = yes || ac_expr=no_such_member
+
+      gl_cv_sys_dir_fd_member_name=$ac_expr
+    ]
+  )
+  if test $gl_cv_sys_dir_fd_member_name != no_such_member; then
+    AC_DEFINE_UNQUOTED([DIR_FD_MEMBER_NAME],
+      [$gl_cv_sys_dir_fd_member_name],
+      [the name of the file descriptor member of DIR])
+  fi
+  AH_VERBATIM([DIR_TO_FD],
+              [#ifdef DIR_FD_MEMBER_NAME
+# define DIR_TO_FD(Dir_p) ((Dir_p)->DIR_FD_MEMBER_NAME)
+#else
+# define DIR_TO_FD(Dir_p) -1
+#endif
+])
+])