X-Git-Url: http://erislabs.net/gitweb/?a=blobdiff_plain;f=m4%2Fgetgroups.m4;h=8a5547f432fba5e275ee322709b970f150257c9b;hb=eb944d1d03d408d829b4fa68eefd3a1ae94f9eb5;hp=e0f3359b090dc8c49ddb80acb4cb7cfc12ac8b78;hpb=6fe8d7498529e40705598c70355fd2f38efc7aea;p=gnulib.git

diff --git a/m4/getgroups.m4 b/m4/getgroups.m4
index e0f3359b0..8a5547f43 100644
--- a/m4/getgroups.m4
+++ b/m4/getgroups.m4
@@ -1,46 +1,43 @@
-#serial 5
+# serial 15
 
 dnl From Jim Meyering.
-dnl
-dnl Invoking code should check $GETGROUPS_LIB something like this:
-dnl  jm_FUNC_GETGROUPS
-dnl  test -n "$GETGROUPS_LIB" && LIBS="$GETGROUPS_LIB $LIBS"
-dnl
+dnl A wrapper around AC_FUNC_GETGROUPS.
 
-AC_DEFUN([jm_FUNC_GETGROUPS],
-[AC_REQUIRE([AC_TYPE_GETGROUPS])dnl
- AC_REQUIRE([AC_TYPE_SIZE_T])dnl
- AC_CHECK_FUNCS(getgroups)
+# Copyright (C) 1996-1997, 1999-2004, 2008-2011 Free Software Foundation, Inc.
+#
+# This file is free software; the Free Software Foundation
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
 
- # If we don't yet have getgroups, see if it's in -lbsd.
- # This is reported to be necessary on an ITOS 3000WS running SEIUX 3.1.
- if test $ac_cv_func_getgroups = no; then
-   jm_cv_sys_getgroups_saved_lib="$LIBS"
-   AC_CHECK_LIB(bsd, getgroups, [GETGROUPS_LIB=-lbsd])
-   LIBS="$jm_cv_sys_getgroups_saved_lib"
- fi
-
- # Run the program to test the functionality of the system-supplied
- # getgroups function only if there is such a function.
- if test $ac_cv_func_getgroups = yes; then
-   AC_CACHE_CHECK([for working getgroups], jm_cv_func_working_getgroups,
-    [AC_TRY_RUN([
-      int
-      main ()
-      {
-	/* On Ultrix 4.3, getgroups (0, 0) always fails.  */
-	exit (getgroups (0, 0) == -1 ? 1 : 0);
-      }
-		],
-	       jm_cv_func_working_getgroups=yes,
-	       jm_cv_func_working_getgroups=no,
-	       dnl When crosscompiling, assume getgroups is broken.
-	       jm_cv_func_working_getgroups=no)
-    ])
-    if test $jm_cv_func_working_getgroups = no; then
-      AC_LIBOBJ(getgroups)
-      AC_DEFINE(getgroups, rpl_getgroups,
-	[Define as rpl_getgroups if getgroups doesn't work right.])
+AC_DEFUN([gl_FUNC_GETGROUPS],
+[
+  AC_REQUIRE([AC_FUNC_GETGROUPS])
+  AC_REQUIRE([AC_TYPE_GETGROUPS])
+  AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
+  if test "$ac_cv_func_getgroups" != yes; then
+    AC_LIBOBJ([getgroups])
+    HAVE_GETGROUPS=0
+  elif test "$ac_cv_func_getgroups_works.$ac_cv_type_getgroups" != yes.gid_t
+  then
+    AC_LIBOBJ([getgroups])
+    REPLACE_GETGROUPS=1
+    AC_DEFINE([GETGROUPS_ZERO_BUG], [1], [Define this to 1 if
+      getgroups(0,NULL) does not return the number of groups.])
+  else
+    dnl Detect FreeBSD bug; POSIX requires getgroups(-1,ptr) to fail.
+    AC_CACHE_CHECK([whether getgroups handles negative values],
+      [gl_cv_func_getgroups_works],
+      [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
+        [[int size = getgroups (0, 0);
+          gid_t *list = malloc (size * sizeof *list);
+          return getgroups (-1, list) != -1;]])],
+        [gl_cv_func_getgroups_works=yes],
+        [gl_cv_func_getgroups_works=no],
+        [gl_cv_func_getgroups_works="guessing no"])])
+    if test "$gl_cv_func_getgroups_works" != yes; then
+      AC_LIBOBJ([getgroups])
+      REPLACE_GETGROUPS=1
     fi
   fi
+  test -n "$GETGROUPS_LIB" && LIBS="$GETGROUPS_LIB $LIBS"
 ])