X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fdirfd.m4;h=f401f6ced4846fb5cc7ea3fa9aab74e3a392bd83;hb=99b313868bb6a7441f762d78252ce418f5ca7fdb;hp=b62e12a54f5b6f6ec9bef72b8443f6405ee11327;hpb=7e7fa1da8c3471b86ff76898f4e73d2c43bcd6e8;p=gnulib.git

diff --git a/m4/dirfd.m4 b/m4/dirfd.m4
index b62e12a54..f401f6ced 100644
--- a/m4/dirfd.m4
+++ b/m4/dirfd.m4
@@ -1,49 +1,80 @@
-#serial 1
+# serial 20   -*- Autoconf -*-
 
 dnl Find out how to get the file descriptor associated with an open DIR*.
+
+# Copyright (C) 2001-2006, 2008-2011 Free Software Foundation, Inc.
+# This file is free software; the Free Software Foundation
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
+
 dnl From Jim Meyering
 
-AC_DEFUN([UTILS_FUNC_DIRFD],
+AC_DEFUN([gl_FUNC_DIRFD],
 [
-  AC_REPLACE_FUNCS([dirfd])
-  if test $ac_cv_func_dirfd = no; then
+  AC_REQUIRE([gl_DIRENT_H_DEFAULTS])
+
+  dnl Persuade glibc <dirent.h> to declare dirfd().
+  AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
+
+  AC_CHECK_FUNCS([dirfd])
+  AC_CHECK_DECLS([dirfd], , ,
+    [#include <sys/types.h>
+     #include <dirent.h>])
+  if test $ac_cv_have_decl_dirfd = no; then
+    HAVE_DECL_DIRFD=0
+  fi
+
+  AC_CACHE_CHECK([whether dirfd is a macro],
+    gl_cv_func_dirfd_macro,
+    [AC_EGREP_CPP([dirent_header_defines_dirfd], [
+#include <sys/types.h>
+#include <dirent.h>
+#ifdef dirfd
+ dirent_header_defines_dirfd
+#endif],
+       gl_cv_func_dirfd_macro=yes,
+       gl_cv_func_dirfd_macro=no)])
+
+  # Use the replacement only if we have no function or macro with that name.
+  if test $ac_cv_func_dirfd,$gl_cv_func_dirfd_macro = no,no; then
+    if test $ac_cv_have_decl_dirfd = yes; then
+      # If the system declares dirfd already, let's declare rpl_dirfd instead.
+      REPLACE_DIRFD=1
+    fi
+    AC_LIBOBJ([dirfd])
     AC_CACHE_CHECK(
-	      [how to get the file descriptor associated with an open DIR*],
-		   ac_cv_sys_dir_to_fd,
+              [how to get the file descriptor associated with an open DIR*],
+                   gl_cv_sys_dir_fd_member_name,
       [
-        dirfd_save_DEFS=$DEFS
-	for ac_expr in						\
-								\
-	    '# Solaris'						\
-	    'dir_p->d_fd'					\
-								\
-	    '# Solaris'						\
-	    'dir_p->dd_fd'					\
-								\
-	    '# systems for which the info is not available'	\
-	    -1							\
-	    ; do
-
-	  # Skip each embedded comment.
-	  case "$ac_expr" in '#'*) continue;; esac
-
-	  DEFS="$DEFS -DDIR_TO_FD=$ac_expr"
-	  AC_TRY_COMPILE(
-	    [#include <sys/types.h>
-	     #include <dirent.h>
-	    ],
-	    [DIR *dir_p = opendir("."); (void) ($ac_expr);],
-	    dir_fd_done=yes
-	  )
-	  DEFS=$dirfd_save_DEFS
-	  test "$dir_fd_done" = yes && break
-	done
-
-	ac_cv_sys_dir_to_fd=$ac_expr
+        dirfd_save_CFLAGS=$CFLAGS
+        for ac_expr in d_fd dd_fd; do
+
+          CFLAGS="$CFLAGS -DDIR_FD_MEMBER_NAME=$ac_expr"
+          AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+             #include <sys/types.h>
+             #include <dirent.h>]],
+            [[DIR *dir_p = opendir("."); (void) dir_p->DIR_FD_MEMBER_NAME;]])],
+            [dir_fd_found=yes]
+          )
+          CFLAGS=$dirfd_save_CFLAGS
+          test "$dir_fd_found" = yes && break
+        done
+        test "$dir_fd_found" = yes || ac_expr=no_such_member
+
+        gl_cv_sys_dir_fd_member_name=$ac_expr
       ]
     )
-    AC_DEFINE_UNQUOTED(DIR_TO_FD,
-      $ac_cv_sys_dir_to_fd,
-      [the file descriptor associated with `dir_p'])
+    if test $gl_cv_sys_dir_fd_member_name != no_such_member; then
+      AC_DEFINE_UNQUOTED([DIR_FD_MEMBER_NAME],
+        $gl_cv_sys_dir_fd_member_name,
+        [the name of the file descriptor member of DIR])
+    fi
+    AH_VERBATIM(DIR_TO_FD,
+                [#ifdef DIR_FD_MEMBER_NAME
+# define DIR_TO_FD(Dir_p) ((Dir_p)->DIR_FD_MEMBER_NAME)
+#else
+# define DIR_TO_FD(Dir_p) -1
+#endif
+])
   fi
 ])